matita/matita/contribs/lambdadelta/static_2/static/lsubf_frees.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/lsubf.ma".
  16
  17 (* RESTRICTED REFINEMENT FOR CONTEXT-SENSITIVE FREE VARIABLES ***************)
  18
  19 (* Properties with context-sensitive free variables *************************)
  20
  21 lemma lsubf_frees_trans: ∀f2,L2,T. L2 ⊢ 𝐅*⦃T⦄ ≘ f2 →
  22                          ∀f1,L1. ⦃L1, f1⦄ ⫃𝐅* ⦃L2, f2⦄ → L1 ⊢ 𝐅*⦃T⦄ ≘ f1.
  23 #f2 #L2 #T #H elim H -f2 -L2 -T
  24 [ /3 width=5 by lsubf_fwd_isid_dx, frees_sort/
  25 | #f2 #i #Hf2 #g1 #Y1 #H
  26   elim (lsubf_inv_atom2 … H) -H #Hg1 #H destruct
  27   elim (eq_inv_pushs_dx … Hg1) -Hg1 #g #Hg #H destruct
  28   elim (eq_inv_xn … Hg) -Hg
  29   /3 width=3 by frees_atom, isid_eq_repl_fwd/
  30 | #f2 #I #K2 #W #_ #IH #g1 #Y1 #H elim (lsubf_inv_pair2 … H) -H *
  31   [ #f1 #K1 #H12 #H1 #H2 destruct /3 width=1 by frees_pair/
  32   | #f #f0 #f1 #K1 #V #H12 #Hf #Hf1 #H1 #H2 #H3 destruct
  33     /4 width=5 by frees_pair, frees_flat/
  34   ]
  35 | #f2 #I #L2 #Hf2 #g1 #Y1 #H elim (lsubf_inv_unit2 … H) -H *
  36   [ #f1 #L1 #H12 #H1 #H2 destruct
  37     /3 width=5 by lsubf_fwd_isid_dx, frees_unit/
  38   | #f #f0 #f1 #J #L1 #V #H12 #Hf #Hf1 #H1 #H2 destruct
  39     /5 width=9 by lsubf_fwd_isid_dx, frees_eq_repl_back, frees_pair, sor_isid_inv_sn/
  40   ]
  41 | #f2 #I #L2 #i #_ #IH #g1 #L1 #H elim (lsubf_inv_push2 … H) -H
  42   /3 width=1 by frees_lref/
  43 | /3 width=5 by lsubf_fwd_isid_dx, frees_gref/
  44 | #f2V #f2T #f2 #p #I #L2 #V #T #_ #_ #Hf2 #IHV #IHT #f1 #L1 #H12
  45   elim (lsubf_inv_sor_dx … H12 … Hf2) -f2 #f1V #g1T #HV #HT #Hf1
  46   elim (lsubf_bind_tl_dx … (BPair I V) … HT) -HT #f1T #HT #H destruct
  47   /3 width=5 by frees_bind/
  48 | #f2V #f2T #f2 #I #L2 #V #T #_ #_ #Hf2 #IHV #IHT #f1 #L1 #H12
  49   elim (lsubf_inv_sor_dx … H12 … Hf2) -f2 /3 width=5 by frees_flat/
  50 ]
  51 qed-.