matita/matita/contribs/lambdadelta/static_2/static/reqx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/notation/relations/stareqsn_3.ma".
  16 include "static_2/syntax/teqx_ext.ma".
  17 include "static_2/static/rex.ma".
  18
  19 (* SORT-IRRELEVANT EQUIVALENCE FOR LOCAL ENVIRONMENTS ON REFERRED ENTRIES ***)
  20
  21 definition reqx: relation3 … ≝
  22            rex cdeq.
  23
  24 interpretation
  25   "sort-irrelevant equivalence on referred entries (local environment)"
  26   'StarEqSn T L1 L2 = (reqx T L1 L2).
  27
  28 interpretation
  29   "sort-irrelevant ranged equivalence (local environment)"
  30   'StarEqSn f L1 L2 = (sex cdeq_ext cfull f L1 L2).
  31
  32 (* Basic properties ***********************************************************)
  33
  34 lemma frees_teqx_conf_reqx:
  35       ∀f,L1,T1. L1 ⊢ 𝐅+❪T1❫ ≘ f → ∀T2. T1 ≛ T2 →
  36       ∀L2. L1 ≛[f] L2 → L2 ⊢ 𝐅+❪T2❫ ≘ f.
  37 #f #L1 #T1 #H elim H -f -L1 -T1
  38 [ #f #L1 #s1 #Hf #X #H1 #L2 #_
  39   elim (teqx_inv_sort1 … H1) -H1 #s2 #H destruct
  40   /2 width=3 by frees_sort/
  41 | #f #i #Hf #X #H1
  42   >(teqx_inv_lref1 … H1) -X #Y #H2
  43   >(sex_inv_atom1 … H2) -Y
  44   /2 width=1 by frees_atom/
  45 | #f #I #L1 #V1 #_ #IH #X #H1
  46   >(teqx_inv_lref1 … H1) -X #Y #H2
  47   elim (sex_inv_next1 … H2) -H2 #Z #L2 #HL12 #HZ #H destruct
  48   elim (ext2_inv_pair_sn … HZ) -HZ #V2 #HV12 #H destruct
  49   /3 width=1 by frees_pair/
  50 | #f #I #L1 #Hf #X #H1
  51   >(teqx_inv_lref1 … H1) -X #Y #H2
  52   elim (sex_inv_next1 … H2) -H2 #Z #L2 #_ #HZ #H destruct
  53   >(ext2_inv_unit_sn … HZ) -Z /2 width=1 by frees_unit/
  54 | #f #I #L1 #i #_ #IH #X #H1
  55   >(teqx_inv_lref1 … H1) -X #Y #H2
  56   elim (sex_inv_push1 … H2) -H2 #J #L2 #HL12 #_ #H destruct
  57   /3 width=1 by frees_lref/
  58 | #f #L1 #l #Hf #X #H1 #L2 #_
  59   >(teqx_inv_gref1 … H1) -X /2 width=1 by frees_gref/
  60 | #f1V #f1T #f1 #p #I #L1 #V1 #T1 #_ #_ #Hf1 #IHV #IHT #X #H1
  61   elim (teqx_inv_pair1 … H1) -H1 #V2 #T2 #HV12 #HT12 #H1 #L2 #HL12 destruct
  62   /6 width=5 by frees_bind, sex_inv_tl, ext2_pair, sle_sex_trans, sor_inv_sle_dx, sor_inv_sle_sn/
  63 | #f1V #f1T #f1 #I #L1 #V1 #T1 #_ #_ #Hf1 #IHV #IHT #X #H1
  64   elim (teqx_inv_pair1 … H1) -H1 #V2 #T2 #HV12 #HT12 #H1 #L2 #HL12 destruct
  65   /5 width=5 by frees_flat, sle_sex_trans, sor_inv_sle_dx, sor_inv_sle_sn/
  66 ]
  67 qed-.
  68
  69 lemma frees_teqx_conf:
  70       ∀f,L,T1. L ⊢ 𝐅+❪T1❫ ≘ f →
  71       ∀T2. T1 ≛ T2 → L ⊢ 𝐅+❪T2❫ ≘ f.
  72 /4 width=7 by frees_teqx_conf_reqx, sex_refl, ext2_refl/ qed-.
  73
  74 lemma frees_reqx_conf:
  75       ∀f,L1,T. L1 ⊢ 𝐅+❪T❫ ≘ f →
  76       ∀L2. L1 ≛[f] L2 → L2 ⊢ 𝐅+❪T❫ ≘ f.
  77 /2 width=7 by frees_teqx_conf_reqx, teqx_refl/ qed-.
  78
  79 lemma teqx_rex_conf_sn (R):
  80       s_r_confluent1 … cdeq (rex R).
  81 #R #L1 #T1 #T2 #HT12 #L2 *
  82 /3 width=5 by frees_teqx_conf, ex2_intro/
  83 qed-.
  84
  85 lemma teqx_rex_div (R):
  86       ∀T1,T2. T1 ≛ T2 →
  87       ∀L1,L2. L1 ⪤[R,T2] L2 → L1 ⪤[R,T1] L2.
  88 /3 width=5 by teqx_rex_conf_sn, teqx_sym/ qed-.
  89
  90 lemma teqx_reqx_conf_sn:
  91       s_r_confluent1 … cdeq reqx.
  92 /2 width=5 by teqx_rex_conf_sn/ qed-.
  93
  94 lemma teqx_reqx_div:
  95       ∀T1,T2. T1 ≛ T2 →
  96       ∀L1,L2. L1 ≛[T2] L2 → L1 ≛[T1] L2.
  97 /2 width=5 by teqx_rex_div/ qed-.
  98
  99 lemma reqx_atom: ∀I. ⋆ ≛[⓪[I]] ⋆.
 100 /2 width=1 by rex_atom/ qed.
 101
 102 lemma reqx_sort:
 103       ∀I1,I2,L1,L2,s.
 104       L1 ≛[⋆s] L2 → L1.ⓘ[I1] ≛[⋆s] L2.ⓘ[I2].
 105 /2 width=1 by rex_sort/ qed.
 106
 107 lemma reqx_pair:
 108       ∀I,L1,L2,V1,V2.
 109       L1 ≛[V1] L2 → V1 ≛ V2 → L1.ⓑ[I]V1 ≛[#0] L2.ⓑ[I]V2.
 110 /2 width=1 by rex_pair/ qed.
 111
 112 lemma reqx_unit:
 113       ∀f,I,L1,L2. 𝐈❪f❫ → L1 ≛[f] L2 →
 114       L1.ⓤ[I] ≛[#0] L2.ⓤ[I].
 115 /2 width=3 by rex_unit/ qed.
 116
 117 lemma reqx_lref:
 118       ∀I1,I2,L1,L2,i.
 119       L1 ≛[#i] L2 → L1.ⓘ[I1] ≛[#↑i] L2.ⓘ[I2].
 120 /2 width=1 by rex_lref/ qed.
 121
 122 lemma reqx_gref:
 123       ∀I1,I2,L1,L2,l.
 124       L1 ≛[§l] L2 → L1.ⓘ[I1] ≛[§l] L2.ⓘ[I2].
 125 /2 width=1 by rex_gref/ qed.
 126
 127 lemma reqx_bind_repl_dx:
 128       ∀I,I1,L1,L2.∀T:term. L1.ⓘ[I] ≛[T] L2.ⓘ[I1] →
 129       ∀I2. I ≛ I2 → L1.ⓘ[I] ≛[T] L2.ⓘ[I2].
 130 /2 width=2 by rex_bind_repl_dx/ qed-.
 131
 132 (* Basic inversion lemmas ***************************************************)
 133
 134 lemma reqx_inv_atom_sn:
 135       ∀Y2. ∀T:term. ⋆ ≛[T] Y2 → Y2 = ⋆.
 136 /2 width=3 by rex_inv_atom_sn/ qed-.
 137
 138 lemma reqx_inv_atom_dx:
 139       ∀Y1. ∀T:term. Y1 ≛[T] ⋆ → Y1 = ⋆.
 140 /2 width=3 by rex_inv_atom_dx/ qed-.
 141
 142 lemma reqx_inv_zero:
 143       ∀Y1,Y2. Y1 ≛[#0] Y2 →
 144       ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
 145        | ∃∃I,L1,L2,V1,V2. L1 ≛[V1] L2 & V1 ≛ V2 & Y1 = L1.ⓑ[I]V1 & Y2 = L2.ⓑ[I]V2
 146        | ∃∃f,I,L1,L2. 𝐈❪f❫ & L1 ≛[f] L2 & Y1 = L1.ⓤ[I] & Y2 = L2.ⓤ[I].
 147 #Y1 #Y2 #H elim (rex_inv_zero … H) -H *
 148 /3 width=9 by or3_intro0, or3_intro1, or3_intro2, ex4_5_intro, ex4_4_intro, conj/
 149 qed-.
 150
 151 lemma reqx_inv_lref:
 152       ∀Y1,Y2,i. Y1 ≛[#↑i] Y2 →
 153       ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
 154        | ∃∃I1,I2,L1,L2. L1 ≛[#i] L2 & Y1 = L1.ⓘ[I1] & Y2 = L2.ⓘ[I2].
 155 /2 width=1 by rex_inv_lref/ qed-.
 156
 157 (* Basic_2A1: uses: lleq_inv_bind lleq_inv_bind_O *)
 158 lemma reqx_inv_bind:
 159       ∀p,I,L1,L2,V,T. L1 ≛[ⓑ[p,I]V.T] L2 →
 160       ∧∧ L1 ≛[V] L2 & L1.ⓑ[I]V ≛[T] L2.ⓑ[I]V.
 161 /2 width=2 by rex_inv_bind/ qed-.
 162
 163 (* Basic_2A1: uses: lleq_inv_flat *)
 164 lemma reqx_inv_flat:
 165       ∀I,L1,L2,V,T. L1 ≛[ⓕ[I]V.T] L2 →
 166       ∧∧ L1 ≛[V] L2 & L1 ≛[T] L2.
 167 /2 width=2 by rex_inv_flat/ qed-.
 168
 169 (* Advanced inversion lemmas ************************************************)
 170
 171 lemma reqx_inv_zero_pair_sn:
 172       ∀I,Y2,L1,V1. L1.ⓑ[I]V1 ≛[#0] Y2 →
 173       ∃∃L2,V2. L1 ≛[V1] L2 & V1 ≛ V2 & Y2 = L2.ⓑ[I]V2.
 174 /2 width=1 by rex_inv_zero_pair_sn/ qed-.
 175
 176 lemma reqx_inv_zero_pair_dx:
 177       ∀I,Y1,L2,V2. Y1 ≛[#0] L2.ⓑ[I]V2 →
 178       ∃∃L1,V1. L1 ≛[V1] L2 & V1 ≛ V2 & Y1 = L1.ⓑ[I]V1.
 179 /2 width=1 by rex_inv_zero_pair_dx/ qed-.
 180
 181 lemma reqx_inv_lref_bind_sn:
 182       ∀I1,Y2,L1,i. L1.ⓘ[I1] ≛[#↑i] Y2 →
 183       ∃∃I2,L2. L1 ≛[#i] L2 & Y2 = L2.ⓘ[I2].
 184 /2 width=2 by rex_inv_lref_bind_sn/ qed-.
 185
 186 lemma reqx_inv_lref_bind_dx:
 187       ∀I2,Y1,L2,i. Y1 ≛[#↑i] L2.ⓘ[I2] →
 188       ∃∃I1,L1. L1 ≛[#i] L2 & Y1 = L1.ⓘ[I1].
 189 /2 width=2 by rex_inv_lref_bind_dx/ qed-.
 190
 191 (* Basic forward lemmas *****************************************************)
 192
 193 lemma reqx_fwd_zero_pair:
 194       ∀I,K1,K2,V1,V2.
 195       K1.ⓑ[I]V1 ≛[#0] K2.ⓑ[I]V2 → K1 ≛[V1] K2.
 196 /2 width=3 by rex_fwd_zero_pair/ qed-.
 197
 198 (* Basic_2A1: uses: lleq_fwd_bind_sn lleq_fwd_flat_sn *)
 199 lemma reqx_fwd_pair_sn:
 200       ∀I,L1,L2,V,T. L1 ≛[②[I]V.T] L2 → L1 ≛[V] L2.
 201 /2 width=3 by rex_fwd_pair_sn/ qed-.
 202
 203 (* Basic_2A1: uses: lleq_fwd_bind_dx lleq_fwd_bind_O_dx *)
 204 lemma reqx_fwd_bind_dx:
 205       ∀p,I,L1,L2,V,T.
 206       L1 ≛[ⓑ[p,I]V.T] L2 → L1.ⓑ[I]V ≛[T] L2.ⓑ[I]V.
 207 /2 width=2 by rex_fwd_bind_dx/ qed-.
 208
 209 (* Basic_2A1: uses: lleq_fwd_flat_dx *)
 210 lemma reqx_fwd_flat_dx:
 211       ∀I,L1,L2,V,T. L1 ≛[ⓕ[I]V.T] L2 → L1 ≛[T] L2.
 212 /2 width=3 by rex_fwd_flat_dx/ qed-.
 213
 214 lemma reqx_fwd_dx:
 215       ∀I2,L1,K2. ∀T:term. L1 ≛[T] K2.ⓘ[I2] →
 216       ∃∃I1,K1. L1 = K1.ⓘ[I1].
 217 /2 width=5 by rex_fwd_dx/ qed-.