matita/matita/contribs/lambdadelta/static_2/static/lsubr_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/relocation/drops.ma".
  16 include "static_2/static/lsubr.ma".
  17
  18 (* RESTRICTED REFINEMENT FOR LOCAL ENVIRONMENTS *****************************)
  19
  20 (* Forward lemmas with generic slicing for local environments ***************)
  21
  22 (* Basic_2A1: includes: lsubr_fwd_drop2_pair *)
  23 lemma lsubr_fwd_drops2_bind:
  24       ∀L1,L2. L1 ⫃ L2 →
  25       ∀b,f,I,K2. 𝐔❪f❫ → ⇩*[b,f] L2 ≘ K2.ⓘ[I] →
  26       ∨∨ ∃∃K1. K1 ⫃ K2 & ⇩*[b,f] L1 ≘ K1.ⓘ[I]
  27        | ∃∃K1,W,V. K1 ⫃ K2 & ⇩*[b,f] L1 ≘ K1.ⓓⓝW.V & I = BPair Abst W
  28        | ∃∃J1,J2,K1,V. K1 ⫃ K2 & ⇩*[b,f] L1 ≘ K1.ⓑ[J1]V & I = BUnit J2.
  29 #L1 #L2 #H elim H -L1 -L2
  30 [ #b #f #I #K2 #_ #H
  31   elim (drops_inv_atom1 … H) -H #H destruct
  32 | #J #L1 #L2 | #L1 #L2 #V #W | #I1 #I2 #L1 #L2 #V1
  33 ]
  34 #HL12 #IH #b #f #I #K2 #Hf #H
  35 elim (drops_inv_bind1_isuni … Hf H) -Hf -H *
  36 [1,3,5: #Hf #H destruct -IH
  37   /4 width=6 by drops_refl, or3_intro0, or3_intro1, or3_intro2, ex3_4_intro, ex3_3_intro, ex2_intro/
  38 |2,4,6: #g #Hg #HLK2 #H destruct -HL12
  39   elim (IH … Hg HLK2) -IH -Hg -HLK2 *
  40   /4 width=6 by drops_drop, or3_intro0, or3_intro1, or3_intro2, ex3_4_intro, ex3_3_intro, ex2_intro/
  41 ]
  42 qed-.
  43
  44 (* Basic_2A1: includes: lsubr_fwd_drop2_abbr *)
  45 lemma lsubr_fwd_drops2_abbr:
  46       ∀L1,L2. L1 ⫃ L2 →
  47       ∀b,f,K2,V. 𝐔❪f❫ → ⇩*[b,f] L2 ≘ K2.ⓓV →
  48       ∃∃K1. K1 ⫃ K2 & ⇩*[b,f] L1 ≘ K1.ⓓV.
  49 #L1 #L2 #HL12 #b #f #K2 #V #Hf #HLK2
  50 elim (lsubr_fwd_drops2_bind … HL12 … Hf HLK2) -L2 -Hf // *
  51 [ #K1 #W #V #_ #_ #H destruct
  52 | #I1 #I2 #K1 #V #_ #_ #H destruct
  53 ]
  54 qed-.