matita/matita/contribs/lambdadelta/static_2/static/rex_fsle.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/relocation/sex_length.ma".
  16 include "static_2/static/fsle_fsle.ma".
  17 include "static_2/static/rex_drops.ma".
  18 include "static_2/static/rex_rex.ma".
  19
  20 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  21
  22 definition R_fsge_compatible: predicate (relation3 …) ≝ λRN.
  23                               ∀L,T1,T2. RN L T1 T2 → ❪L,T2❫ ⊆ ❪L,T1❫.
  24
  25 definition rex_fsge_compatible: predicate (relation3 …) ≝ λRN.
  26                                 ∀L1,L2,T. L1 ⪤[RN,T] L2 → ❪L2,T❫ ⊆ ❪L1,T❫.
  27
  28 definition rex_fsle_compatible: predicate (relation3 …) ≝ λRN.
  29                                 ∀L1,L2,T. L1 ⪤[RN,T] L2 → ❪L1,T❫ ⊆ ❪L2,T❫.
  30
  31 (* Basic inversions with free variables inclusion for restricted closures ***)
  32
  33 lemma frees_sex_conf (R):
  34       rex_fsge_compatible R →
  35       ∀L1,T,f1. L1 ⊢ 𝐅+❪T❫ ≘ f1 →
  36       ∀L2. L1 ⪤[cext2 R,cfull,f1] L2 →
  37       ∃∃f2. L2 ⊢ 𝐅+❪T❫ ≘ f2 & f2 ⊆ f1.
  38 #R #HR #L1 #T #f1 #Hf1 #L2 #H1L
  39 lapply (HR L1 L2 T ?) /2 width=3 by ex2_intro/ #H2L
  40 @(fsle_frees_trans_eq … H2L … Hf1) /3 width=4 by sex_fwd_length, sym_eq/
  41 qed-.
  42
  43 (* Properties with free variables inclusion for restricted closures *********)
  44
  45 (* Note: we just need lveq_inv_refl: ∀L, n1, n2. L ≋ⓧ*[n1, n2] L → ∧∧ 0 = n1 & 0 = n2 *)
  46 lemma fsge_rex_trans (R):
  47       ∀L1,T1,T2. ❪L1,T1❫ ⊆ ❪L1,T2❫ →
  48       ∀L2. L1 ⪤[R,T2] L2 → L1 ⪤[R,T1] L2.
  49 #R #L1 #T1 #T2 * #n1 #n2 #f1 #f2 #Hf1 #Hf2 #Hn #Hf #L2 #HL12
  50 elim (lveq_inj_length … Hn ?) // #H1 #H2 destruct
  51 /4 width=5 by rex_inv_frees, sle_sex_trans, ex2_intro/
  52 qed-.
  53
  54 lemma rex_sym (R):
  55       rex_fsge_compatible R →
  56       (∀L1,L2,T1,T2. R L1 T1 T2 → R L2 T2 T1) →
  57       ∀T. symmetric … (rex R T).
  58 #R #H1R #H2R #T #L1 #L2
  59 * #f1 #Hf1 #HL12
  60 elim (frees_sex_conf … Hf1 … HL12) -Hf1 //
  61 /5 width=5 by sle_sex_trans, sex_sym, cext2_sym, ex2_intro/
  62 qed-.
  63
  64 lemma rex_pair_sn_split (R1) (R2):
  65       (∀L. reflexive … (R1 L)) → (∀L. reflexive … (R2 L)) →
  66       rex_fsge_compatible R1 →
  67       ∀L1,L2,V. L1 ⪤[R1,V] L2 → ∀I,T.
  68       ∃∃L. L1 ⪤[R1,②[I]V.T] L & L ⪤[R2,V] L2.
  69 #R1 #R2 #HR1 #HR2 #HR #L1 #L2 #V * #f #Hf #HL12 * [ #p ] #I #T
  70 [ elim (frees_total L1 (ⓑ[p,I]V.T)) #g #Hg
  71   elim (frees_inv_bind … Hg) #y1 #y2 #H #_ #Hy
  72 | elim (frees_total L1 (ⓕ[I]V.T)) #g #Hg
  73   elim (frees_inv_flat … Hg) #y1 #y2 #H #_ #Hy
  74 ]
  75 lapply(frees_mono … H … Hf) -H #H1
  76 lapply (sor_eq_repl_back1 … Hy … H1) -y1 #Hy
  77 lapply (sor_inv_sle_sn … Hy) -y2 #Hfg
  78 elim (sex_sle_split (cext2 R1) (cext2 R2) … HL12 … Hfg) -HL12 /2 width=1 by ext2_refl/ #L #HL1 #HL2
  79 lapply (sle_sex_trans … HL1 … Hfg) // #H
  80 elim (frees_sex_conf … Hf … H) -Hf -H
  81 /4 width=7 by sle_sex_trans, ex2_intro/
  82 qed-.
  83
  84 lemma rex_flat_dx_split (R1) (R2):
  85       (∀L. reflexive … (R1 L)) → (∀L. reflexive … (R2 L)) →
  86       rex_fsge_compatible R1 →
  87       ∀L1,L2,T. L1 ⪤[R1,T] L2 → ∀I,V.
  88       ∃∃L. L1 ⪤[R1,ⓕ[I]V.T] L & L ⪤[R2,T] L2.
  89 #R1 #R2 #HR1 #HR2 #HR #L1 #L2 #T * #f #Hf #HL12 #I #V
  90 elim (frees_total L1 (ⓕ[I]V.T)) #g #Hg
  91 elim (frees_inv_flat … Hg) #y1 #y2 #_ #H #Hy
  92 lapply(frees_mono … H … Hf) -H #H2
  93 lapply (sor_eq_repl_back2 … Hy … H2) -y2 #Hy
  94 lapply (sor_inv_sle_dx … Hy) -y1 #Hfg
  95 elim (sex_sle_split (cext2 R1) (cext2 R2) … HL12 … Hfg) -HL12 /2 width=1 by ext2_refl/ #L #HL1 #HL2
  96 lapply (sle_sex_trans … HL1 … Hfg) // #H
  97 elim (frees_sex_conf … Hf … H) -Hf -H
  98 /4 width=7 by sle_sex_trans, ex2_intro/
  99 qed-.
 100
 101 lemma rex_bind_dx_split (R1) (R2):
 102       (∀L. reflexive … (R1 L)) → (∀L. reflexive … (R2 L)) →
 103       rex_fsge_compatible R1 →
 104       ∀I,L1,L2,V1,T. L1.ⓑ[I]V1 ⪤[R1,T] L2 → ∀p.
 105       ∃∃L,V. L1 ⪤[R1,ⓑ[p,I]V1.T] L & L.ⓑ[I]V ⪤[R2,T] L2 & R1 L1 V1 V.
 106 #R1 #R2 #HR1 #HR2 #HR #I #L1 #L2 #V1 #T * #f #Hf #HL12 #p
 107 elim (frees_total L1 (ⓑ[p,I]V1.T)) #g #Hg
 108 elim (frees_inv_bind … Hg) #y1 #y2 #_ #H #Hy
 109 lapply(frees_mono … H … Hf) -H #H2
 110 lapply (tl_eq_repl … H2) -H2 #H2
 111 lapply (sor_eq_repl_back2 … Hy … H2) -y2 #Hy
 112 lapply (sor_inv_sle_dx … Hy) -y1 #Hfg
 113 lapply (sle_inv_tl_sn … Hfg) -Hfg #Hfg
 114 elim (sex_sle_split (cext2 R1) (cext2 R2) … HL12 … Hfg) -HL12 /2 width=1 by ext2_refl/ #Y #H #HL2
 115 lapply (sle_sex_trans … H … Hfg) // #H0
 116 elim (sex_inv_next1 … H) -H #Z #L #HL1 #H
 117 elim (ext2_inv_pair_sn … H) -H #V #HV #H1 #H2 destruct
 118 elim (frees_sex_conf … Hf … H0) -Hf -H0
 119 /4 width=7 by sle_sex_trans, ex3_2_intro, ex2_intro/
 120 qed-.
 121
 122 lemma rex_bind_dx_split_void (R1) (R2):
 123       (∀L. reflexive … (R1 L)) → (∀L. reflexive … (R2 L)) →
 124       rex_fsge_compatible R1 →
 125       ∀L1,L2,T. L1.ⓧ ⪤[R1,T] L2 → ∀p,I,V.
 126       ∃∃L. L1 ⪤[R1,ⓑ[p,I]V.T] L & L.ⓧ ⪤[R2,T] L2.
 127 #R1 #R2 #HR1 #HR2 #HR #L1 #L2 #T * #f #Hf #HL12 #p #I #V
 128 elim (frees_total L1 (ⓑ[p,I]V.T)) #g #Hg
 129 elim (frees_inv_bind_void … Hg) #y1 #y2 #_ #H #Hy
 130 lapply(frees_mono … H … Hf) -H #H2
 131 lapply (tl_eq_repl … H2) -H2 #H2
 132 lapply (sor_eq_repl_back2 … Hy … H2) -y2 #Hy
 133 lapply (sor_inv_sle_dx … Hy) -y1 #Hfg
 134 lapply (sle_inv_tl_sn … Hfg) -Hfg #Hfg
 135 elim (sex_sle_split (cext2 R1) (cext2 R2) … HL12 … Hfg) -HL12 /2 width=1 by ext2_refl/ #Y #H #HL2
 136 lapply (sle_sex_trans … H … Hfg) // #H0
 137 elim (sex_inv_next1 … H) -H #Z #L #HL1 #H
 138 elim (ext2_inv_unit_sn … H) -H #H destruct
 139 elim (frees_sex_conf … Hf … H0) -Hf -H0
 140 /4 width=7 by sle_sex_trans, ex2_intro/ (* note: 2 ex2_intro *)
 141 qed-.
 142
 143 (* Main properties with free variables inclusion for restricted closures ****)
 144
 145 theorem rex_conf (R1) (R2):
 146         rex_fsge_compatible R1 → rex_fsge_compatible R2 →
 147         R_confluent2_rex R1 R2 R1 R2 →
 148         ∀T. confluent2 … (rex R1 T) (rex R2 T).
 149 #R1 #R2 #HR1 #HR2 #HR12 #T #L0 #L1 * #f1 #Hf1 #HL01 #L2 * #f #Hf #HL02
 150 lapply (frees_mono … Hf1 … Hf) -Hf1 #Hf12
 151 lapply (sex_eq_repl_back … HL01 … Hf12) -f1 #HL01
 152 elim (sex_conf … HL01 … HL02) /2 width=3 by ex2_intro/ [ | -HL01 -HL02 ]
 153 [ #L #HL1 #HL2
 154   elim (frees_sex_conf … Hf … HL01) // -HR1 -HL01 #f1 #Hf1 #H1
 155   elim (frees_sex_conf … Hf … HL02) // -HR2 -HL02 #f2 #Hf2 #H2
 156   lapply (sle_sex_trans … HL1 … H1) // -HL1 -H1 #HL1
 157   lapply (sle_sex_trans … HL2 … H2) // -HL2 -H2 #HL2
 158   /3 width=5 by ex2_intro/
 159 | #g * #I0 [2: #V0 ] #K0 #n #HLK0 #Hgf #Z1 #H1 #Z2 #H2 #K1 #HK01 #K2 #HK02
 160   [ elim (ext2_inv_pair_sn … H1) -H1 #V1 #HV01 #H destruct
 161     elim (ext2_inv_pair_sn … H2) -H2 #V2 #HV02 #H destruct
 162     elim (frees_inv_drops_next … Hf … HLK0 … Hgf) -Hf -HLK0 -Hgf #g0 #Hg0 #H0
 163     lapply (sle_sex_trans … HK01 … H0) // -HK01 #HK01
 164     lapply (sle_sex_trans … HK02 … H0) // -HK02 #HK02
 165     elim (HR12 … HV01 … HV02 K1 … K2) /3 width=3 by ext2_pair, ex2_intro/
 166   | lapply (ext2_inv_unit_sn … H1) -H1 #H destruct
 167     lapply (ext2_inv_unit_sn … H2) -H2 #H destruct
 168     /3 width=3 by ext2_unit, ex2_intro/
 169   ]
 170 ]
 171 qed-.
 172
 173 theorem rex_trans_fsle (R1) (R2) (R3):
 174         rex_fsle_compatible R1 → f_transitive_next R1 R2 R3 →
 175         ∀L1,L,T. L1 ⪤[R1,T] L → ∀L2. L ⪤[R2,T] L2 → L1 ⪤[R3,T] L2.
 176 #R1 #R2 #R3 #H1R #H2R #L1 #L #T #H
 177 lapply (H1R … H) -H1R #H0
 178 cases H -H #f1 #Hf1 #HL1 #L2 * #f2 #Hf2 #HL2
 179 lapply (fsle_inv_frees_eq … H0 … Hf1 … Hf2) -H0 -Hf2
 180 /4 width=14 by sex_trans_gen, sex_fwd_length, sle_sex_trans, ex2_intro/
 181 qed-.