matita/matita/contribs/lambdadelta/static_2/static/fsle_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/frees_drops.ma".
  16 include "static_2/static/fsle_length.ma".
  17
  18 (* FREE VARIABLES INCLUSION FOR RESTRICTED CLOSURES *************************)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 lemma fsle_lifts_sn: ∀T1,U1. ⬆*[1] T1 ≘ U1 → ∀L1,L2. |L2| ≤ |L1| →
  23                      ∀T2. ⦃L1, T1⦄ ⊆ ⦃L2, T2⦄ → ⦃L1.ⓧ, U1⦄ ⊆ ⦃L2, T2⦄.
  24 #T1 #U1 #HTU1 #L1 #L2 #H1L #T2
  25 * #n #m #f #g #Hf #Hg #H2L #Hfg
  26 lapply (lveq_length_fwd_dx … H2L ?) // -H1L #H destruct
  27 lapply (frees_lifts_SO (Ⓣ) (L1.ⓧ) … HTU1 … Hf)
  28 [ /3 width=4 by drops_refl, drops_drop/ ] -T1 #Hf
  29 @(ex4_4_intro … Hf Hg) /2 width=4 by lveq_void_sn/ (**) (* explict constructor *)
  30 qed-.
  31
  32 lemma fsle_lifts_SO_sn: ∀K1,K2. |K1| = |K2| → ∀V1,V2. ⦃K1, V1⦄ ⊆ ⦃K2, V2⦄ →
  33                         ∀W1. ⬆*[1] V1 ≘ W1 → ∀I1,I2. ⦃K1.ⓘ{I1}, W1⦄ ⊆ ⦃K2.ⓑ{I2}V2, #O⦄.
  34 #K1 #K2 #HK #V1 #V2
  35 * #n1 #n2 #f1 #f2 #Hf1 #Hf2 #HK12 #Hf12
  36 #W1 #HVW1 #I1 #I2
  37 elim (lveq_inj_length … HK12) // -HK #H1 #H2 destruct
  38 /5 width=12 by frees_lifts_SO, frees_pair, drops_refl, drops_drop, lveq_bind, sle_weak, ex4_4_intro/
  39 qed.
  40
  41 lemma fsle_lifts_SO: ∀K1,K2. |K1| = |K2| → ∀T1,T2. ⦃K1, T1⦄ ⊆ ⦃K2, T2⦄ →
  42                      ∀U1,U2. ⬆*[1] T1 ≘ U1 → ⬆*[1] T2 ≘ U2 →
  43                      ∀I1,I2.  ⦃K1.ⓘ{I1}, U1⦄ ⊆ ⦃K2.ⓘ{I2}, U2⦄.
  44 #K1 #K2 #HK #T1 #T2
  45 * #n1 #n2 #f1 #f2 #Hf1 #Hf2 #HK12 #Hf12
  46 #U1 #U2 #HTU1 #HTU2 #I1 #I2
  47 elim (lveq_inj_length … HK12) // -HK #H1 #H2 destruct
  48 /5 width=12 by frees_lifts_SO, drops_refl, drops_drop, lveq_bind, sle_push, ex4_4_intro/
  49 qed.
  50
  51 (* Advanced inversion lemmas ************************************************)
  52
  53 lemma fsle_inv_lifts_sn: ∀T1,U1. ⬆*[1] T1 ≘ U1 →
  54                          ∀I1,I2,L1,L2,V1,V2,U2. ⦃L1.ⓑ{I1}V1,U1⦄ ⊆ ⦃L2.ⓑ{I2}V2, U2⦄ →
  55                          ∀p. ⦃L1, T1⦄ ⊆ ⦃L2, ⓑ{p,I2}V2.U2⦄.
  56 #T1 #U1 #HTU1 #I1 #I2 #L1 #L2 #V1 #V2 #U2
  57 * #n #m #f2 #g2 #Hf2 #Hg2 #HL #Hfg2 #p
  58 elim (lveq_inv_pair_pair … HL) -HL #HL #H1 #H2 destruct
  59 elim (frees_total L2 V2) #g1 #Hg1
  60 elim (sor_isfin_ex g1 (⫱g2)) /3 width=3 by frees_fwd_isfin, isfin_tl/ #g #Hg #_
  61 lapply (frees_inv_lifts_SO (Ⓣ) … Hf2 … HTU1)
  62 [1,2: /3 width=4 by drops_refl, drops_drop/ ] -U1 #Hf2
  63 lapply (sor_inv_sle_dx … Hg) #H0g
  64 /5 width=10 by frees_bind, sle_tl, sle_trans, ex4_4_intro/
  65 qed-.