matita/matita/contribs/lambdadelta/static_2/static/rex.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_1_2.ma".
  16 include "ground/xoa/ex_3_4.ma".
  17 include "ground/xoa/ex_4_4.ma".
  18 include "ground/xoa/ex_4_5.ma".
  19 include "ground/relocation/rtmap_id.ma".
  20 include "static_2/notation/relations/relation_4.ma".
  21 include "static_2/syntax/cext2.ma".
  22 include "static_2/relocation/sex.ma".
  23 include "static_2/static/frees.ma".
  24
  25 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  26
  27 definition rex (R) (T): relation lenv ≝
  28                λL1,L2. ∃∃f. L1 ⊢ 𝐅+❪T❫ ≘ f & L1 ⪤[cext2 R,cfull,f] L2.
  29
  30 interpretation "generic extension on referred entries (local environment)"
  31    'Relation R T L1 L2 = (rex R T L1 L2).
  32
  33 definition R_confluent2_rex: relation4 (relation3 lenv term term)
  34                                        (relation3 lenv term term) … ≝
  35                              λR1,R2,RP1,RP2.
  36                              ∀L0,T0,T1. R1 L0 T0 T1 → ∀T2. R2 L0 T0 T2 →
  37                              ∀L1. L0 ⪤[RP1,T0] L1 → ∀L2. L0 ⪤[RP2,T0] L2 →
  38                              ∃∃T. R2 L1 T1 T & R1 L2 T2 T.
  39
  40 definition rex_confluent: relation … ≝
  41                           λR1,R2.
  42                           ∀K1,K,V1. K1 ⪤[R1,V1] K → ∀V. R1 K1 V1 V →
  43                           ∀K2. K ⪤[R2,V] K2 → K ⪤[R2,V1] K2.
  44
  45 definition rex_transitive: relation3 ? (relation3 ?? term) … ≝
  46                            λR1,R2,R3.
  47                            ∀K1,K,V1. K1 ⪤[R1,V1] K →
  48                            ∀V. R1 K1 V1 V → ∀V2. R2 K V V2 → R3 K1 V1 V2.
  49
  50 (* Basic inversion lemmas ***************************************************)
  51
  52 lemma rex_inv_atom_sn (R): ∀Y2,T. ⋆ ⪤[R,T] Y2 → Y2 = ⋆.
  53 #R #Y2 #T * /2 width=4 by sex_inv_atom1/
  54 qed-.
  55
  56 lemma rex_inv_atom_dx (R): ∀Y1,T. Y1 ⪤[R,T] ⋆ → Y1 = ⋆.
  57 #R #I #Y1 * /2 width=4 by sex_inv_atom2/
  58 qed-.
  59
  60 lemma rex_inv_sort (R):
  61       ∀Y1,Y2,s. Y1 ⪤[R,⋆s] Y2 →
  62       ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
  63        | ∃∃I1,I2,L1,L2. L1 ⪤[R,⋆s] L2 & Y1 = L1.ⓘ[I1] & Y2 = L2.ⓘ[I2].
  64 #R * [ | #Y1 #I1 ] #Y2 #s * #f #H1 #H2
  65 [ lapply (sex_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
  66 | lapply (frees_inv_sort … H1) -H1 #Hf
  67   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
  68   elim (sex_inv_push1 … H2) -H2 #I2 #L2 #H12 #_ #H destruct
  69   /5 width=7 by frees_sort, ex3_4_intro, ex2_intro, or_intror/
  70 ]
  71 qed-.
  72
  73 lemma rex_inv_zero (R):
  74       ∀Y1,Y2. Y1 ⪤[R,#0] Y2 →
  75       ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
  76        | ∃∃I,L1,L2,V1,V2. L1 ⪤[R,V1] L2 & R L1 V1 V2 &
  77            Y1 = L1.ⓑ[I]V1 & Y2 = L2.ⓑ[I]V2
  78        | ∃∃f,I,L1,L2. 𝐈❪f❫ & L1 ⪤[cext2 R,cfull,f] L2 &
  79            Y1 = L1.ⓤ[I] & Y2 = L2.ⓤ[I].
  80 #R * [ | #Y1 * #I1 [ | #X ] ] #Y2 * #f #H1 #H2
  81 [ lapply (sex_inv_atom1 … H2) -H2 /3 width=1 by or3_intro0, conj/
  82 | elim (frees_inv_unit … H1) -H1 #g #HX #H destruct
  83   elim (sex_inv_next1 … H2) -H2 #I2 #L2 #HL12 #H #H2 destruct
  84   >(ext2_inv_unit_sn … H) -H /3 width=8 by or3_intro2, ex4_4_intro/
  85 | elim (frees_inv_pair … H1) -H1 #g #Hg #H destruct
  86   elim (sex_inv_next1 … H2) -H2 #Z2 #L2 #HL12 #H
  87   elim (ext2_inv_pair_sn … H) -H
  88   /4 width=9 by or3_intro1, ex4_5_intro, ex2_intro/
  89 ]
  90 qed-.
  91
  92 lemma rex_inv_lref (R):
  93       ∀Y1,Y2,i. Y1 ⪤[R,#↑i] Y2 →
  94       ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
  95        | ∃∃I1,I2,L1,L2. L1 ⪤[R,#i] L2 & Y1 = L1.ⓘ[I1] & Y2 = L2.ⓘ[I2].
  96 #R * [ | #Y1 #I1 ] #Y2 #i * #f #H1 #H2
  97 [ lapply (sex_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
  98 | elim (frees_inv_lref … H1) -H1 #g #Hg #H destruct
  99   elim (sex_inv_push1 … H2) -H2
 100   /4 width=7 by ex3_4_intro, ex2_intro, or_intror/
 101 ]
 102 qed-.
 103
 104 lemma rex_inv_gref (R):
 105       ∀Y1,Y2,l. Y1 ⪤[R,§l] Y2 →
 106       ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
 107        | ∃∃I1,I2,L1,L2. L1 ⪤[R,§l] L2 & Y1 = L1.ⓘ[I1] & Y2 = L2.ⓘ[I2].
 108 #R * [ | #Y1 #I1 ] #Y2 #l * #f #H1 #H2
 109 [ lapply (sex_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 110 | lapply (frees_inv_gref … H1) -H1 #Hf
 111   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
 112   elim (sex_inv_push1 … H2) -H2 #I2 #L2 #H12 #_ #H destruct
 113   /5 width=7 by frees_gref, ex3_4_intro, ex2_intro, or_intror/
 114 ]
 115 qed-.
 116
 117 (* Basic_2A1: uses: llpx_sn_inv_bind llpx_sn_inv_bind_O *)
 118 lemma rex_inv_bind (R):
 119       ∀p,I,L1,L2,V1,V2,T. L1 ⪤[R,ⓑ[p,I]V1.T] L2 → R L1 V1 V2 →
 120       ∧∧ L1 ⪤[R,V1] L2 & L1.ⓑ[I]V1 ⪤[R,T] L2.ⓑ[I]V2.
 121 #R #p #I #L1 #L2 #V1 #V2 #T * #f #Hf #HL #HV elim (frees_inv_bind … Hf) -Hf
 122 /6 width=6 by sle_sex_trans, sex_inv_tl, ext2_pair, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 123 qed-.
 124
 125 (* Basic_2A1: uses: llpx_sn_inv_flat *)
 126 lemma rex_inv_flat (R):
 127       ∀I,L1,L2,V,T. L1 ⪤[R,ⓕ[I]V.T] L2 →
 128       ∧∧ L1 ⪤[R,V] L2 & L1 ⪤[R,T] L2.
 129 #R #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_flat … Hf) -Hf
 130 /5 width=6 by sle_sex_trans, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 131 qed-.
 132
 133 (* Advanced inversion lemmas ************************************************)
 134
 135 lemma rex_inv_sort_bind_sn (R):
 136       ∀I1,K1,L2,s. K1.ⓘ[I1] ⪤[R,⋆s] L2 →
 137       ∃∃I2,K2. K1 ⪤[R,⋆s] K2 & L2 = K2.ⓘ[I2].
 138 #R #I1 #K1 #L2 #s #H elim (rex_inv_sort … H) -H *
 139 [ #H destruct
 140 | #Z1 #I2 #Y1 #K2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 141 ]
 142 qed-.
 143
 144 lemma rex_inv_sort_bind_dx (R):
 145       ∀I2,K2,L1,s. L1 ⪤[R,⋆s] K2.ⓘ[I2] →
 146       ∃∃I1,K1. K1 ⪤[R,⋆s] K2 & L1 = K1.ⓘ[I1].
 147 #R #I2 #K2 #L1 #s #H elim (rex_inv_sort … H) -H *
 148 [ #_ #H destruct
 149 | #I1 #Z2 #K1 #Y2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 150 ]
 151 qed-.
 152
 153 lemma rex_inv_zero_pair_sn (R):
 154       ∀I,L2,K1,V1. K1.ⓑ[I]V1 ⪤[R,#0] L2 →
 155       ∃∃K2,V2. K1 ⪤[R,V1] K2 & R K1 V1 V2 & L2 = K2.ⓑ[I]V2.
 156 #R #I #L2 #K1 #V1 #H elim (rex_inv_zero … H) -H *
 157 [ #H destruct
 158 | #Z #Y1 #K2 #X1 #V2 #HK12 #HV12 #H1 #H2 destruct
 159   /2 width=5 by ex3_2_intro/
 160 | #f #Z #Y1 #Y2 #_ #_ #H destruct
 161 ]
 162 qed-.
 163
 164 lemma rex_inv_zero_pair_dx (R):
 165       ∀I,L1,K2,V2. L1 ⪤[R,#0] K2.ⓑ[I]V2 →
 166       ∃∃K1,V1. K1 ⪤[R,V1] K2 & R K1 V1 V2 & L1 = K1.ⓑ[I]V1.
 167 #R #I #L1 #K2 #V2 #H elim (rex_inv_zero … H) -H *
 168 [ #_ #H destruct
 169 | #Z #K1 #Y2 #V1 #X2 #HK12 #HV12 #H1 #H2 destruct
 170   /2 width=5 by ex3_2_intro/
 171 | #f #Z #Y1 #Y2 #_ #_ #_ #H destruct
 172 ]
 173 qed-.
 174
 175 lemma rex_inv_zero_unit_sn (R):
 176       ∀I,K1,L2. K1.ⓤ[I] ⪤[R,#0] L2 →
 177       ∃∃f,K2. 𝐈❪f❫ & K1 ⪤[cext2 R,cfull,f] K2 & L2 = K2.ⓤ[I].
 178 #R #I #K1 #L2 #H elim (rex_inv_zero … H) -H *
 179 [ #H destruct
 180 | #Z #Y1 #Y2 #X1 #X2 #_ #_ #H destruct
 181 | #f #Z #Y1 #K2 #Hf #HK12 #H1 #H2 destruct /2 width=5 by ex3_2_intro/
 182 ]
 183 qed-.
 184
 185 lemma rex_inv_zero_unit_dx (R):
 186       ∀I,L1,K2. L1 ⪤[R,#0] K2.ⓤ[I] →
 187       ∃∃f,K1. 𝐈❪f❫ & K1 ⪤[cext2 R,cfull,f] K2 & L1 = K1.ⓤ[I].
 188 #R #I #L1 #K2 #H elim (rex_inv_zero … H) -H *
 189 [ #_ #H destruct
 190 | #Z #Y1 #Y2 #X1 #X2 #_ #_ #_ #H destruct
 191 | #f #Z #K1 #Y2 #Hf #HK12 #H1 #H2 destruct /2 width=5 by ex3_2_intro/
 192 ]
 193 qed-.
 194
 195 lemma rex_inv_lref_bind_sn (R):
 196       ∀I1,K1,L2,i. K1.ⓘ[I1] ⪤[R,#↑i] L2 →
 197       ∃∃I2,K2. K1 ⪤[R,#i] K2 & L2 = K2.ⓘ[I2].
 198 #R #I1 #K1 #L2 #i #H elim (rex_inv_lref … H) -H *
 199 [ #H destruct
 200 | #Z1 #I2 #Y1 #K2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 201 ]
 202 qed-.
 203
 204 lemma rex_inv_lref_bind_dx (R):
 205       ∀I2,K2,L1,i. L1 ⪤[R,#↑i] K2.ⓘ[I2] →
 206       ∃∃I1,K1. K1 ⪤[R,#i] K2 & L1 = K1.ⓘ[I1].
 207 #R #I2 #K2 #L1 #i #H elim (rex_inv_lref … H) -H *
 208 [ #_ #H destruct
 209 | #I1 #Z2 #K1 #Y2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 210 ]
 211 qed-.
 212
 213 lemma rex_inv_gref_bind_sn (R):
 214       ∀I1,K1,L2,l. K1.ⓘ[I1] ⪤[R,§l] L2 →
 215       ∃∃I2,K2. K1 ⪤[R,§l] K2 & L2 = K2.ⓘ[I2].
 216 #R #I1 #K1 #L2 #l #H elim (rex_inv_gref … H) -H *
 217 [ #H destruct
 218 | #Z1 #I2 #Y1 #K2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 219 ]
 220 qed-.
 221
 222 lemma rex_inv_gref_bind_dx (R):
 223       ∀I2,K2,L1,l. L1 ⪤[R,§l] K2.ⓘ[I2] →
 224       ∃∃I1,K1. K1 ⪤[R,§l] K2 & L1 = K1.ⓘ[I1].
 225 #R #I2 #K2 #L1 #l #H elim (rex_inv_gref … H) -H *
 226 [ #_ #H destruct
 227 | #I1 #Z2 #K1 #Y2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 228 ]
 229 qed-.
 230
 231 (* Basic forward lemmas *****************************************************)
 232
 233 lemma rex_fwd_zero_pair (R):
 234       ∀I,K1,K2,V1,V2. K1.ⓑ[I]V1 ⪤[R,#0] K2.ⓑ[I]V2 → K1 ⪤[R,V1] K2.
 235 #R #I #K1 #K2 #V1 #V2 #H
 236 elim (rex_inv_zero_pair_sn … H) -H #Y #X #HK12 #_ #H destruct //
 237 qed-.
 238
 239 (* Basic_2A1: uses: llpx_sn_fwd_pair_sn llpx_sn_fwd_bind_sn llpx_sn_fwd_flat_sn *)
 240 lemma rex_fwd_pair_sn (R): ∀I,L1,L2,V,T. L1 ⪤[R,②[I]V.T] L2 → L1 ⪤[R,V] L2.
 241 #R * [ #p ] #I #L1 #L2 #V #T * #f #Hf #HL
 242 [ elim (frees_inv_bind … Hf) | elim (frees_inv_flat … Hf) ] -Hf
 243 /4 width=6 by sle_sex_trans, sor_inv_sle_sn, ex2_intro/
 244 qed-.
 245
 246 (* Basic_2A1: uses: llpx_sn_fwd_bind_dx llpx_sn_fwd_bind_O_dx *)
 247 lemma rex_fwd_bind_dx (R):
 248       ∀p,I,L1,L2,V1,V2,T. L1 ⪤[R,ⓑ[p,I]V1.T] L2 →
 249       R L1 V1 V2 → L1.ⓑ[I]V1 ⪤[R,T] L2.ⓑ[I]V2.
 250 #R #p #I #L1 #L2 #V1 #V2 #T #H #HV elim (rex_inv_bind … H HV) -H -HV //
 251 qed-.
 252
 253 (* Basic_2A1: uses: llpx_sn_fwd_flat_dx *)
 254 lemma rex_fwd_flat_dx (R): ∀I,L1,L2,V,T. L1 ⪤[R,ⓕ[I]V.T] L2 → L1 ⪤[R,T] L2.
 255 #R #I #L1 #L2 #V #T #H elim (rex_inv_flat … H) -H //
 256 qed-.
 257
 258 lemma rex_fwd_dx (R):
 259       ∀I2,L1,K2,T. L1 ⪤[R,T] K2.ⓘ[I2] →
 260       ∃∃I1,K1. L1 = K1.ⓘ[I1].
 261 #R #I2 #L1 #K2 #T * #f elim (pn_split f) * #g #Hg #_ #Hf destruct
 262 [ elim (sex_inv_push2 … Hf) | elim (sex_inv_next2 … Hf) ] -Hf #I1 #K1 #_ #_ #H destruct
 263 /2 width=3 by ex1_2_intro/
 264 qed-.
 265
 266 (* Basic properties *********************************************************)
 267
 268 lemma rex_atom (R): ∀I. ⋆ ⪤[R,⓪[I]] ⋆.
 269 #R * /3 width=3 by frees_sort, frees_atom, frees_gref, sex_atom, ex2_intro/
 270 qed.
 271
 272 lemma rex_sort (R):
 273       ∀I1,I2,L1,L2,s. L1 ⪤[R,⋆s] L2 → L1.ⓘ[I1] ⪤[R,⋆s] L2.ⓘ[I2].
 274 #R #I1 #I2 #L1 #L2 #s * #f #Hf #H12
 275 lapply (frees_inv_sort … Hf) -Hf
 276 /4 width=3 by frees_sort, sex_push, isid_push, ex2_intro/
 277 qed.
 278
 279 lemma rex_pair (R):
 280       ∀I,L1,L2,V1,V2. L1 ⪤[R,V1] L2 →
 281       R L1 V1 V2 → L1.ⓑ[I]V1 ⪤[R,#0] L2.ⓑ[I]V2.
 282 #R #I1 #I2 #L1 #L2 #V1 *
 283 /4 width=3 by ext2_pair, frees_pair, sex_next, ex2_intro/
 284 qed.
 285
 286 lemma rex_unit (R):
 287       ∀f,I,L1,L2. 𝐈❪f❫ → L1 ⪤[cext2 R,cfull,f] L2 →
 288       L1.ⓤ[I] ⪤[R,#0] L2.ⓤ[I].
 289 /4 width=3 by frees_unit, sex_next, ext2_unit, ex2_intro/ qed.
 290
 291 lemma rex_lref (R):
 292       ∀I1,I2,L1,L2,i. L1 ⪤[R,#i] L2 → L1.ⓘ[I1] ⪤[R,#↑i] L2.ⓘ[I2].
 293 #R #I1 #I2 #L1 #L2 #i * /3 width=3 by sex_push, frees_lref, ex2_intro/
 294 qed.
 295
 296 lemma rex_gref (R):
 297       ∀I1,I2,L1,L2,l. L1 ⪤[R,§l] L2 → L1.ⓘ[I1] ⪤[R,§l] L2.ⓘ[I2].
 298 #R #I1 #I2 #L1 #L2 #l * #f #Hf #H12
 299 lapply (frees_inv_gref … Hf) -Hf
 300 /4 width=3 by frees_gref, sex_push, isid_push, ex2_intro/
 301 qed.
 302
 303 lemma rex_bind_repl_dx (R):
 304       ∀I,I1,L1,L2,T. L1.ⓘ[I] ⪤[R,T] L2.ⓘ[I1] →
 305       ∀I2. cext2 R L1 I I2 → L1.ⓘ[I] ⪤[R,T] L2.ⓘ[I2].
 306 #R #I #I1 #L1 #L2 #T * #f #Hf #HL12 #I2 #HR
 307 /3 width=5 by sex_pair_repl, ex2_intro/
 308 qed-.
 309
 310 (* Basic_2A1: uses: llpx_sn_co *)
 311 lemma rex_co (R1) (R2):
 312       (∀L,T1,T2. R1 L T1 T2 → R2 L T1 T2) →
 313       ∀L1,L2,T. L1 ⪤[R1,T] L2 → L1 ⪤[R2,T] L2.
 314 #R1 #R2 #HR #L1 #L2 #T * /5 width=7 by sex_co, cext2_co, ex2_intro/
 315 qed-.
 316
 317 lemma rex_isid (R1) (R2):
 318       ∀L1,L2,T1,T2.
 319       (∀f. L1 ⊢ 𝐅+❪T1❫ ≘ f → 𝐈❪f❫) →
 320       (∀f. 𝐈❪f❫ → L1 ⊢ 𝐅+❪T2❫ ≘ f) →
 321       L1 ⪤[R1,T1] L2 → L1 ⪤[R2,T2] L2.
 322 #R1 #R2 #L1 #L2 #T1 #T2 #H1 #H2 *
 323 /4 width=7 by sex_co_isid, ex2_intro/
 324 qed-.
 325
 326 lemma rex_unit_sn (R1) (R2):
 327       ∀I,K1,L2. K1.ⓤ[I] ⪤[R1,#0] L2 → K1.ⓤ[I] ⪤[R2,#0] L2.
 328 #R1 #R2 #I #K1 #L2 #H
 329 elim (rex_inv_zero_unit_sn … H) -H #f #K2 #Hf #HK12 #H destruct
 330 /3 width=7 by rex_unit, sex_co_isid/
 331 qed-.
 332
 333 (* Basic_2A1: removed theorems 9:
 334               llpx_sn_skip llpx_sn_lref llpx_sn_free
 335               llpx_sn_fwd_lref
 336               llpx_sn_Y llpx_sn_ge_up llpx_sn_ge
 337               llpx_sn_fwd_drop_sn llpx_sn_fwd_drop_dx
 338 *)