matita/matita/contribs/lambdadelta/static_2/static/lsubf_frees.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/lsubf.ma".
  16
  17 (* RESTRICTED REFINEMENT FOR CONTEXT-SENSITIVE FREE VARIABLES ***************)
  18
  19 (* Properties with context-sensitive free variables *************************)
  20
  21 lemma lsubf_frees_trans:
  22       ∀f2,L2,T. L2 ⊢ 𝐅+❪T❫ ≘ f2 →
  23       ∀f1,L1. ❪L1,f1❫ ⫃𝐅+ ❪L2,f2❫ → L1 ⊢ 𝐅+❪T❫ ≘ f1.
  24 #f2 #L2 #T #H elim H -f2 -L2 -T
  25 [ /3 width=5 by lsubf_fwd_isid_dx, frees_sort/
  26 | #f2 #i #Hf2 #g1 #Y1 #H
  27   elim (lsubf_inv_atom2 … H) -H #Hg1 #H destruct
  28   elim (eq_inv_pushs_dx … Hg1) -Hg1 #g #Hg #H destruct
  29   elim (eq_inv_xn … Hg) -Hg
  30   /3 width=3 by frees_atom, isid_eq_repl_fwd/
  31 | #f2 #I #K2 #W #_ #IH #g1 #Y1 #H elim (lsubf_inv_pair2 … H) -H *
  32   [ #f1 #K1 #H12 #H1 #H2 destruct /3 width=1 by frees_pair/
  33   | #f #f0 #f1 #K1 #V #H12 #Hf #Hf1 #H1 #H2 #H3 destruct
  34     /4 width=5 by frees_pair, frees_flat/
  35   ]
  36 | #f2 #I #L2 #Hf2 #g1 #Y1 #H elim (lsubf_inv_unit2 … H) -H *
  37   [ #f1 #L1 #H12 #H1 #H2 destruct
  38     /3 width=5 by lsubf_fwd_isid_dx, frees_unit/
  39   | #f #f0 #f1 #J #L1 #V #H12 #Hf #Hf1 #H1 #H2 destruct
  40     /5 width=9 by lsubf_fwd_isid_dx, frees_eq_repl_back, frees_pair, sor_isid_inv_sn/
  41   ]
  42 | #f2 #I #L2 #i #_ #IH #g1 #L1 #H elim (lsubf_inv_push2 … H) -H
  43   /3 width=1 by frees_lref/
  44 | /3 width=5 by lsubf_fwd_isid_dx, frees_gref/
  45 | #f2V #f2T #f2 #p #I #L2 #V #T #_ #_ #Hf2 #IHV #IHT #f1 #L1 #H12
  46   elim (lsubf_inv_sor_dx … H12 … Hf2) -f2 #f1V #g1T #HV #HT #Hf1
  47   elim (lsubf_bind_tl_dx … (BPair I V) … HT) -HT #f1T #HT #H destruct
  48   /3 width=5 by frees_bind/
  49 | #f2V #f2T #f2 #I #L2 #V #T #_ #_ #Hf2 #IHV #IHT #f1 #L1 #H12
  50   elim (lsubf_inv_sor_dx … H12 … Hf2) -f2 /3 width=5 by frees_flat/
  51 ]
  52 qed-.