matita/matita/contribs/lambdadelta/static_2/static/rex.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_id.ma".
  16 include "static_2/notation/relations/relation_4.ma".
  17 include "static_2/syntax/cext2.ma".
  18 include "static_2/relocation/sex.ma".
  19 include "static_2/static/frees.ma".
  20
  21 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  22
  23 definition rex (R) (T): relation lenv ≝
  24                λL1,L2. ∃∃f. L1 ⊢ 𝐅+⦃T⦄ ≘ f & L1 ⪤[cext2 R,cfull,f] L2.
  25
  26 interpretation "generic extension on referred entries (local environment)"
  27    'Relation R T L1 L2 = (rex R T L1 L2).
  28
  29 definition R_confluent2_rex: relation4 (relation3 lenv term term)
  30                                        (relation3 lenv term term) … ≝
  31                              λR1,R2,RP1,RP2.
  32                              ∀L0,T0,T1. R1 L0 T0 T1 → ∀T2. R2 L0 T0 T2 →
  33                              ∀L1. L0 ⪤[RP1,T0] L1 → ∀L2. L0 ⪤[RP2,T0] L2 →
  34                              ∃∃T. R2 L1 T1 T & R1 L2 T2 T.
  35
  36 definition rex_confluent: relation … ≝
  37                           λR1,R2.
  38                           ∀K1,K,V1. K1 ⪤[R1,V1] K → ∀V. R1 K1 V1 V →
  39                           ∀K2. K ⪤[R2,V] K2 → K ⪤[R2,V1] K2.
  40
  41 definition rex_transitive: relation3 ? (relation3 ?? term) … ≝
  42                            λR1,R2,R3.
  43                            ∀K1,K,V1. K1 ⪤[R1,V1] K →
  44                            ∀V. R1 K1 V1 V → ∀V2. R2 K V V2 → R3 K1 V1 V2.
  45
  46 (* Basic inversion lemmas ***************************************************)
  47
  48 lemma rex_inv_atom_sn (R): ∀Y2,T. ⋆ ⪤[R,T] Y2 → Y2 = ⋆.
  49 #R #Y2 #T * /2 width=4 by sex_inv_atom1/
  50 qed-.
  51
  52 lemma rex_inv_atom_dx (R): ∀Y1,T. Y1 ⪤[R,T] ⋆ → Y1 = ⋆.
  53 #R #I #Y1 * /2 width=4 by sex_inv_atom2/
  54 qed-.
  55
  56 lemma rex_inv_sort (R):
  57       ∀Y1,Y2,s. Y1 ⪤[R,⋆s] Y2 →
  58       ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
  59        | ∃∃I1,I2,L1,L2. L1 ⪤[R,⋆s] L2 & Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
  60 #R * [ | #Y1 #I1 ] #Y2 #s * #f #H1 #H2
  61 [ lapply (sex_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
  62 | lapply (frees_inv_sort … H1) -H1 #Hf
  63   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
  64   elim (sex_inv_push1 … H2) -H2 #I2 #L2 #H12 #_ #H destruct
  65   /5 width=7 by frees_sort, ex3_4_intro, ex2_intro, or_intror/
  66 ]
  67 qed-.
  68
  69 lemma rex_inv_zero (R):
  70       ∀Y1,Y2. Y1 ⪤[R,#0] Y2 →
  71       ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
  72        | ∃∃I,L1,L2,V1,V2. L1 ⪤[R,V1] L2 & R L1 V1 V2 &
  73            Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2
  74        | ∃∃f,I,L1,L2. 𝐈⦃f⦄ & L1 ⪤[cext2 R,cfull,f] L2 &
  75            Y1 = L1.ⓤ{I} & Y2 = L2.ⓤ{I}.
  76 #R * [ | #Y1 * #I1 [ | #X ] ] #Y2 * #f #H1 #H2
  77 [ lapply (sex_inv_atom1 … H2) -H2 /3 width=1 by or3_intro0, conj/
  78 | elim (frees_inv_unit … H1) -H1 #g #HX #H destruct
  79   elim (sex_inv_next1 … H2) -H2 #I2 #L2 #HL12 #H #H2 destruct
  80   >(ext2_inv_unit_sn … H) -H /3 width=8 by or3_intro2, ex4_4_intro/
  81 | elim (frees_inv_pair … H1) -H1 #g #Hg #H destruct
  82   elim (sex_inv_next1 … H2) -H2 #Z2 #L2 #HL12 #H
  83   elim (ext2_inv_pair_sn … H) -H
  84   /4 width=9 by or3_intro1, ex4_5_intro, ex2_intro/
  85 ]
  86 qed-.
  87
  88 lemma rex_inv_lref (R):
  89       ∀Y1,Y2,i. Y1 ⪤[R,#↑i] Y2 →
  90       ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
  91        | ∃∃I1,I2,L1,L2. L1 ⪤[R,#i] L2 & Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
  92 #R * [ | #Y1 #I1 ] #Y2 #i * #f #H1 #H2
  93 [ lapply (sex_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
  94 | elim (frees_inv_lref … H1) -H1 #g #Hg #H destruct
  95   elim (sex_inv_push1 … H2) -H2
  96   /4 width=7 by ex3_4_intro, ex2_intro, or_intror/
  97 ]
  98 qed-.
  99
 100 lemma rex_inv_gref (R):
 101       ∀Y1,Y2,l. Y1 ⪤[R,§l] Y2 →
 102       ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
 103        | ∃∃I1,I2,L1,L2. L1 ⪤[R,§l] L2 & Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
 104 #R * [ | #Y1 #I1 ] #Y2 #l * #f #H1 #H2
 105 [ lapply (sex_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 106 | lapply (frees_inv_gref … H1) -H1 #Hf
 107   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
 108   elim (sex_inv_push1 … H2) -H2 #I2 #L2 #H12 #_ #H destruct
 109   /5 width=7 by frees_gref, ex3_4_intro, ex2_intro, or_intror/
 110 ]
 111 qed-.
 112
 113 (* Basic_2A1: uses: llpx_sn_inv_bind llpx_sn_inv_bind_O *)
 114 lemma rex_inv_bind (R):
 115       ∀p,I,L1,L2,V1,V2,T. L1 ⪤[R,ⓑ{p,I}V1.T] L2 → R L1 V1 V2 →
 116       ∧∧ L1 ⪤[R,V1] L2 & L1.ⓑ{I}V1 ⪤[R,T] L2.ⓑ{I}V2.
 117 #R #p #I #L1 #L2 #V1 #V2 #T * #f #Hf #HL #HV elim (frees_inv_bind … Hf) -Hf
 118 /6 width=6 by sle_sex_trans, sex_inv_tl, ext2_pair, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 119 qed-.
 120
 121 (* Basic_2A1: uses: llpx_sn_inv_flat *)
 122 lemma rex_inv_flat (R):
 123       ∀I,L1,L2,V,T. L1 ⪤[R,ⓕ{I}V.T] L2 →
 124       ∧∧ L1 ⪤[R,V] L2 & L1 ⪤[R,T] L2.
 125 #R #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_flat … Hf) -Hf
 126 /5 width=6 by sle_sex_trans, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 127 qed-.
 128
 129 (* Advanced inversion lemmas ************************************************)
 130
 131 lemma rex_inv_sort_bind_sn (R):
 132       ∀I1,K1,L2,s. K1.ⓘ{I1} ⪤[R,⋆s] L2 →
 133       ∃∃I2,K2. K1 ⪤[R,⋆s] K2 & L2 = K2.ⓘ{I2}.
 134 #R #I1 #K1 #L2 #s #H elim (rex_inv_sort … H) -H *
 135 [ #H destruct
 136 | #Z1 #I2 #Y1 #K2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 137 ]
 138 qed-.
 139
 140 lemma rex_inv_sort_bind_dx (R):
 141       ∀I2,K2,L1,s. L1 ⪤[R,⋆s] K2.ⓘ{I2} →
 142       ∃∃I1,K1. K1 ⪤[R,⋆s] K2 & L1 = K1.ⓘ{I1}.
 143 #R #I2 #K2 #L1 #s #H elim (rex_inv_sort … H) -H *
 144 [ #_ #H destruct
 145 | #I1 #Z2 #K1 #Y2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 146 ]
 147 qed-.
 148
 149 lemma rex_inv_zero_pair_sn (R):
 150       ∀I,L2,K1,V1. K1.ⓑ{I}V1 ⪤[R,#0] L2 →
 151       ∃∃K2,V2. K1 ⪤[R,V1] K2 & R K1 V1 V2 & L2 = K2.ⓑ{I}V2.
 152 #R #I #L2 #K1 #V1 #H elim (rex_inv_zero … H) -H *
 153 [ #H destruct
 154 | #Z #Y1 #K2 #X1 #V2 #HK12 #HV12 #H1 #H2 destruct
 155   /2 width=5 by ex3_2_intro/
 156 | #f #Z #Y1 #Y2 #_ #_ #H destruct
 157 ]
 158 qed-.
 159
 160 lemma rex_inv_zero_pair_dx (R):
 161       ∀I,L1,K2,V2. L1 ⪤[R,#0] K2.ⓑ{I}V2 →
 162       ∃∃K1,V1. K1 ⪤[R,V1] K2 & R K1 V1 V2 & L1 = K1.ⓑ{I}V1.
 163 #R #I #L1 #K2 #V2 #H elim (rex_inv_zero … H) -H *
 164 [ #_ #H destruct
 165 | #Z #K1 #Y2 #V1 #X2 #HK12 #HV12 #H1 #H2 destruct
 166   /2 width=5 by ex3_2_intro/
 167 | #f #Z #Y1 #Y2 #_ #_ #_ #H destruct
 168 ]
 169 qed-.
 170
 171 lemma rex_inv_zero_unit_sn (R):
 172       ∀I,K1,L2. K1.ⓤ{I} ⪤[R,#0] L2 →
 173       ∃∃f,K2. 𝐈⦃f⦄ & K1 ⪤[cext2 R,cfull,f] K2 & L2 = K2.ⓤ{I}.
 174 #R #I #K1 #L2 #H elim (rex_inv_zero … H) -H *
 175 [ #H destruct
 176 | #Z #Y1 #Y2 #X1 #X2 #_ #_ #H destruct
 177 | #f #Z #Y1 #K2 #Hf #HK12 #H1 #H2 destruct /2 width=5 by ex3_2_intro/
 178 ]
 179 qed-.
 180
 181 lemma rex_inv_zero_unit_dx (R):
 182       ∀I,L1,K2. L1 ⪤[R,#0] K2.ⓤ{I} →
 183       ∃∃f,K1. 𝐈⦃f⦄ & K1 ⪤[cext2 R,cfull,f] K2 & L1 = K1.ⓤ{I}.
 184 #R #I #L1 #K2 #H elim (rex_inv_zero … H) -H *
 185 [ #_ #H destruct
 186 | #Z #Y1 #Y2 #X1 #X2 #_ #_ #_ #H destruct
 187 | #f #Z #K1 #Y2 #Hf #HK12 #H1 #H2 destruct /2 width=5 by ex3_2_intro/
 188 ]
 189 qed-.
 190
 191 lemma rex_inv_lref_bind_sn (R):
 192       ∀I1,K1,L2,i. K1.ⓘ{I1} ⪤[R,#↑i] L2 →
 193       ∃∃I2,K2. K1 ⪤[R,#i] K2 & L2 = K2.ⓘ{I2}.
 194 #R #I1 #K1 #L2 #i #H elim (rex_inv_lref … H) -H *
 195 [ #H destruct
 196 | #Z1 #I2 #Y1 #K2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 197 ]
 198 qed-.
 199
 200 lemma rex_inv_lref_bind_dx (R):
 201       ∀I2,K2,L1,i. L1 ⪤[R,#↑i] K2.ⓘ{I2} →
 202       ∃∃I1,K1. K1 ⪤[R,#i] K2 & L1 = K1.ⓘ{I1}.
 203 #R #I2 #K2 #L1 #i #H elim (rex_inv_lref … H) -H *
 204 [ #_ #H destruct
 205 | #I1 #Z2 #K1 #Y2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 206 ]
 207 qed-.
 208
 209 lemma rex_inv_gref_bind_sn (R):
 210       ∀I1,K1,L2,l. K1.ⓘ{I1} ⪤[R,§l] L2 →
 211       ∃∃I2,K2. K1 ⪤[R,§l] K2 & L2 = K2.ⓘ{I2}.
 212 #R #I1 #K1 #L2 #l #H elim (rex_inv_gref … H) -H *
 213 [ #H destruct
 214 | #Z1 #I2 #Y1 #K2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 215 ]
 216 qed-.
 217
 218 lemma rex_inv_gref_bind_dx (R):
 219       ∀I2,K2,L1,l. L1 ⪤[R,§l] K2.ⓘ{I2} →
 220       ∃∃I1,K1. K1 ⪤[R,§l] K2 & L1 = K1.ⓘ{I1}.
 221 #R #I2 #K2 #L1 #l #H elim (rex_inv_gref … H) -H *
 222 [ #_ #H destruct
 223 | #I1 #Z2 #K1 #Y2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 224 ]
 225 qed-.
 226
 227 (* Basic forward lemmas *****************************************************)
 228
 229 lemma rex_fwd_zero_pair (R):
 230       ∀I,K1,K2,V1,V2. K1.ⓑ{I}V1 ⪤[R,#0] K2.ⓑ{I}V2 → K1 ⪤[R,V1] K2.
 231 #R #I #K1 #K2 #V1 #V2 #H
 232 elim (rex_inv_zero_pair_sn … H) -H #Y #X #HK12 #_ #H destruct //
 233 qed-.
 234
 235 (* Basic_2A1: uses: llpx_sn_fwd_pair_sn llpx_sn_fwd_bind_sn llpx_sn_fwd_flat_sn *)
 236 lemma rex_fwd_pair_sn (R): ∀I,L1,L2,V,T. L1 ⪤[R,②{I}V.T] L2 → L1 ⪤[R,V] L2.
 237 #R * [ #p ] #I #L1 #L2 #V #T * #f #Hf #HL
 238 [ elim (frees_inv_bind … Hf) | elim (frees_inv_flat … Hf) ] -Hf
 239 /4 width=6 by sle_sex_trans, sor_inv_sle_sn, ex2_intro/
 240 qed-.
 241
 242 (* Basic_2A1: uses: llpx_sn_fwd_bind_dx llpx_sn_fwd_bind_O_dx *)
 243 lemma rex_fwd_bind_dx (R):
 244       ∀p,I,L1,L2,V1,V2,T. L1 ⪤[R,ⓑ{p,I}V1.T] L2 →
 245       R L1 V1 V2 → L1.ⓑ{I}V1 ⪤[R,T] L2.ⓑ{I}V2.
 246 #R #p #I #L1 #L2 #V1 #V2 #T #H #HV elim (rex_inv_bind … H HV) -H -HV //
 247 qed-.
 248
 249 (* Basic_2A1: uses: llpx_sn_fwd_flat_dx *)
 250 lemma rex_fwd_flat_dx (R): ∀I,L1,L2,V,T. L1 ⪤[R,ⓕ{I}V.T] L2 → L1 ⪤[R,T] L2.
 251 #R #I #L1 #L2 #V #T #H elim (rex_inv_flat … H) -H //
 252 qed-.
 253
 254 lemma rex_fwd_dx (R):
 255       ∀I2,L1,K2,T. L1 ⪤[R,T] K2.ⓘ{I2} →
 256       ∃∃I1,K1. L1 = K1.ⓘ{I1}.
 257 #R #I2 #L1 #K2 #T * #f elim (pn_split f) * #g #Hg #_ #Hf destruct
 258 [ elim (sex_inv_push2 … Hf) | elim (sex_inv_next2 … Hf) ] -Hf #I1 #K1 #_ #_ #H destruct
 259 /2 width=3 by ex1_2_intro/
 260 qed-.
 261
 262 (* Basic properties *********************************************************)
 263
 264 lemma rex_atom (R): ∀I. ⋆ ⪤[R,⓪{I}] ⋆.
 265 #R * /3 width=3 by frees_sort, frees_atom, frees_gref, sex_atom, ex2_intro/
 266 qed.
 267
 268 lemma rex_sort (R):
 269       ∀I1,I2,L1,L2,s. L1 ⪤[R,⋆s] L2 → L1.ⓘ{I1} ⪤[R,⋆s] L2.ⓘ{I2}.
 270 #R #I1 #I2 #L1 #L2 #s * #f #Hf #H12
 271 lapply (frees_inv_sort … Hf) -Hf
 272 /4 width=3 by frees_sort, sex_push, isid_push, ex2_intro/
 273 qed.
 274
 275 lemma rex_pair (R):
 276       ∀I,L1,L2,V1,V2. L1 ⪤[R,V1] L2 →
 277       R L1 V1 V2 → L1.ⓑ{I}V1 ⪤[R,#0] L2.ⓑ{I}V2.
 278 #R #I1 #I2 #L1 #L2 #V1 *
 279 /4 width=3 by ext2_pair, frees_pair, sex_next, ex2_intro/
 280 qed.
 281
 282 lemma rex_unit (R):
 283       ∀f,I,L1,L2. 𝐈⦃f⦄ → L1 ⪤[cext2 R,cfull,f] L2 →
 284       L1.ⓤ{I} ⪤[R,#0] L2.ⓤ{I}.
 285 /4 width=3 by frees_unit, sex_next, ext2_unit, ex2_intro/ qed.
 286
 287 lemma rex_lref (R):
 288       ∀I1,I2,L1,L2,i. L1 ⪤[R,#i] L2 → L1.ⓘ{I1} ⪤[R,#↑i] L2.ⓘ{I2}.
 289 #R #I1 #I2 #L1 #L2 #i * /3 width=3 by sex_push, frees_lref, ex2_intro/
 290 qed.
 291
 292 lemma rex_gref (R):
 293       ∀I1,I2,L1,L2,l. L1 ⪤[R,§l] L2 → L1.ⓘ{I1} ⪤[R,§l] L2.ⓘ{I2}.
 294 #R #I1 #I2 #L1 #L2 #l * #f #Hf #H12
 295 lapply (frees_inv_gref … Hf) -Hf
 296 /4 width=3 by frees_gref, sex_push, isid_push, ex2_intro/
 297 qed.
 298
 299 lemma rex_bind_repl_dx (R):
 300       ∀I,I1,L1,L2,T. L1.ⓘ{I} ⪤[R,T] L2.ⓘ{I1} →
 301       ∀I2. cext2 R L1 I I2 → L1.ⓘ{I} ⪤[R,T] L2.ⓘ{I2}.
 302 #R #I #I1 #L1 #L2 #T * #f #Hf #HL12 #I2 #HR
 303 /3 width=5 by sex_pair_repl, ex2_intro/
 304 qed-.
 305
 306 (* Basic_2A1: uses: llpx_sn_co *)
 307 lemma rex_co (R1) (R2):
 308       (∀L,T1,T2. R1 L T1 T2 → R2 L T1 T2) →
 309       ∀L1,L2,T. L1 ⪤[R1,T] L2 → L1 ⪤[R2,T] L2.
 310 #R1 #R2 #HR #L1 #L2 #T * /5 width=7 by sex_co, cext2_co, ex2_intro/
 311 qed-.
 312
 313 lemma rex_isid (R1) (R2):
 314       ∀L1,L2,T1,T2.
 315       (∀f. L1 ⊢ 𝐅+⦃T1⦄ ≘ f → 𝐈⦃f⦄) →
 316       (∀f. 𝐈⦃f⦄ → L1 ⊢ 𝐅+⦃T2⦄ ≘ f) →
 317       L1 ⪤[R1,T1] L2 → L1 ⪤[R2,T2] L2.
 318 #R1 #R2 #L1 #L2 #T1 #T2 #H1 #H2 *
 319 /4 width=7 by sex_co_isid, ex2_intro/
 320 qed-.
 321
 322 lemma rex_unit_sn (R1) (R2):
 323       ∀I,K1,L2. K1.ⓤ{I} ⪤[R1,#0] L2 → K1.ⓤ{I} ⪤[R2,#0] L2.
 324 #R1 #R2 #I #K1 #L2 #H
 325 elim (rex_inv_zero_unit_sn … H) -H #f #K2 #Hf #HK12 #H destruct
 326 /3 width=7 by rex_unit, sex_co_isid/
 327 qed-.
 328
 329 (* Basic_2A1: removed theorems 9:
 330               llpx_sn_skip llpx_sn_lref llpx_sn_free
 331               llpx_sn_fwd_lref
 332               llpx_sn_Y llpx_sn_ge_up llpx_sn_ge
 333               llpx_sn_fwd_drop_sn llpx_sn_fwd_drop_dx
 334 *)