matita/matita/contribs/lambdadelta/static_2/static/rex.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_1_2.ma".
  16 include "ground/xoa/ex_3_4.ma".
  17 include "ground/xoa/ex_4_4.ma".
  18 include "ground/xoa/ex_4_5.ma".
  19 include "ground/relocation/rtmap_id.ma".
  20 include "static_2/notation/relations/relation_4.ma".
  21 include "static_2/syntax/cext2.ma".
  22 include "static_2/relocation/sex.ma".
  23 include "static_2/static/frees.ma".
  24
  25 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  26
  27 definition rex (R) (T): relation lenv ≝
  28                λL1,L2. ∃∃f. L1 ⊢ 𝐅+❪T❫ ≘ f & L1 ⪤[cext2 R,cfull,f] L2.
  29
  30 interpretation "generic extension on referred entries (local environment)"
  31    'Relation R T L1 L2 = (rex R T L1 L2).
  32
  33 definition R_confluent2_rex:
  34            relation4 (relation3 lenv term term)
  35                      (relation3 lenv term term) … ≝
  36            λR1,R2,RP1,RP2.
  37            ∀L0,T0,T1. R1 L0 T0 T1 → ∀T2. R2 L0 T0 T2 →
  38            ∀L1. L0 ⪤[RP1,T0] L1 → ∀L2. L0 ⪤[RP2,T0] L2 →
  39            ∃∃T. R2 L1 T1 T & R1 L2 T2 T.
  40
  41 definition R_replace3_rex:
  42            relation4 (relation3 lenv term term)
  43                      (relation3 lenv term term) … ≝
  44            λR1,R2,RP1,RP2.
  45            ∀L0,T0,T1. R1 L0 T0 T1 → ∀T2. R2 L0 T0 T2 →
  46            ∀L1. L0 ⪤[RP1,T0] L1 → ∀L2. L0 ⪤[RP2,T0] L2 →
  47            ∀T. R2 L1 T1 T → R1 L2 T2 T.
  48
  49 definition rex_confluent: relation … ≝
  50            λR1,R2.
  51            ∀K1,K,V1. K1 ⪤[R1,V1] K → ∀V. R1 K1 V1 V →
  52            ∀K2. K ⪤[R2,V] K2 → K ⪤[R2,V1] K2.
  53
  54 definition rex_transitive: relation3 ? (relation3 ?? term) … ≝
  55            λR1,R2,R3.
  56            ∀K1,K,V1. K1 ⪤[R1,V1] K →
  57            ∀V. R1 K1 V1 V → ∀V2. R2 K V V2 → R3 K1 V1 V2.
  58
  59 (* Basic inversion lemmas ***************************************************)
  60
  61 lemma rex_inv_atom_sn (R): ∀Y2,T. ⋆ ⪤[R,T] Y2 → Y2 = ⋆.
  62 #R #Y2 #T * /2 width=4 by sex_inv_atom1/
  63 qed-.
  64
  65 lemma rex_inv_atom_dx (R): ∀Y1,T. Y1 ⪤[R,T] ⋆ → Y1 = ⋆.
  66 #R #I #Y1 * /2 width=4 by sex_inv_atom2/
  67 qed-.
  68
  69 lemma rex_inv_sort (R):
  70       ∀Y1,Y2,s. Y1 ⪤[R,⋆s] Y2 →
  71       ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
  72        | ∃∃I1,I2,L1,L2. L1 ⪤[R,⋆s] L2 & Y1 = L1.ⓘ[I1] & Y2 = L2.ⓘ[I2].
  73 #R * [ | #Y1 #I1 ] #Y2 #s * #f #H1 #H2
  74 [ lapply (sex_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
  75 | lapply (frees_inv_sort … H1) -H1 #Hf
  76   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
  77   elim (sex_inv_push1 … H2) -H2 #I2 #L2 #H12 #_ #H destruct
  78   /5 width=7 by frees_sort, ex3_4_intro, ex2_intro, or_intror/
  79 ]
  80 qed-.
  81
  82 lemma rex_inv_zero (R):
  83       ∀Y1,Y2. Y1 ⪤[R,#0] Y2 →
  84       ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
  85        | ∃∃I,L1,L2,V1,V2. L1 ⪤[R,V1] L2 & R L1 V1 V2 &
  86            Y1 = L1.ⓑ[I]V1 & Y2 = L2.ⓑ[I]V2
  87        | ∃∃f,I,L1,L2. 𝐈❪f❫ & L1 ⪤[cext2 R,cfull,f] L2 &
  88            Y1 = L1.ⓤ[I] & Y2 = L2.ⓤ[I].
  89 #R * [ | #Y1 * #I1 [ | #X ] ] #Y2 * #f #H1 #H2
  90 [ lapply (sex_inv_atom1 … H2) -H2 /3 width=1 by or3_intro0, conj/
  91 | elim (frees_inv_unit … H1) -H1 #g #HX #H destruct
  92   elim (sex_inv_next1 … H2) -H2 #I2 #L2 #HL12 #H #H2 destruct
  93   >(ext2_inv_unit_sn … H) -H /3 width=8 by or3_intro2, ex4_4_intro/
  94 | elim (frees_inv_pair … H1) -H1 #g #Hg #H destruct
  95   elim (sex_inv_next1 … H2) -H2 #Z2 #L2 #HL12 #H
  96   elim (ext2_inv_pair_sn … H) -H
  97   /4 width=9 by or3_intro1, ex4_5_intro, ex2_intro/
  98 ]
  99 qed-.
 100
 101 lemma rex_inv_lref (R):
 102       ∀Y1,Y2,i. Y1 ⪤[R,#↑i] Y2 →
 103       ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
 104        | ∃∃I1,I2,L1,L2. L1 ⪤[R,#i] L2 & Y1 = L1.ⓘ[I1] & Y2 = L2.ⓘ[I2].
 105 #R * [ | #Y1 #I1 ] #Y2 #i * #f #H1 #H2
 106 [ lapply (sex_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 107 | elim (frees_inv_lref … H1) -H1 #g #Hg #H destruct
 108   elim (sex_inv_push1 … H2) -H2
 109   /4 width=7 by ex3_4_intro, ex2_intro, or_intror/
 110 ]
 111 qed-.
 112
 113 lemma rex_inv_gref (R):
 114       ∀Y1,Y2,l. Y1 ⪤[R,§l] Y2 →
 115       ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
 116        | ∃∃I1,I2,L1,L2. L1 ⪤[R,§l] L2 & Y1 = L1.ⓘ[I1] & Y2 = L2.ⓘ[I2].
 117 #R * [ | #Y1 #I1 ] #Y2 #l * #f #H1 #H2
 118 [ lapply (sex_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 119 | lapply (frees_inv_gref … H1) -H1 #Hf
 120   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
 121   elim (sex_inv_push1 … H2) -H2 #I2 #L2 #H12 #_ #H destruct
 122   /5 width=7 by frees_gref, ex3_4_intro, ex2_intro, or_intror/
 123 ]
 124 qed-.
 125
 126 (* Basic_2A1: uses: llpx_sn_inv_bind llpx_sn_inv_bind_O *)
 127 lemma rex_inv_bind (R):
 128       ∀p,I,L1,L2,V1,V2,T. L1 ⪤[R,ⓑ[p,I]V1.T] L2 → R L1 V1 V2 →
 129       ∧∧ L1 ⪤[R,V1] L2 & L1.ⓑ[I]V1 ⪤[R,T] L2.ⓑ[I]V2.
 130 #R #p #I #L1 #L2 #V1 #V2 #T * #f #Hf #HL #HV elim (frees_inv_bind … Hf) -Hf
 131 /6 width=6 by sle_sex_trans, sex_inv_tl, ext2_pair, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 132 qed-.
 133
 134 (* Basic_2A1: uses: llpx_sn_inv_flat *)
 135 lemma rex_inv_flat (R):
 136       ∀I,L1,L2,V,T. L1 ⪤[R,ⓕ[I]V.T] L2 →
 137       ∧∧ L1 ⪤[R,V] L2 & L1 ⪤[R,T] L2.
 138 #R #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_flat … Hf) -Hf
 139 /5 width=6 by sle_sex_trans, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 140 qed-.
 141
 142 (* Advanced inversion lemmas ************************************************)
 143
 144 lemma rex_inv_sort_bind_sn (R):
 145       ∀I1,K1,L2,s. K1.ⓘ[I1] ⪤[R,⋆s] L2 →
 146       ∃∃I2,K2. K1 ⪤[R,⋆s] K2 & L2 = K2.ⓘ[I2].
 147 #R #I1 #K1 #L2 #s #H elim (rex_inv_sort … H) -H *
 148 [ #H destruct
 149 | #Z1 #I2 #Y1 #K2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 150 ]
 151 qed-.
 152
 153 lemma rex_inv_sort_bind_dx (R):
 154       ∀I2,K2,L1,s. L1 ⪤[R,⋆s] K2.ⓘ[I2] →
 155       ∃∃I1,K1. K1 ⪤[R,⋆s] K2 & L1 = K1.ⓘ[I1].
 156 #R #I2 #K2 #L1 #s #H elim (rex_inv_sort … H) -H *
 157 [ #_ #H destruct
 158 | #I1 #Z2 #K1 #Y2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 159 ]
 160 qed-.
 161
 162 lemma rex_inv_zero_pair_sn (R):
 163       ∀I,L2,K1,V1. K1.ⓑ[I]V1 ⪤[R,#0] L2 →
 164       ∃∃K2,V2. K1 ⪤[R,V1] K2 & R K1 V1 V2 & L2 = K2.ⓑ[I]V2.
 165 #R #I #L2 #K1 #V1 #H elim (rex_inv_zero … H) -H *
 166 [ #H destruct
 167 | #Z #Y1 #K2 #X1 #V2 #HK12 #HV12 #H1 #H2 destruct
 168   /2 width=5 by ex3_2_intro/
 169 | #f #Z #Y1 #Y2 #_ #_ #H destruct
 170 ]
 171 qed-.
 172
 173 lemma rex_inv_zero_pair_dx (R):
 174       ∀I,L1,K2,V2. L1 ⪤[R,#0] K2.ⓑ[I]V2 →
 175       ∃∃K1,V1. K1 ⪤[R,V1] K2 & R K1 V1 V2 & L1 = K1.ⓑ[I]V1.
 176 #R #I #L1 #K2 #V2 #H elim (rex_inv_zero … H) -H *
 177 [ #_ #H destruct
 178 | #Z #K1 #Y2 #V1 #X2 #HK12 #HV12 #H1 #H2 destruct
 179   /2 width=5 by ex3_2_intro/
 180 | #f #Z #Y1 #Y2 #_ #_ #_ #H destruct
 181 ]
 182 qed-.
 183
 184 lemma rex_inv_zero_unit_sn (R):
 185       ∀I,K1,L2. K1.ⓤ[I] ⪤[R,#0] L2 →
 186       ∃∃f,K2. 𝐈❪f❫ & K1 ⪤[cext2 R,cfull,f] K2 & L2 = K2.ⓤ[I].
 187 #R #I #K1 #L2 #H elim (rex_inv_zero … H) -H *
 188 [ #H destruct
 189 | #Z #Y1 #Y2 #X1 #X2 #_ #_ #H destruct
 190 | #f #Z #Y1 #K2 #Hf #HK12 #H1 #H2 destruct /2 width=5 by ex3_2_intro/
 191 ]
 192 qed-.
 193
 194 lemma rex_inv_zero_unit_dx (R):
 195       ∀I,L1,K2. L1 ⪤[R,#0] K2.ⓤ[I] →
 196       ∃∃f,K1. 𝐈❪f❫ & K1 ⪤[cext2 R,cfull,f] K2 & L1 = K1.ⓤ[I].
 197 #R #I #L1 #K2 #H elim (rex_inv_zero … H) -H *
 198 [ #_ #H destruct
 199 | #Z #Y1 #Y2 #X1 #X2 #_ #_ #_ #H destruct
 200 | #f #Z #K1 #Y2 #Hf #HK12 #H1 #H2 destruct /2 width=5 by ex3_2_intro/
 201 ]
 202 qed-.
 203
 204 lemma rex_inv_lref_bind_sn (R):
 205       ∀I1,K1,L2,i. K1.ⓘ[I1] ⪤[R,#↑i] L2 →
 206       ∃∃I2,K2. K1 ⪤[R,#i] K2 & L2 = K2.ⓘ[I2].
 207 #R #I1 #K1 #L2 #i #H elim (rex_inv_lref … H) -H *
 208 [ #H destruct
 209 | #Z1 #I2 #Y1 #K2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 210 ]
 211 qed-.
 212
 213 lemma rex_inv_lref_bind_dx (R):
 214       ∀I2,K2,L1,i. L1 ⪤[R,#↑i] K2.ⓘ[I2] →
 215       ∃∃I1,K1. K1 ⪤[R,#i] K2 & L1 = K1.ⓘ[I1].
 216 #R #I2 #K2 #L1 #i #H elim (rex_inv_lref … H) -H *
 217 [ #_ #H destruct
 218 | #I1 #Z2 #K1 #Y2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 219 ]
 220 qed-.
 221
 222 lemma rex_inv_gref_bind_sn (R):
 223       ∀I1,K1,L2,l. K1.ⓘ[I1] ⪤[R,§l] L2 →
 224       ∃∃I2,K2. K1 ⪤[R,§l] K2 & L2 = K2.ⓘ[I2].
 225 #R #I1 #K1 #L2 #l #H elim (rex_inv_gref … H) -H *
 226 [ #H destruct
 227 | #Z1 #I2 #Y1 #K2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 228 ]
 229 qed-.
 230
 231 lemma rex_inv_gref_bind_dx (R):
 232       ∀I2,K2,L1,l. L1 ⪤[R,§l] K2.ⓘ[I2] →
 233       ∃∃I1,K1. K1 ⪤[R,§l] K2 & L1 = K1.ⓘ[I1].
 234 #R #I2 #K2 #L1 #l #H elim (rex_inv_gref … H) -H *
 235 [ #_ #H destruct
 236 | #I1 #Z2 #K1 #Y2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 237 ]
 238 qed-.
 239
 240 (* Basic forward lemmas *****************************************************)
 241
 242 lemma rex_fwd_zero_pair (R):
 243       ∀I,K1,K2,V1,V2. K1.ⓑ[I]V1 ⪤[R,#0] K2.ⓑ[I]V2 → K1 ⪤[R,V1] K2.
 244 #R #I #K1 #K2 #V1 #V2 #H
 245 elim (rex_inv_zero_pair_sn … H) -H #Y #X #HK12 #_ #H destruct //
 246 qed-.
 247
 248 (* Basic_2A1: uses: llpx_sn_fwd_pair_sn llpx_sn_fwd_bind_sn llpx_sn_fwd_flat_sn *)
 249 lemma rex_fwd_pair_sn (R): ∀I,L1,L2,V,T. L1 ⪤[R,②[I]V.T] L2 → L1 ⪤[R,V] L2.
 250 #R * [ #p ] #I #L1 #L2 #V #T * #f #Hf #HL
 251 [ elim (frees_inv_bind … Hf) | elim (frees_inv_flat … Hf) ] -Hf
 252 /4 width=6 by sle_sex_trans, sor_inv_sle_sn, ex2_intro/
 253 qed-.
 254
 255 (* Basic_2A1: uses: llpx_sn_fwd_bind_dx llpx_sn_fwd_bind_O_dx *)
 256 lemma rex_fwd_bind_dx (R):
 257       ∀p,I,L1,L2,V1,V2,T. L1 ⪤[R,ⓑ[p,I]V1.T] L2 →
 258       R L1 V1 V2 → L1.ⓑ[I]V1 ⪤[R,T] L2.ⓑ[I]V2.
 259 #R #p #I #L1 #L2 #V1 #V2 #T #H #HV elim (rex_inv_bind … H HV) -H -HV //
 260 qed-.
 261
 262 (* Basic_2A1: uses: llpx_sn_fwd_flat_dx *)
 263 lemma rex_fwd_flat_dx (R): ∀I,L1,L2,V,T. L1 ⪤[R,ⓕ[I]V.T] L2 → L1 ⪤[R,T] L2.
 264 #R #I #L1 #L2 #V #T #H elim (rex_inv_flat … H) -H //
 265 qed-.
 266
 267 lemma rex_fwd_dx (R):
 268       ∀I2,L1,K2,T. L1 ⪤[R,T] K2.ⓘ[I2] →
 269       ∃∃I1,K1. L1 = K1.ⓘ[I1].
 270 #R #I2 #L1 #K2 #T * #f elim (pn_split f) * #g #Hg #_ #Hf destruct
 271 [ elim (sex_inv_push2 … Hf) | elim (sex_inv_next2 … Hf) ] -Hf #I1 #K1 #_ #_ #H destruct
 272 /2 width=3 by ex1_2_intro/
 273 qed-.
 274
 275 (* Basic properties *********************************************************)
 276
 277 lemma rex_atom (R): ∀I. ⋆ ⪤[R,⓪[I]] ⋆.
 278 #R * /3 width=3 by frees_sort, frees_atom, frees_gref, sex_atom, ex2_intro/
 279 qed.
 280
 281 lemma rex_sort (R):
 282       ∀I1,I2,L1,L2,s. L1 ⪤[R,⋆s] L2 → L1.ⓘ[I1] ⪤[R,⋆s] L2.ⓘ[I2].
 283 #R #I1 #I2 #L1 #L2 #s * #f #Hf #H12
 284 lapply (frees_inv_sort … Hf) -Hf
 285 /4 width=3 by frees_sort, sex_push, isid_push, ex2_intro/
 286 qed.
 287
 288 lemma rex_pair (R):
 289       ∀I,L1,L2,V1,V2. L1 ⪤[R,V1] L2 →
 290       R L1 V1 V2 → L1.ⓑ[I]V1 ⪤[R,#0] L2.ⓑ[I]V2.
 291 #R #I1 #I2 #L1 #L2 #V1 *
 292 /4 width=3 by ext2_pair, frees_pair, sex_next, ex2_intro/
 293 qed.
 294
 295 lemma rex_unit (R):
 296       ∀f,I,L1,L2. 𝐈❪f❫ → L1 ⪤[cext2 R,cfull,f] L2 →
 297       L1.ⓤ[I] ⪤[R,#0] L2.ⓤ[I].
 298 /4 width=3 by frees_unit, sex_next, ext2_unit, ex2_intro/ qed.
 299
 300 lemma rex_lref (R):
 301       ∀I1,I2,L1,L2,i. L1 ⪤[R,#i] L2 → L1.ⓘ[I1] ⪤[R,#↑i] L2.ⓘ[I2].
 302 #R #I1 #I2 #L1 #L2 #i * /3 width=3 by sex_push, frees_lref, ex2_intro/
 303 qed.
 304
 305 lemma rex_gref (R):
 306       ∀I1,I2,L1,L2,l. L1 ⪤[R,§l] L2 → L1.ⓘ[I1] ⪤[R,§l] L2.ⓘ[I2].
 307 #R #I1 #I2 #L1 #L2 #l * #f #Hf #H12
 308 lapply (frees_inv_gref … Hf) -Hf
 309 /4 width=3 by frees_gref, sex_push, isid_push, ex2_intro/
 310 qed.
 311
 312 lemma rex_bind_repl_dx (R):
 313       ∀I,I1,L1,L2,T. L1.ⓘ[I] ⪤[R,T] L2.ⓘ[I1] →
 314       ∀I2. cext2 R L1 I I2 → L1.ⓘ[I] ⪤[R,T] L2.ⓘ[I2].
 315 #R #I #I1 #L1 #L2 #T * #f #Hf #HL12 #I2 #HR
 316 /3 width=5 by sex_pair_repl, ex2_intro/
 317 qed-.
 318
 319 (* Basic_2A1: uses: llpx_sn_co *)
 320 lemma rex_co (R1) (R2):
 321       (∀L,T1,T2. R1 L T1 T2 → R2 L T1 T2) →
 322       ∀L1,L2,T. L1 ⪤[R1,T] L2 → L1 ⪤[R2,T] L2.
 323 #R1 #R2 #HR #L1 #L2 #T * /5 width=7 by sex_co, cext2_co, ex2_intro/
 324 qed-.
 325
 326 lemma rex_isid (R1) (R2):
 327       ∀L1,L2,T1,T2.
 328       (∀f. L1 ⊢ 𝐅+❪T1❫ ≘ f → 𝐈❪f❫) →
 329       (∀f. 𝐈❪f❫ → L1 ⊢ 𝐅+❪T2❫ ≘ f) →
 330       L1 ⪤[R1,T1] L2 → L1 ⪤[R2,T2] L2.
 331 #R1 #R2 #L1 #L2 #T1 #T2 #H1 #H2 *
 332 /4 width=7 by sex_co_isid, ex2_intro/
 333 qed-.
 334
 335 lemma rex_unit_sn (R1) (R2):
 336       ∀I,K1,L2. K1.ⓤ[I] ⪤[R1,#0] L2 → K1.ⓤ[I] ⪤[R2,#0] L2.
 337 #R1 #R2 #I #K1 #L2 #H
 338 elim (rex_inv_zero_unit_sn … H) -H #f #K2 #Hf #HK12 #H destruct
 339 /3 width=7 by rex_unit, sex_co_isid/
 340 qed-.
 341
 342 (* Basic_2A1: removed theorems 9:
 343               llpx_sn_skip llpx_sn_lref llpx_sn_free
 344               llpx_sn_fwd_lref
 345               llpx_sn_Y llpx_sn_ge_up llpx_sn_ge
 346               llpx_sn_fwd_drop_sn llpx_sn_fwd_drop_dx
 347 *)