matita/matita/contribs/lambdadelta/static_2/static/reqg_reqg.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/syntax/ext2_ext2.ma".
  16 include "static_2/syntax/teqg_teqg.ma".
  17 include "static_2/static/rex_rex.ma".
  18 include "static_2/static/reqg_length.ma".
  19
  20 (* GENERIC EQUIVALENCE FOR LOCAL ENVIRONMENTS ON REFERRED ENTRIES ***********)
  21
  22 (* Advanced forward lemmas **************************************************)
  23
  24 lemma frees_reqg_conf (S):
  25       reflexive … S →
  26       ∀f,L1,T. L1 ⊢ 𝐅+❪T❫ ≘ f →
  27       ∀L2. L1 ≛[S,T] L2 → L2 ⊢ 𝐅+❪T❫ ≘ f.
  28 /3 width=7 by frees_seqg_conf, rex_inv_frees/ qed-.
  29
  30 (* Properties with free variables inclusion for restricted closures *******)
  31
  32 lemma reqg_fsle_comp (S):
  33       reflexive … S →
  34       rex_fsle_compatible (ceqg S).
  35 #S #HS #L1 #L2 #T #HL12
  36 elim (frees_total L1 T) #f #Hf
  37 /4 width=8 by frees_reqg_conf, rex_fwd_length, lveq_length_eq, sle_refl, ex4_4_intro/
  38 qed.
  39
  40 (* Advanced properties ******************************************************)
  41
  42 lemma reqg_sym (S) (T):
  43       reflexive … S → symmetric … S →
  44       symmetric … (reqg S T).
  45 /3 width=3 by reqg_fsge_comp, rex_sym, teqg_sym/ qed-.
  46
  47 (* Basic_2A1: uses: lleq_dec *)
  48 lemma reqg_dec (S):
  49       (∀s1,s2. Decidable … (S s1 s2)) →
  50       ∀L1,L2. ∀T:term. Decidable (L1 ≛[S,T] L2).
  51 /3 width=1 by rex_dec, teqg_dec/ qed-.
  52
  53 (* Main properties **********************************************************)
  54
  55 (* Basic_2A1: uses: lleq_bind lleq_bind_O *)
  56 theorem reqg_bind (S):
  57         ∀p,I,L1,L2,V1,V2,T.
  58         L1 ≛[S,V1] L2 → L1.ⓑ[I]V1 ≛[S,T] L2.ⓑ[I]V2 →
  59         L1 ≛[S,ⓑ[p,I]V1.T] L2.
  60 /2 width=2 by rex_bind/ qed.
  61
  62 (* Basic_2A1: uses: lleq_flat *)
  63 theorem reqg_flat (S):
  64         ∀I,L1,L2,V,T.
  65         L1 ≛[S,V] L2 → L1 ≛[S,T] L2 → L1 ≛[S,ⓕ[I]V.T] L2.
  66 /2 width=1 by rex_flat/ qed.
  67
  68 theorem reqg_bind_void (S):
  69         ∀p,I,L1,L2,V,T.
  70         L1 ≛[S,V] L2 → L1.ⓧ ≛[S,T] L2.ⓧ → L1 ≛[S,ⓑ[p,I]V.T] L2.
  71 /2 width=1 by rex_bind_void/ qed.
  72
  73 (* Basic_2A1: uses: lleq_trans *)
  74 theorem reqg_trans (S) (T):
  75         reflexive … S → Transitive … S →
  76         Transitive … (reqg S T).
  77 #S #T #H1S #H2S #L1 #L * #f1 #Hf1 #HL1 #L2 * #f2 #Hf2 #HL2
  78 lapply (frees_teqg_conf_seqg … Hf1 T … HL1) /2 width=1 by teqg_refl/ #H0
  79 lapply (frees_mono … Hf2 … H0) -Hf2 -H0
  80 /5 width=7 by sex_trans, sex_eq_repl_back, teqg_trans, ext2_trans, ex2_intro/
  81 qed-.
  82
  83 (* Basic_2A1: uses: lleq_canc_sn *)
  84 theorem reqg_canc_sn (S) (T):
  85         reflexive … S → symmetric … S → Transitive … S →
  86         left_cancellable … (reqg S T).
  87 /3 width=3 by reqg_trans, reqg_sym/ qed-.
  88
  89 (* Basic_2A1: uses: lleq_canc_dx *)
  90 theorem reqg_canc_dx (S) (T):
  91         reflexive … S → symmetric … S → Transitive … S →
  92         right_cancellable … (reqg S T).
  93 /3 width=3 by reqg_trans, reqg_sym/ qed-.
  94
  95 theorem reqg_repl (S) (T:term):
  96         reflexive … S → symmetric … S → Transitive … S →
  97         ∀L1,L2. L1 ≛[S,T] L2 →
  98         ∀K1. L1 ≛[S,T] K1 → ∀K2. L2 ≛[S,T] K2 → K1 ≛[S,T] K2.
  99 /3 width=3 by reqg_canc_sn, reqg_trans/ qed-.
 100
 101 (* Negated properties *******************************************************)
 102
 103 (* Note: auto works with /4 width=8/ so reqg_canc_sn is preferred **********)
 104 (* Basic_2A1: uses: lleq_nlleq_trans *)
 105 lemma reqg_rneqg_trans (S) (T:term):
 106       reflexive … S → symmetric … S → Transitive … S →
 107       ∀L1,L. L1 ≛[S,T] L →
 108       ∀L2. (L ≛[S,T] L2 → ⊥) → (L1 ≛[S,T] L2 → ⊥).
 109 /3 width=3 by reqg_canc_sn/ qed-.
 110
 111 (* Basic_2A1: uses: nlleq_lleq_div *)
 112 lemma rneqg_reqg_div (S) (T:term):
 113       reflexive … S → Transitive … S →
 114       ∀L2,L. L2 ≛[S,T] L →
 115       ∀L1. (L1 ≛[S,T] L → ⊥) → (L1 ≛[S,T] L2 → ⊥).
 116 /3 width=3 by reqg_trans/ qed-.
 117
 118 theorem rneqg_reqg_canc_dx (S) (T:term):
 119         reflexive … S → Transitive … S →
 120         ∀L1,L. (L1 ≛[S,T] L → ⊥) →
 121         ∀L2. L2 ≛[S,T] L → L1 ≛[S,T] L2 → ⊥.
 122 /3 width=3 by reqg_trans/ qed-.
 123
 124 (* Negated inversion lemmas *************************************************)
 125
 126 (* Basic_2A1: uses: nlleq_inv_bind nlleq_inv_bind_O *)
 127 lemma rneqg_inv_bind (S):
 128       (∀s1,s2. Decidable … (S s1 s2)) →
 129       ∀p,I,L1,L2,V,T. (L1 ≛[S,ⓑ[p,I]V.T] L2 → ⊥) →
 130       ∨∨ L1 ≛[S,V] L2 → ⊥ | (L1.ⓑ[I]V ≛[S,T] L2.ⓑ[I]V → ⊥).
 131 /3 width=2 by rnex_inv_bind, teqg_dec/ qed-.
 132
 133 (* Basic_2A1: uses: nlleq_inv_flat *)
 134 lemma rneqg_inv_flat (S):
 135       (∀s1,s2. Decidable … (S s1 s2)) →
 136       ∀I,L1,L2,V,T. (L1 ≛[S,ⓕ[I]V.T] L2 → ⊥) →
 137       ∨∨ L1 ≛[S,V] L2 → ⊥ | (L1 ≛[S,T] L2 → ⊥).
 138 /3 width=2 by rnex_inv_flat, teqg_dec/ qed-.
 139
 140 lemma rneqg_inv_bind_void (S):
 141       (∀s1,s2. Decidable … (S s1 s2)) →
 142       ∀p,I,L1,L2,V,T. (L1 ≛[S,ⓑ[p,I]V.T] L2 → ⊥) →
 143       ∨∨ L1 ≛[S,V] L2 → ⊥ | (L1.ⓧ ≛[S,T] L2.ⓧ → ⊥).
 144 /3 width=3 by rnex_inv_bind_void, teqg_dec/ qed-.