matita/matita/contribs/lambdadelta/static_2/static/rex_fqup.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/frees_fqup.ma".
  16 include "static_2/static/rex.ma".
  17
  18 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 (* Basic_2A1: uses: llpx_sn_refl *)
  23 lemma rex_refl (R): (∀L. reflexive … (R L)) → ∀L,T. L ⪤[R,T] L.
  24 #R #HR #L #T elim (frees_total L T)
  25 /4 width=3 by sex_refl, ext2_refl, ex2_intro/
  26 qed.
  27
  28 lemma rex_pair_refl (R):
  29       (∀L. reflexive … (R L)) →
  30       ∀L,V1,V2. R L V1 V2 → ∀I,T. L.ⓑ[I]V1 ⪤[R,T] L.ⓑ[I]V2.
  31 #R #HR #L #V1 #V2 #HV12 #I #T
  32 elim (frees_total (L.ⓑ[I]V1) T) #f #Hf
  33 elim (pn_split f) * #g #H destruct
  34 /5 width=3 by sex_refl, sex_next, sex_push, ext2_refl, ext2_pair, ex2_intro/
  35 qed.
  36
  37 (* Advanced inversion lemmas ************************************************)
  38
  39 lemma rex_inv_bind_void (R):
  40       ∀p,I,L1,L2,V,T. L1 ⪤[R,ⓑ[p,I]V.T] L2 → L1 ⪤[R,V] L2 ∧ L1.ⓧ ⪤[R,T] L2.ⓧ.
  41 #R #p #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_bind_void … Hf) -Hf
  42 /6 width=6 by sle_sex_trans, sex_inv_tl, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
  43 qed-.
  44
  45 (* Advanced forward lemmas **************************************************)
  46
  47 lemma rex_fwd_bind_dx_void (R):
  48       ∀p,I,L1,L2,V,T. L1 ⪤[R,ⓑ[p,I]V.T] L2 → L1.ⓧ ⪤[R,T] L2.ⓧ.
  49 #R #p #I #L1 #L2 #V #T #H elim (rex_inv_bind_void … H) -H //
  50 qed-.