matita/matita/contribs/lambdadelta/static_2/syntax/lveq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_3_1.ma".
  16 include "ground/xoa/ex_3_4.ma".
  17 include "ground/xoa/ex_4_1.ma".
  18 include "ground/arith/nat_succ.ma".
  19 include "static_2/notation/relations/voidstareq_4.ma".
  20 include "static_2/syntax/lenv.ma".
  21
  22 (* EQUIVALENCE FOR LOCAL ENVIRONMENTS UP TO EXCLUSION BINDERS ***************)
  23
  24 inductive lveq: bi_relation nat lenv ≝
  25 | lveq_atom   : lveq 𝟎 (⋆) 𝟎 (⋆)
  26 | lveq_bind   : ∀I1,I2,K1,K2. lveq 𝟎 K1 𝟎 K2 →
  27                 lveq 𝟎 (K1.ⓘ[I1]) 𝟎 (K2.ⓘ[I2])
  28 | lveq_void_sn: ∀K1,K2,n1. lveq n1 K1 𝟎 K2 →
  29                 lveq (↑n1) (K1.ⓧ) 𝟎 K2
  30 | lveq_void_dx: ∀K1,K2,n2. lveq 𝟎 K1 n2 K2 →
  31                 lveq 𝟎 K1 (↑n2) (K2.ⓧ)
  32 .
  33
  34 interpretation "equivalence up to exclusion binders (local environment)"
  35    'VoidStarEq L1 n1 n2 L2 = (lveq n1 L1 n2 L2).
  36
  37 (* Basic properties *********************************************************)
  38
  39 lemma lveq_refl: ∀L. L ≋ⓧ*[𝟎,𝟎] L.
  40 #L elim L -L /2 width=1 by lveq_atom, lveq_bind/
  41 qed.
  42
  43 lemma lveq_sym: bi_symmetric … lveq.
  44 #n1 #n2 #L1 #L2 #H elim H -L1 -L2 -n1 -n2
  45 /2 width=1 by lveq_atom, lveq_bind, lveq_void_sn, lveq_void_dx/
  46 qed-.
  47
  48 (* Basic inversion lemmas ***************************************************)
  49
  50 fact lveq_inv_zero_aux: ∀L1,L2,n1,n2. L1 ≋ⓧ*[n1,n2] L2 →
  51                         (𝟎 = n1) → 𝟎 = n2 →
  52                         ∨∨ ∧∧ ⋆ = L1 & ⋆ = L2
  53                          | ∃∃I1,I2,K1,K2. K1 ≋ⓧ*[𝟎,𝟎] K2 & K1.ⓘ[I1] = L1 & K2.ⓘ[I2] = L2.
  54 #L1 #L2 #n1 #n2 * -L1 -L2 -n1 -n2
  55 [1: /3 width=1 by or_introl, conj/
  56 |2: /3 width=7 by ex3_4_intro, or_intror/
  57 |*: #K1 #K2 #n #_ [ #H #_ | #_ #H ]
  58     elim (eq_inv_zero_nsucc … H)
  59 ]
  60 qed-.
  61
  62 lemma lveq_inv_zero: ∀L1,L2. L1 ≋ⓧ*[𝟎,𝟎] L2 →
  63                      ∨∨ ∧∧ ⋆ = L1 & ⋆ = L2
  64                       | ∃∃I1,I2,K1,K2. K1 ≋ⓧ*[𝟎,𝟎] K2 & K1.ⓘ[I1] = L1 & K2.ⓘ[I2] = L2.
  65 /2 width=5 by lveq_inv_zero_aux/ qed-.
  66
  67 fact lveq_inv_succ_sn_aux: ∀L1,L2,n1,n2. L1 ≋ⓧ*[n1,n2] L2 →
  68                            ∀m1. ↑m1 = n1 →
  69                            ∃∃K1. K1 ≋ⓧ*[m1,𝟎] L2 & K1.ⓧ = L1 & 𝟎 = n2.
  70 #L1 #L2 #n1 #n2 * -L1 -L2 -n1 -n2
  71 [1: #m #H elim (eq_inv_nsucc_zero … H)
  72 |2: #I1 #I2 #K1 #K2 #_ #m #H elim (eq_inv_nsucc_zero … H)
  73 |*: #K1 #K2 #n #HK #m #H
  74     [ >(eq_inv_nsucc_bi … H) -m /2 width=3 by ex3_intro/
  75     | elim (eq_inv_nsucc_zero … H)
  76     ]
  77 ]
  78 qed-.
  79
  80 lemma lveq_inv_succ_sn: ∀L1,K2,n1,n2. L1 ≋ⓧ*[↑n1,n2] K2 →
  81                         ∃∃K1. K1 ≋ⓧ*[n1,𝟎] K2 & K1.ⓧ = L1 & 𝟎 = n2.
  82 /2 width=3 by lveq_inv_succ_sn_aux/ qed-.
  83
  84 lemma lveq_inv_succ_dx: ∀K1,L2,n1,n2. K1 ≋ⓧ*[n1,↑n2] L2 →
  85                         ∃∃K2. K1 ≋ⓧ*[𝟎,n2] K2 & K2.ⓧ = L2 & 𝟎 = n1.
  86 #K1 #L2 #n1 #n2 #H
  87 lapply (lveq_sym … H) -H #H
  88 elim (lveq_inv_succ_sn … H) -H /3 width=3 by lveq_sym, ex3_intro/
  89 qed-.
  90
  91 fact lveq_inv_succ_aux: ∀L1,L2,n1,n2. L1 ≋ⓧ*[n1,n2] L2 →
  92                         ∀m1,m2. ↑m1 = n1 → ↑m2 = n2 → ⊥.
  93 #L1 #L2 #n1 #n2 * -L1 -L2 -n1 -n2
  94 [1: #m1 #m2 #H #_ elim (eq_inv_nsucc_zero … H)
  95 |2: #I1 #I2 #K1 #K2 #_ #m1 #m2 #H #_ elim (eq_inv_nsucc_zero … H)
  96 |*: #K1 #K2 #n #_ #m1 #m2 [ #_ #H | #H #_ ]
  97     elim (eq_inv_nsucc_zero … H)
  98 ]
  99 qed-.
 100
 101 lemma lveq_inv_succ: ∀L1,L2,n1,n2. L1 ≋ⓧ*[↑n1,↑n2] L2 → ⊥.
 102 /2 width=9 by lveq_inv_succ_aux/ qed-.
 103
 104 (* Advanced inversion lemmas ************************************************)
 105
 106 lemma lveq_inv_bind_O: ∀I1,I2,K1,K2. K1.ⓘ[I1] ≋ⓧ*[𝟎,𝟎] K2.ⓘ[I2] → K1 ≋ⓧ*[𝟎,𝟎] K2.
 107 #I1 #I2 #K1 #K2 #H
 108 elim (lveq_inv_zero … H) -H * [| #Z1 #Z2 #Y1 #Y2 #HY ] #H1 #H2 destruct //
 109 qed-.
 110
 111 lemma lveq_inv_atom_atom: ∀n1,n2. ⋆ ≋ⓧ*[n1,n2] ⋆ → ∧∧ 𝟎 = n1 & 𝟎 = n2.
 112 #n1 @(nat_ind_succ …  n1) -n1 [2: #n1 #_ ]
 113 #n2 @(nat_ind_succ …  n2) -n2 [2,4: #n2 #_ ]
 114 #H
 115 [ elim (lveq_inv_succ … H)
 116 | elim (lveq_inv_succ_dx … H) -H #Y #_ #H1 #H2 destruct
 117 | elim (lveq_inv_succ_sn … H) -H #Y #_ #H1 #H2 destruct
 118 | /2 width=1 by conj/
 119 ]
 120 qed-.
 121
 122 lemma lveq_inv_bind_atom: ∀I1,K1,n1,n2. K1.ⓘ[I1] ≋ⓧ*[n1,n2] ⋆ →
 123                           ∃∃m1. K1 ≋ⓧ*[m1,𝟎] ⋆ & BUnit Void = I1 & ↑m1 = n1 & 𝟎 = n2.
 124 #I1 #K1
 125 #n1 @(nat_ind_succ …  n1) -n1 [2: #n1 #_ ]
 126 #n2 @(nat_ind_succ …  n2) -n2 [2,4: #n2 #_ ]
 127 #H
 128 [ elim (lveq_inv_succ … H)
 129 | elim (lveq_inv_succ_dx … H) -H #Y #_ #H1 #H2 destruct
 130 | elim (lveq_inv_succ_sn … H) -H #Y #HY #H1 #H2 destruct /2 width=3 by ex4_intro/
 131 | elim (lveq_inv_zero … H) -H *
 132   [ #H1 #H2 destruct
 133   | #Z1 #Z2 #Y1 #Y2 #_ #H1 #H2 destruct
 134   ]
 135 ]
 136 qed-.
 137
 138 lemma lveq_inv_atom_bind: ∀I2,K2,n1,n2. ⋆ ≋ⓧ*[n1,n2] K2.ⓘ[I2] →
 139                           ∃∃m2. ⋆ ≋ⓧ*[𝟎,m2] K2 & BUnit Void = I2 & 𝟎 = n1 & ↑m2 = n2.
 140 #I2 #K2 #n1 #n2 #H
 141 lapply (lveq_sym … H) -H #H
 142 elim (lveq_inv_bind_atom … H) -H
 143 /3 width=3 by lveq_sym, ex4_intro/
 144 qed-.
 145
 146 lemma lveq_inv_pair_pair: ∀I1,I2,K1,K2,V1,V2,n1,n2. K1.ⓑ[I1]V1 ≋ⓧ*[n1,n2] K2.ⓑ[I2]V2 →
 147                           ∧∧ K1 ≋ⓧ*[𝟎,𝟎] K2 & 𝟎 = n1 & 𝟎 = n2.
 148 #I1 #I2 #K1 #K2 #V1 #V2
 149 #n1 @(nat_ind_succ …  n1) -n1 [2: #n1 #_ ]
 150 #n2 @(nat_ind_succ …  n2) -n2 [2,4: #n2 #_ ]
 151 #H
 152 [ elim (lveq_inv_succ … H)
 153 | elim (lveq_inv_succ_dx … H) -H #Y #_ #H1 #H2 destruct
 154 | elim (lveq_inv_succ_sn … H) -H #Y #_ #H1 #H2 destruct
 155 | elim (lveq_inv_zero … H) -H *
 156   [ #H1 #H2 destruct
 157   | #Z1 #Z2 #Y1 #Y2 #HY #H1 #H2 destruct /3 width=1 by and3_intro/
 158   ]
 159 ]
 160 qed-.
 161
 162 lemma lveq_inv_void_succ_sn: ∀L1,L2,n1,n2. L1.ⓧ ≋ⓧ*[↑n1,n2] L2 →
 163                              ∧∧ L1 ≋ ⓧ*[n1,𝟎] L2 & 𝟎 = n2.
 164 #L1 #L2 #n1 #n2 #H
 165 elim (lveq_inv_succ_sn … H) -H #Y #HY #H1 #H2 destruct /2 width=1 by conj/
 166 qed-.
 167
 168 lemma lveq_inv_void_succ_dx: ∀L1,L2,n1,n2. L1 ≋ⓧ*[n1,↑n2] L2.ⓧ →
 169                              ∧∧ L1 ≋ ⓧ*[𝟎,n2] L2 & 𝟎 = n1.
 170 #L1 #L2 #n1 #n2 #H
 171 lapply (lveq_sym … H) -H #H
 172 elim (lveq_inv_void_succ_sn … H) -H
 173 /3 width=1 by lveq_sym, conj/
 174 qed-.
 175
 176 (* Advanced forward lemmas **************************************************)
 177
 178 lemma lveq_fwd_gen: ∀L1,L2,n1,n2. L1 ≋ⓧ*[n1,n2] L2 →
 179                     ∨∨ 𝟎 = n1 | 𝟎 = n2.
 180 #L1 #L2
 181 #n1 @(nat_ind_succ …  n1) -n1 [2: #n1 #_ ]
 182 #n2 @(nat_ind_succ …  n2) -n2 [2,4: #n2 #_ ]
 183 #H
 184 [ elim (lveq_inv_succ … H) ]
 185 /2 width=1 by or_introl, or_intror/
 186 qed-.
 187
 188 lemma lveq_fwd_pair_sn:
 189       ∀I1,K1,L2,V1,n1,n2. K1.ⓑ[I1]V1 ≋ⓧ*[n1,n2] L2 → 𝟎 = n1.
 190 #I1 #K1 #L2 #V1
 191 #n1 @(nat_ind_succ …  n1) -n1 [2: #n1 #_ ] //
 192 #n2 @(nat_ind_succ …  n2) -n2 [2: #n2 #_ ] #H
 193 [ elim (lveq_inv_succ … H)
 194 | elim (lveq_inv_succ_sn … H) -H #Y #_ #H1 #H2 destruct
 195 ]
 196 qed-.
 197
 198 lemma lveq_fwd_pair_dx:
 199       ∀I2,L1,K2,V2,n1,n2. L1 ≋ⓧ*[n1,n2] K2.ⓑ[I2]V2 → 𝟎 = n2.
 200 /3 width=6 by lveq_fwd_pair_sn, lveq_sym/ qed-.