matita/matita/contribs/lambdadelta/static_2/static/fsle_fsle.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/syntax/lveq_lveq.ma".
  16 include "static_2/static/fsle_fqup.ma".
  17
  18 (* FREE VARIABLES INCLUSION FOR RESTRICTED CLOSURES *************************)
  19
  20 (* Advanced inversion lemmas ************************************************)
  21
  22 lemma fsle_frees_trans:
  23       ∀L1,L2,T1,T2. ❪L1,T1❫ ⊆ ❪L2,T2❫ →
  24       ∀f2. L2 ⊢ 𝐅+❪T2❫ ≘ f2 →
  25       ∃∃n1,n2,f1. L1 ⊢ 𝐅+❪T1❫ ≘ f1 & L1 ≋ⓧ*[n1,n2] L2 & ⫱*[n1]f1 ⊆ ⫱*[n2]f2.
  26 #L1 #L2 #T1 #T2 * #n1 #n2 #f1 #g2 #Hf1 #Hg2 #HL #Hn #f2 #Hf2
  27 lapply (frees_mono … Hg2 … Hf2) -Hg2 -Hf2 #Hgf2
  28 lapply (tls_eq_repl n2 … Hgf2) -Hgf2 #Hgf2
  29 lapply (sle_eq_repl_back2 … Hn … Hgf2) -g2
  30 /2 width=6 by ex3_3_intro/
  31 qed-.
  32
  33 lemma fsle_frees_trans_eq:
  34       ∀L1,L2. |L1| = |L2| →
  35       ∀T1,T2. ❪L1,T1❫ ⊆ ❪L2,T2❫ → ∀f2. L2 ⊢ 𝐅+❪T2❫ ≘ f2 →
  36       ∃∃f1. L1 ⊢ 𝐅+❪T1❫ ≘ f1 & f1 ⊆ f2.
  37 #L1 #L2 #H1L #T1 #T2 #H2L #f2 #Hf2
  38 elim (fsle_frees_trans … H2L … Hf2) -T2 #n1 #n2 #f1 #Hf1 #H2L #Hf12
  39 elim (lveq_inj_length … H2L) // -L2 #H1 #H2 destruct
  40 /2 width=3 by ex2_intro/
  41 qed-.
  42
  43 lemma fsle_inv_frees_eq:
  44       ∀L1,L2. |L1| = |L2| →
  45       ∀T1,T2. ❪L1,T1❫ ⊆ ❪L2,T2❫ →
  46       ∀f1. L1 ⊢ 𝐅+❪T1❫ ≘ f1 → ∀f2. L2 ⊢ 𝐅+❪T2❫ ≘ f2 →
  47       f1 ⊆ f2.
  48 #L1 #L2 #H1L #T1 #T2 #H2L #f1 #Hf1 #f2 #Hf2
  49 elim (fsle_frees_trans_eq … H2L … Hf2) // -L2 -T2
  50 /3 width=6 by frees_mono, sle_eq_repl_back1/
  51 qed-.
  52
  53 (* Main properties **********************************************************)
  54
  55 theorem fsle_trans_sn:
  56         ∀L1,L2,T1,T. ❪L1,T1❫ ⊆ ❪L2,T❫ →
  57         ∀T2. ❪L2,T❫ ⊆ ❪L2,T2❫ → ❪L1,T1❫ ⊆ ❪L2,T2❫.
  58 #L1 #L2 #T1 #T
  59 * #m1 #m0 #g1 #g0 #Hg1 #Hg0 #Hm #Hg
  60 #T2
  61 * #n0 #n2 #f0 #f2 #Hf0 #Hf2 #Hn #Hf
  62 lapply (frees_mono … Hf0 … Hg0) -Hf0 -Hg0 #Hfg0
  63 elim (lveq_inj_length … Hn) // -Hn #H1 #H2 destruct
  64 lapply (sle_eq_repl_back1 … Hf … Hfg0) -f0
  65 /4 width=10 by sle_tls, sle_trans, ex4_4_intro/
  66 qed-.
  67
  68 theorem fsle_trans_dx:
  69         ∀L1,T1,T. ❪L1,T1❫ ⊆ ❪L1,T❫ →
  70         ∀L2,T2. ❪L1,T❫ ⊆ ❪L2,T2❫ → ❪L1,T1❫ ⊆ ❪L2,T2❫.
  71 #L1 #T1 #T
  72 * #m1 #m0 #g1 #g0 #Hg1 #Hg0 #Hm #Hg
  73 #L2 #T2
  74 * #n0 #n2 #f0 #f2 #Hf0 #Hf2 #Hn #Hf
  75 lapply (frees_mono … Hg0 … Hf0) -Hg0 -Hf0 #Hgf0
  76 elim (lveq_inj_length … Hm) // -Hm #H1 #H2 destruct
  77 lapply (sle_eq_repl_back2 … Hg … Hgf0) -g0
  78 /4 width=10 by sle_tls, sle_trans, ex4_4_intro/
  79 qed-.
  80
  81 theorem fsle_trans_rc:
  82         ∀L1,L,T1,T. |L1| = |L| → ❪L1,T1❫ ⊆ ❪L,T❫ →
  83         ∀L2,T2. |L| = |L2| → ❪L,T❫ ⊆ ❪L2,T2❫ → ❪L1,T1❫ ⊆ ❪L2,T2❫.
  84 #L1 #L #T1 #T #HL1
  85 * #m1 #m0 #g1 #g0 #Hg1 #Hg0 #Hm #Hg
  86 #L2 #T2 #HL2
  87 * #n0 #n2 #f0 #f2 #Hf0 #Hf2 #Hn #Hf
  88 lapply (frees_mono … Hg0 … Hf0) -Hg0 -Hf0 #Hgf0
  89 elim (lveq_inj_length … Hm) // -Hm #H1 #H2 destruct
  90 elim (lveq_inj_length … Hn) // -Hn #H1 #H2 destruct
  91 lapply (sle_eq_repl_back2 … Hg … Hgf0) -g0
  92 /3 width=10 by lveq_length_eq, sle_trans, ex4_4_intro/
  93 qed-.
  94
  95 theorem fsle_bind_sn_ge:
  96         ∀L1,L2. |L2| ≤ |L1| →
  97         ∀V1,T1,T. ❪L1,V1❫ ⊆ ❪L2,T❫ → ❪L1.ⓧ,T1❫ ⊆ ❪L2,T❫ →
  98         ∀p,I. ❪L1,ⓑ[p,I]V1.T1❫ ⊆ ❪L2,T❫.
  99 #L1 #L2 #HL #V1 #T1 #T * #n1 #x #f1 #g #Hf1 #Hg #H1n1 #H2n1 #H #p #I
 100 elim (fsle_frees_trans … H … Hg) -H #n2 #n #f2 #Hf2 #H1n2 #H2n2
 101 elim (lveq_inj_void_sn_ge … H1n1 … H1n2) -H1n2 // #H1 #H2 #H3 destruct
 102 elim (sor_isfin_ex f1 (⫱f2)) /3 width=3 by frees_fwd_isfin, isfin_tl/ #f #Hf #_
 103 <tls_xn in H2n2; #H2n2
 104 /4 width=12 by frees_bind_void, sor_inv_sle, sor_tls, ex4_4_intro/
 105 qed.
 106
 107 theorem fsle_flat_sn:
 108         ∀L1,L2,V1,T1,T. ❪L1,V1❫ ⊆ ❪L2,T❫ → ❪L1,T1❫ ⊆ ❪L2,T❫ →
 109         ∀I. ❪L1,ⓕ[I]V1.T1❫ ⊆ ❪L2,T❫.
 110 #L1 #L2 #V1 #T1 #T * #n1 #x #f1 #g #Hf1 #Hg #H1n1 #H2n1 #H #I
 111 elim (fsle_frees_trans … H … Hg) -H #n2 #n #f2 #Hf2 #H1n2 #H2n2
 112 elim (lveq_inj … H1n1 … H1n2) -H1n2 #H1 #H2 destruct
 113 elim (sor_isfin_ex f1 f2) /2 width=3 by frees_fwd_isfin/ #f #Hf #_
 114 /4 width=12 by frees_flat, sor_inv_sle, sor_tls, ex4_4_intro/
 115 qed.
 116
 117 theorem fsle_bind_eq:
 118         ∀L1,L2. |L1| = |L2| → ∀V1,V2. ❪L1,V1❫ ⊆ ❪L2,V2❫ →
 119         ∀I2,T1,T2. ❪L1.ⓧ,T1❫ ⊆ ❪L2.ⓑ[I2]V2,T2❫ →
 120         ∀p,I1. ❪L1,ⓑ[p,I1]V1.T1❫ ⊆ ❪L2,ⓑ[p,I2]V2.T2❫.
 121 #L1 #L2 #HL #V1 #V2
 122 * #n1 #m1 #f1 #g1 #Hf1 #Hg1 #H1L #Hfg1 #I2 #T1 #T2
 123 * #n2 #m2 #f2 #g2 #Hf2 #Hg2 #H2L #Hfg2 #p #I1
 124 elim (lveq_inj_length … H1L) // #H1 #H2 destruct
 125 elim (lveq_inj_length … H2L) // -HL -H2L #H1 #H2 destruct
 126 elim (sor_isfin_ex f1 (⫱f2)) /3 width=3 by frees_fwd_isfin, isfin_tl/ #f #Hf #_
 127 elim (sor_isfin_ex g1 (⫱g2)) /3 width=3 by frees_fwd_isfin, isfin_tl/ #g #Hg #_
 128 /4 width=15 by frees_bind_void, frees_bind, monotonic_sle_sor, sle_tl, ex4_4_intro/
 129 qed.
 130
 131 theorem fsle_bind:
 132         ∀L1,L2,V1,V2. ❪L1,V1❫ ⊆ ❪L2,V2❫ →
 133         ∀I1,I2,T1,T2. ❪L1.ⓑ[I1]V1,T1❫ ⊆ ❪L2.ⓑ[I2]V2,T2❫ →
 134         ∀p. ❪L1,ⓑ[p,I1]V1.T1❫ ⊆ ❪L2,ⓑ[p,I2]V2.T2❫.
 135 #L1 #L2 #V1 #V2
 136 * #n1 #m1 #f1 #g1 #Hf1 #Hg1 #H1L #Hfg1 #I1 #I2 #T1 #T2
 137 * #n2 #m2 #f2 #g2 #Hf2 #Hg2 #H2L #Hfg2 #p
 138 elim (lveq_inv_pair_pair … H2L) -H2L #H2L #H1 #H2 destruct
 139 elim (lveq_inj … H2L … H1L) -H1L #H1 #H2 destruct
 140 elim (sor_isfin_ex f1 (⫱f2)) /3 width=3 by frees_fwd_isfin, isfin_tl/ #f #Hf #_
 141 elim (sor_isfin_ex g1 (⫱g2)) /3 width=3 by frees_fwd_isfin, isfin_tl/ #g #Hg #_
 142 /4 width=15 by frees_bind, monotonic_sle_sor, sle_tl, ex4_4_intro/
 143 qed.
 144
 145 theorem fsle_flat:
 146         ∀L1,L2,V1,V2. ❪L1,V1❫ ⊆ ❪L2,V2❫ →
 147         ∀T1,T2. ❪L1,T1❫ ⊆ ❪L2,T2❫ →
 148         ∀I1,I2. ❪L1,ⓕ[I1]V1.T1❫ ⊆ ❪L2,ⓕ[I2]V2.T2❫.
 149 /3 width=1 by fsle_flat_sn, fsle_flat_dx_dx, fsle_flat_dx_sn/ qed-.