matita/matita/contribs/lambdadelta/static_2/static/gcp.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/syntax/genv.ma".
  16 include "static_2/relocation/drops_vector.ma".
  17
  18 (* GENERIC COMPUTATION PROPERTIES *******************************************)
  19
  20 definition nf (RR:relation4 genv lenv term term) (RS:relation term) ≝
  21               λG,L,T. NF … (RR G L) RS T.
  22
  23 definition candidate: Type[0] ≝ relation3 genv lenv term.
  24
  25 definition CP0 (RR) (RS) ≝ ∀G. d_liftable1 (nf RR RS G).
  26
  27 definition CP1 (RR) (RS) ≝ ∀G,L,s. nf RR RS G L (⋆s).
  28
  29 definition CP2 (RP:candidate) ≝ ∀G. d_liftable1 (RP G).
  30
  31 definition CP3 (RP:candidate) ≝ ∀G,L,T,s. RP G L (ⓐ⋆s.T) → RP G L T.
  32
  33 (* requirements for generic computation properties *)
  34 (* Basic_1: includes: nf2_lift1 *)
  35 (* Basic_2A1: includes: gcp0_lifts *)
  36 (* Basic_2A1: includes: gcp2_lifts *)
  37 record gcp (RR:relation4 genv lenv term term) (RS:relation term) (RP:candidate) : Prop ≝
  38 { cp0: CP0 RR RS;
  39   cp1: CP1 RR RS;
  40   cp2: CP2 RP;
  41   cp3: CP3 RP
  42 }.
  43
  44 (* Basic properties *********************************************************)
  45
  46 (* Basic_1: was only: sns3_lifts1 *)
  47 (* Basic_2A1: was: gcp2_lifts_all *)
  48 lemma gcp2_all: ∀RR,RS,RP. gcp RR RS RP → ∀G. d_liftable1_all (RP G).
  49 /3 width=7 by cp2, d1_liftable_liftable_all/ qed.