matita/matita/contribs/lambdadelta/static_2/syntax/lveq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/xoa/ex_3_4.ma".
  16 include "ground_2/xoa/ex_4_1.ma".
  17 include "static_2/notation/relations/voidstareq_4.ma".
  18 include "static_2/syntax/lenv.ma".
  19
  20 (* EQUIVALENCE FOR LOCAL ENVIRONMENTS UP TO EXCLUSION BINDERS ***************)
  21
  22 inductive lveq: bi_relation nat lenv ≝
  23 | lveq_atom   : lveq 0 (⋆) 0 (⋆)
  24 | lveq_bind   : ∀I1,I2,K1,K2. lveq 0 K1 0 K2 →
  25                 lveq 0 (K1.ⓘ[I1]) 0 (K2.ⓘ[I2])
  26 | lveq_void_sn: ∀K1,K2,n1. lveq n1 K1 0 K2 →
  27                 lveq (↑n1) (K1.ⓧ) 0 K2
  28 | lveq_void_dx: ∀K1,K2,n2. lveq 0 K1 n2 K2 →
  29                 lveq 0 K1 (↑n2) (K2.ⓧ)
  30 .
  31
  32 interpretation "equivalence up to exclusion binders (local environment)"
  33    'VoidStarEq L1 n1 n2 L2 = (lveq n1 L1 n2 L2).
  34
  35 (* Basic properties *********************************************************)
  36
  37 lemma lveq_refl: ∀L. L ≋ⓧ*[0,0] L.
  38 #L elim L -L /2 width=1 by lveq_atom, lveq_bind/
  39 qed.
  40
  41 lemma lveq_sym: bi_symmetric … lveq.
  42 #n1 #n2 #L1 #L2 #H elim H -L1 -L2 -n1 -n2
  43 /2 width=1 by lveq_atom, lveq_bind, lveq_void_sn, lveq_void_dx/
  44 qed-.
  45
  46 (* Basic inversion lemmas ***************************************************)
  47
  48 fact lveq_inv_zero_aux: ∀L1,L2,n1,n2. L1 ≋ⓧ*[n1,n2] L2 →
  49                         0 = n1 → 0 = n2 →
  50                         ∨∨ ∧∧ ⋆ = L1 & ⋆ = L2
  51                             | ∃∃I1,I2,K1,K2. K1 ≋ⓧ*[0,0] K2 & K1.ⓘ[I1] = L1 & K2.ⓘ[I2] = L2.
  52 #L1 #L2 #n1 #n2 * -L1 -L2 -n1 -n2
  53 [1: /3 width=1 by or_introl, conj/
  54 |2: /3 width=7 by ex3_4_intro, or_intror/
  55 |*: #K1 #K2 #n #_ #H1 #H2 destruct
  56 ]
  57 qed-.
  58
  59 lemma lveq_inv_zero: ∀L1,L2. L1 ≋ⓧ*[0,0] L2 →
  60                      ∨∨ ∧∧ ⋆ = L1 & ⋆ = L2
  61                       | ∃∃I1,I2,K1,K2. K1 ≋ⓧ*[0,0] K2 & K1.ⓘ[I1] = L1 & K2.ⓘ[I2] = L2.
  62 /2 width=5 by lveq_inv_zero_aux/ qed-.
  63
  64 fact lveq_inv_succ_sn_aux: ∀L1,L2,n1,n2. L1 ≋ⓧ*[n1,n2] L2 →
  65                            ∀m1. ↑m1 = n1 →
  66                            ∃∃K1. K1 ≋ⓧ*[m1,0] L2 & K1.ⓧ = L1 & 0 = n2.
  67 #L1 #L2 #n1 #n2 * -L1 -L2 -n1 -n2
  68 [1: #m #H destruct
  69 |2: #I1 #I2 #K1 #K2 #_ #m #H destruct
  70 |*: #K1 #K2 #n #HK #m #H destruct /2 width=3 by ex3_intro/
  71 ]
  72 qed-.
  73
  74 lemma lveq_inv_succ_sn: ∀L1,K2,n1,n2. L1 ≋ⓧ*[↑n1,n2] K2 →
  75                         ∃∃K1. K1 ≋ⓧ*[n1,0] K2 & K1.ⓧ = L1 & 0 = n2.
  76 /2 width=3 by lveq_inv_succ_sn_aux/ qed-.
  77
  78 lemma lveq_inv_succ_dx: ∀K1,L2,n1,n2. K1 ≋ⓧ*[n1,↑n2] L2 →
  79                         ∃∃K2. K1 ≋ⓧ*[0,n2] K2 & K2.ⓧ = L2 & 0 = n1.
  80 #K1 #L2 #n1 #n2 #H
  81 lapply (lveq_sym … H) -H #H
  82 elim (lveq_inv_succ_sn … H) -H /3 width=3 by lveq_sym, ex3_intro/
  83 qed-.
  84
  85 fact lveq_inv_succ_aux: ∀L1,L2,n1,n2. L1 ≋ⓧ*[n1,n2] L2 →
  86                         ∀m1,m2. ↑m1 = n1 → ↑m2 = n2 → ⊥.
  87 #L1 #L2 #n1 #n2 * -L1 -L2 -n1 -n2
  88 [1: #m1 #m2 #H1 #H2 destruct
  89 |2: #I1 #I2 #K1 #K2 #_ #m1 #m2 #H1 #H2 destruct
  90 |*: #K1 #K2 #n #_ #m1 #m2 #H1 #H2 destruct
  91 ]
  92 qed-.
  93
  94 lemma lveq_inv_succ: ∀L1,L2,n1,n2. L1 ≋ⓧ*[↑n1,↑n2] L2 → ⊥.
  95 /2 width=9 by lveq_inv_succ_aux/ qed-.
  96
  97 (* Advanced inversion lemmas ************************************************)
  98
  99 lemma lveq_inv_bind: ∀I1,I2,K1,K2. K1.ⓘ[I1] ≋ⓧ*[0,0] K2.ⓘ[I2] → K1 ≋ⓧ*[0,0] K2.
 100 #I1 #I2 #K1 #K2 #H
 101 elim (lveq_inv_zero … H) -H * [| #Z1 #Z2 #Y1 #Y2 #HY ] #H1 #H2 destruct //
 102 qed-.
 103
 104 lemma lveq_inv_atom_atom: ∀n1,n2. ⋆ ≋ⓧ*[n1,n2] ⋆ → ∧∧ 0 = n1 & 0 = n2.
 105 * [2: #n1 ] * [2,4: #n2 ] #H
 106 [ elim (lveq_inv_succ … H)
 107 | elim (lveq_inv_succ_dx … H) -H #Y #_ #H1 #H2 destruct
 108 | elim (lveq_inv_succ_sn … H) -H #Y #_ #H1 #H2 destruct
 109 | /2 width=1 by conj/
 110 ]
 111 qed-.
 112
 113 lemma lveq_inv_bind_atom: ∀I1,K1,n1,n2. K1.ⓘ[I1] ≋ⓧ*[n1,n2] ⋆ →
 114                           ∃∃m1. K1 ≋ⓧ*[m1,0] ⋆ & BUnit Void = I1 & ↑m1 = n1 & 0 = n2.
 115 #I1 #K1 * [2: #n1 ] * [2,4: #n2 ] #H
 116 [ elim (lveq_inv_succ … H)
 117 | elim (lveq_inv_succ_dx … H) -H #Y #_ #H1 #H2 destruct
 118 | elim (lveq_inv_succ_sn … H) -H #Y #HY #H1 #H2 destruct /2 width=3 by ex4_intro/
 119 | elim (lveq_inv_zero … H) -H *
 120   [ #H1 #H2 destruct
 121   | #Z1 #Z2 #Y1 #Y2 #_ #H1 #H2 destruct
 122   ]
 123 ]
 124 qed-.
 125
 126 lemma lveq_inv_atom_bind: ∀I2,K2,n1,n2. ⋆ ≋ⓧ*[n1,n2] K2.ⓘ[I2] →
 127                           ∃∃m2. ⋆ ≋ⓧ*[0,m2] K2 & BUnit Void = I2 & 0 = n1 & ↑m2 = n2.
 128 #I2 #K2 #n1 #n2 #H
 129 lapply (lveq_sym … H) -H #H
 130 elim (lveq_inv_bind_atom … H) -H
 131 /3 width=3 by lveq_sym, ex4_intro/
 132 qed-.
 133
 134 lemma lveq_inv_pair_pair: ∀I1,I2,K1,K2,V1,V2,n1,n2. K1.ⓑ[I1]V1 ≋ⓧ*[n1,n2] K2.ⓑ[I2]V2 →
 135                           ∧∧ K1 ≋ⓧ*[0,0] K2 & 0 = n1 & 0 = n2.
 136 #I1 #I2 #K1 #K2 #V1 #V2 * [2: #n1 ] * [2,4: #n2 ] #H
 137 [ elim (lveq_inv_succ … H)
 138 | elim (lveq_inv_succ_dx … H) -H #Y #_ #H1 #H2 destruct
 139 | elim (lveq_inv_succ_sn … H) -H #Y #_ #H1 #H2 destruct
 140 | elim (lveq_inv_zero … H) -H *
 141   [ #H1 #H2 destruct
 142   | #Z1 #Z2 #Y1 #Y2 #HY #H1 #H2 destruct /3 width=1 by and3_intro/
 143   ]
 144 ]
 145 qed-.
 146
 147 lemma lveq_inv_void_succ_sn: ∀L1,L2,n1,n2. L1.ⓧ ≋ⓧ*[↑n1,n2] L2 →
 148                              ∧∧ L1 ≋ ⓧ*[n1,0] L2 & 0 = n2.
 149 #L1 #L2 #n1 #n2 #H
 150 elim (lveq_inv_succ_sn … H) -H #Y #HY #H1 #H2 destruct /2 width=1 by conj/
 151 qed-.
 152
 153 lemma lveq_inv_void_succ_dx: ∀L1,L2,n1,n2. L1 ≋ⓧ*[n1,↑n2] L2.ⓧ →
 154                              ∧∧ L1 ≋ ⓧ*[0,n2] L2 & 0 = n1.
 155 #L1 #L2 #n1 #n2 #H
 156 lapply (lveq_sym … H) -H #H
 157 elim (lveq_inv_void_succ_sn … H) -H
 158 /3 width=1 by lveq_sym, conj/
 159 qed-.
 160
 161 (* Advanced forward lemmas **************************************************)
 162
 163 lemma lveq_fwd_gen: ∀L1,L2,n1,n2. L1 ≋ⓧ*[n1,n2] L2 →
 164                     ∨∨ 0 = n1 | 0 = n2.
 165 #L1 #L2 * [2: #n1 ] * [2,4: #n2 ] #H
 166 [ elim (lveq_inv_succ … H) ]
 167 /2 width=1 by or_introl, or_intror/
 168 qed-.
 169
 170 lemma lveq_fwd_pair_sn: ∀I1,K1,L2,V1,n1,n2. K1.ⓑ[I1]V1 ≋ⓧ*[n1,n2] L2 → 0 = n1.
 171 #I1 #K1 #L2 #V1 * [2: #n1 ] // * [2: #n2 ] #H
 172 [ elim (lveq_inv_succ … H)
 173 | elim (lveq_inv_succ_sn … H) -H #Y #_ #H1 #H2 destruct
 174 ]
 175 qed-.
 176
 177 lemma lveq_fwd_pair_dx: ∀I2,L1,K2,V2,n1,n2. L1 ≋ⓧ*[n1,n2] K2.ⓑ[I2]V2 → 0 = n2.
 178 /3 width=6 by lveq_fwd_pair_sn, lveq_sym/ qed-.