matita/matita/contribs/lambdadelta/static_2/static/reqx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/notation/relations/stareqsn_3.ma".
  16 include "static_2/syntax/teqx_ext.ma".
  17 include "static_2/static/rex.ma".
  18
  19 (* SORT-IRRELEVANT EQUIVALENCE FOR LOCAL ENVIRONMENTS ON REFERRED ENTRIES ***)
  20
  21 definition reqx: relation3 term lenv lenv ≝
  22                  rex cdeq.
  23
  24 interpretation
  25    "sort-irrelevant equivalence on referred entries (local environment)"
  26    'StarEqSn T L1 L2 = (reqx T L1 L2).
  27
  28 interpretation
  29    "sort-irrelevant ranged equivalence (local environment)"
  30    'StarEqSn f L1 L2 = (sex cdeq_ext cfull f L1 L2).
  31
  32 (* Basic properties ***********************************************************)
  33
  34 lemma frees_teqx_conf_reqx: ∀f,L1,T1. L1 ⊢ 𝐅+❪T1❫ ≘ f → ∀T2. T1 ≛ T2 →
  35                             ∀L2. L1 ≛[f] L2 → L2 ⊢ 𝐅+❪T2❫ ≘ f.
  36 #f #L1 #T1 #H elim H -f -L1 -T1
  37 [ #f #L1 #s1 #Hf #X #H1 #L2 #_
  38   elim (teqx_inv_sort1 … H1) -H1 #s2 #H destruct
  39   /2 width=3 by frees_sort/
  40 | #f #i #Hf #X #H1
  41   >(teqx_inv_lref1 … H1) -X #Y #H2
  42   >(sex_inv_atom1 … H2) -Y
  43   /2 width=1 by frees_atom/
  44 | #f #I #L1 #V1 #_ #IH #X #H1
  45   >(teqx_inv_lref1 … H1) -X #Y #H2
  46   elim (sex_inv_next1 … H2) -H2 #Z #L2 #HL12 #HZ #H destruct
  47   elim (ext2_inv_pair_sn … HZ) -HZ #V2 #HV12 #H destruct
  48   /3 width=1 by frees_pair/
  49 | #f #I #L1 #Hf #X #H1
  50   >(teqx_inv_lref1 … H1) -X #Y #H2
  51   elim (sex_inv_next1 … H2) -H2 #Z #L2 #_ #HZ #H destruct
  52   >(ext2_inv_unit_sn … HZ) -Z /2 width=1 by frees_unit/
  53 | #f #I #L1 #i #_ #IH #X #H1
  54   >(teqx_inv_lref1 … H1) -X #Y #H2
  55   elim (sex_inv_push1 … H2) -H2 #J #L2 #HL12 #_ #H destruct
  56   /3 width=1 by frees_lref/
  57 | #f #L1 #l #Hf #X #H1 #L2 #_
  58   >(teqx_inv_gref1 … H1) -X /2 width=1 by frees_gref/
  59 | #f1V #f1T #f1 #p #I #L1 #V1 #T1 #_ #_ #Hf1 #IHV #IHT #X #H1
  60   elim (teqx_inv_pair1 … H1) -H1 #V2 #T2 #HV12 #HT12 #H1 #L2 #HL12 destruct
  61   /6 width=5 by frees_bind, sex_inv_tl, ext2_pair, sle_sex_trans, sor_inv_sle_dx, sor_inv_sle_sn/
  62 | #f1V #f1T #f1 #I #L1 #V1 #T1 #_ #_ #Hf1 #IHV #IHT #X #H1
  63   elim (teqx_inv_pair1 … H1) -H1 #V2 #T2 #HV12 #HT12 #H1 #L2 #HL12 destruct
  64   /5 width=5 by frees_flat, sle_sex_trans, sor_inv_sle_dx, sor_inv_sle_sn/
  65 ]
  66 qed-.
  67
  68 lemma frees_teqx_conf: ∀f,L,T1. L ⊢ 𝐅+❪T1❫ ≘ f →
  69                        ∀T2. T1 ≛ T2 → L ⊢ 𝐅+❪T2❫ ≘ f.
  70 /4 width=7 by frees_teqx_conf_reqx, sex_refl, ext2_refl/ qed-.
  71
  72 lemma frees_reqx_conf: ∀f,L1,T. L1 ⊢ 𝐅+❪T❫ ≘ f →
  73                        ∀L2. L1 ≛[f] L2 → L2 ⊢ 𝐅+❪T❫ ≘ f.
  74 /2 width=7 by frees_teqx_conf_reqx, teqx_refl/ qed-.
  75
  76 lemma teqx_rex_conf (R): s_r_confluent1 … cdeq (rex R).
  77 #R #L1 #T1 #T2 #HT12 #L2 *
  78 /3 width=5 by frees_teqx_conf, ex2_intro/
  79 qed-.
  80
  81 lemma teqx_rex_div (R): ∀T1,T2. T1 ≛ T2 →
  82                         ∀L1,L2. L1 ⪤[R,T2] L2 → L1 ⪤[R,T1] L2.
  83 /3 width=5 by teqx_rex_conf, teqx_sym/ qed-.
  84
  85 lemma teqx_reqx_conf: s_r_confluent1 … cdeq reqx.
  86 /2 width=5 by teqx_rex_conf/ qed-.
  87
  88 lemma teqx_reqx_div: ∀T1,T2. T1 ≛ T2 →
  89                      ∀L1,L2. L1 ≛[T2] L2 → L1 ≛[T1] L2.
  90 /2 width=5 by teqx_rex_div/ qed-.
  91
  92 lemma reqx_atom: ∀I. ⋆ ≛[⓪[I]] ⋆.
  93 /2 width=1 by rex_atom/ qed.
  94
  95 lemma reqx_sort: ∀I1,I2,L1,L2,s.
  96                  L1 ≛[⋆s] L2 → L1.ⓘ[I1] ≛[⋆s] L2.ⓘ[I2].
  97 /2 width=1 by rex_sort/ qed.
  98
  99 lemma reqx_pair: ∀I,L1,L2,V1,V2.
 100                  L1 ≛[V1] L2 → V1 ≛ V2 → L1.ⓑ[I]V1 ≛[#0] L2.ⓑ[I]V2.
 101 /2 width=1 by rex_pair/ qed.
 102
 103 lemma reqx_unit: ∀f,I,L1,L2. 𝐈❪f❫ → L1 ≛[f] L2 →
 104                  L1.ⓤ[I] ≛[#0] L2.ⓤ[I].
 105 /2 width=3 by rex_unit/ qed.
 106
 107 lemma reqx_lref: ∀I1,I2,L1,L2,i.
 108                  L1 ≛[#i] L2 → L1.ⓘ[I1] ≛[#↑i] L2.ⓘ[I2].
 109 /2 width=1 by rex_lref/ qed.
 110
 111 lemma reqx_gref: ∀I1,I2,L1,L2,l.
 112                  L1 ≛[§l] L2 → L1.ⓘ[I1] ≛[§l] L2.ⓘ[I2].
 113 /2 width=1 by rex_gref/ qed.
 114
 115 lemma reqx_bind_repl_dx: ∀I,I1,L1,L2.∀T:term.
 116                          L1.ⓘ[I] ≛[T] L2.ⓘ[I1] →
 117                          ∀I2. I ≛ I2 →
 118                          L1.ⓘ[I] ≛[T] L2.ⓘ[I2].
 119 /2 width=2 by rex_bind_repl_dx/ qed-.
 120
 121 (* Basic inversion lemmas ***************************************************)
 122
 123 lemma reqx_inv_atom_sn: ∀Y2. ∀T:term. ⋆ ≛[T] Y2 → Y2 = ⋆.
 124 /2 width=3 by rex_inv_atom_sn/ qed-.
 125
 126 lemma reqx_inv_atom_dx: ∀Y1. ∀T:term. Y1 ≛[T] ⋆ → Y1 = ⋆.
 127 /2 width=3 by rex_inv_atom_dx/ qed-.
 128
 129 lemma reqx_inv_zero:
 130       ∀Y1,Y2. Y1 ≛[#0] Y2 →
 131       ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
 132        | ∃∃I,L1,L2,V1,V2. L1 ≛[V1] L2 & V1 ≛ V2 & Y1 = L1.ⓑ[I]V1 & Y2 = L2.ⓑ[I]V2
 133        | ∃∃f,I,L1,L2. 𝐈❪f❫ & L1 ≛[f] L2 & Y1 = L1.ⓤ[I] & Y2 = L2.ⓤ[I].
 134 #Y1 #Y2 #H elim (rex_inv_zero … H) -H *
 135 /3 width=9 by or3_intro0, or3_intro1, or3_intro2, ex4_5_intro, ex4_4_intro, conj/
 136 qed-.
 137
 138 lemma reqx_inv_lref: ∀Y1,Y2,i. Y1 ≛[#↑i] Y2 →
 139                      ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
 140                       | ∃∃I1,I2,L1,L2. L1 ≛[#i] L2 &
 141                                        Y1 = L1.ⓘ[I1] & Y2 = L2.ⓘ[I2].
 142 /2 width=1 by rex_inv_lref/ qed-.
 143
 144 (* Basic_2A1: uses: lleq_inv_bind lleq_inv_bind_O *)
 145 lemma reqx_inv_bind: ∀p,I,L1,L2,V,T. L1 ≛[ⓑ[p,I]V.T] L2 →
 146                      ∧∧ L1 ≛[V] L2 & L1.ⓑ[I]V ≛[T] L2.ⓑ[I]V.
 147 /2 width=2 by rex_inv_bind/ qed-.
 148
 149 (* Basic_2A1: uses: lleq_inv_flat *)
 150 lemma reqx_inv_flat: ∀I,L1,L2,V,T. L1 ≛[ⓕ[I]V.T] L2 →
 151                      ∧∧ L1 ≛[V] L2 & L1 ≛[T] L2.
 152 /2 width=2 by rex_inv_flat/ qed-.
 153
 154 (* Advanced inversion lemmas ************************************************)
 155
 156 lemma reqx_inv_zero_pair_sn: ∀I,Y2,L1,V1. L1.ⓑ[I]V1 ≛[#0] Y2 →
 157                              ∃∃L2,V2. L1 ≛[V1] L2 & V1 ≛ V2 & Y2 = L2.ⓑ[I]V2.
 158 /2 width=1 by rex_inv_zero_pair_sn/ qed-.
 159
 160 lemma reqx_inv_zero_pair_dx: ∀I,Y1,L2,V2. Y1 ≛[#0] L2.ⓑ[I]V2 →
 161                              ∃∃L1,V1. L1 ≛[V1] L2 & V1 ≛ V2 & Y1 = L1.ⓑ[I]V1.
 162 /2 width=1 by rex_inv_zero_pair_dx/ qed-.
 163
 164 lemma reqx_inv_lref_bind_sn: ∀I1,Y2,L1,i. L1.ⓘ[I1] ≛[#↑i] Y2 →
 165                              ∃∃I2,L2. L1 ≛[#i] L2 & Y2 = L2.ⓘ[I2].
 166 /2 width=2 by rex_inv_lref_bind_sn/ qed-.
 167
 168 lemma reqx_inv_lref_bind_dx: ∀I2,Y1,L2,i. Y1 ≛[#↑i] L2.ⓘ[I2] →
 169                              ∃∃I1,L1. L1 ≛[#i] L2 & Y1 = L1.ⓘ[I1].
 170 /2 width=2 by rex_inv_lref_bind_dx/ qed-.
 171
 172 (* Basic forward lemmas *****************************************************)
 173
 174 lemma reqx_fwd_zero_pair: ∀I,K1,K2,V1,V2.
 175                           K1.ⓑ[I]V1 ≛[#0] K2.ⓑ[I]V2 → K1 ≛[V1] K2.
 176 /2 width=3 by rex_fwd_zero_pair/ qed-.
 177
 178 (* Basic_2A1: uses: lleq_fwd_bind_sn lleq_fwd_flat_sn *)
 179 lemma reqx_fwd_pair_sn: ∀I,L1,L2,V,T. L1 ≛[②[I]V.T] L2 → L1 ≛[V] L2.
 180 /2 width=3 by rex_fwd_pair_sn/ qed-.
 181
 182 (* Basic_2A1: uses: lleq_fwd_bind_dx lleq_fwd_bind_O_dx *)
 183 lemma reqx_fwd_bind_dx: ∀p,I,L1,L2,V,T.
 184                         L1 ≛[ⓑ[p,I]V.T] L2 → L1.ⓑ[I]V ≛[T] L2.ⓑ[I]V.
 185 /2 width=2 by rex_fwd_bind_dx/ qed-.
 186
 187 (* Basic_2A1: uses: lleq_fwd_flat_dx *)
 188 lemma reqx_fwd_flat_dx: ∀I,L1,L2,V,T. L1 ≛[ⓕ[I]V.T] L2 → L1 ≛[T] L2.
 189 /2 width=3 by rex_fwd_flat_dx/ qed-.
 190
 191 lemma reqx_fwd_dx: ∀I2,L1,K2. ∀T:term. L1 ≛[T] K2.ⓘ[I2] →
 192                    ∃∃I1,K1. L1 = K1.ⓘ[I1].
 193 /2 width=5 by rex_fwd_dx/ qed-.