matita/matita/contribs/lambdadelta/static_2/syntax/lveq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/notation/relations/voidstareq_4.ma".
  16 include "static_2/syntax/lenv.ma".
  17
  18 (* EQUIVALENCE FOR LOCAL ENVIRONMENTS UP TO EXCLUSION BINDERS ***************)
  19
  20 inductive lveq: bi_relation nat lenv ≝
  21 | lveq_atom   : lveq 0 (⋆) 0 (⋆)
  22 | lveq_bind   : ∀I1,I2,K1,K2. lveq 0 K1 0 K2 →
  23                 lveq 0 (K1.ⓘ{I1}) 0 (K2.ⓘ{I2})
  24 | lveq_void_sn: ∀K1,K2,n1. lveq n1 K1 0 K2 →
  25                 lveq (↑n1) (K1.ⓧ) 0 K2
  26 | lveq_void_dx: ∀K1,K2,n2. lveq 0 K1 n2 K2 →
  27                 lveq 0 K1 (↑n2) (K2.ⓧ)
  28 .
  29
  30 interpretation "equivalence up to exclusion binders (local environment)"
  31    'VoidStarEq L1 n1 n2 L2 = (lveq n1 L1 n2 L2).
  32
  33 (* Basic properties *********************************************************)
  34
  35 lemma lveq_refl: ∀L. L ≋ⓧ*[0, 0] L.
  36 #L elim L -L /2 width=1 by lveq_atom, lveq_bind/
  37 qed.
  38
  39 lemma lveq_sym: bi_symmetric … lveq.
  40 #n1 #n2 #L1 #L2 #H elim H -L1 -L2 -n1 -n2
  41 /2 width=1 by lveq_atom, lveq_bind, lveq_void_sn, lveq_void_dx/
  42 qed-.
  43
  44 (* Basic inversion lemmas ***************************************************)
  45
  46 fact lveq_inv_zero_aux: ∀L1,L2,n1,n2. L1 ≋ⓧ*[n1, n2] L2 →
  47                         0 = n1 → 0 = n2 →
  48                         ∨∨ ∧∧ ⋆ = L1 & ⋆ = L2
  49                             | ∃∃I1,I2,K1,K2. K1 ≋ⓧ*[0, 0] K2 & K1.ⓘ{I1} = L1 & K2.ⓘ{I2} = L2.
  50 #L1 #L2 #n1 #n2 * -L1 -L2 -n1 -n2
  51 [1: /3 width=1 by or_introl, conj/
  52 |2: /3 width=7 by ex3_4_intro, or_intror/
  53 |*: #K1 #K2 #n #_ #H1 #H2 destruct
  54 ]
  55 qed-.
  56
  57 lemma lveq_inv_zero: ∀L1,L2. L1 ≋ⓧ*[0, 0] L2 →
  58                      ∨∨ ∧∧ ⋆ = L1 & ⋆ = L2
  59                       | ∃∃I1,I2,K1,K2. K1 ≋ⓧ*[0, 0] K2 & K1.ⓘ{I1} = L1 & K2.ⓘ{I2} = L2.
  60 /2 width=5 by lveq_inv_zero_aux/ qed-.
  61
  62 fact lveq_inv_succ_sn_aux: ∀L1,L2,n1,n2. L1 ≋ⓧ*[n1, n2] L2 →
  63                            ∀m1. ↑m1 = n1 →
  64                            ∃∃K1. K1 ≋ⓧ*[m1, 0] L2 & K1.ⓧ = L1 & 0 = n2.
  65 #L1 #L2 #n1 #n2 * -L1 -L2 -n1 -n2
  66 [1: #m #H destruct
  67 |2: #I1 #I2 #K1 #K2 #_ #m #H destruct
  68 |*: #K1 #K2 #n #HK #m #H destruct /2 width=3 by ex3_intro/
  69 ]
  70 qed-.
  71
  72 lemma lveq_inv_succ_sn: ∀L1,K2,n1,n2. L1 ≋ⓧ*[↑n1, n2] K2 →
  73                         ∃∃K1. K1 ≋ⓧ*[n1, 0] K2 & K1.ⓧ = L1 & 0 = n2.
  74 /2 width=3 by lveq_inv_succ_sn_aux/ qed-.
  75
  76 lemma lveq_inv_succ_dx: ∀K1,L2,n1,n2. K1 ≋ⓧ*[n1, ↑n2] L2 →
  77                         ∃∃K2. K1 ≋ⓧ*[0, n2] K2 & K2.ⓧ = L2 & 0 = n1.
  78 #K1 #L2 #n1 #n2 #H
  79 lapply (lveq_sym … H) -H #H
  80 elim (lveq_inv_succ_sn … H) -H /3 width=3 by lveq_sym, ex3_intro/
  81 qed-.
  82
  83 fact lveq_inv_succ_aux: ∀L1,L2,n1,n2. L1 ≋ⓧ*[n1, n2] L2 →
  84                         ∀m1,m2. ↑m1 = n1 → ↑m2 = n2 → ⊥.
  85 #L1 #L2 #n1 #n2 * -L1 -L2 -n1 -n2
  86 [1: #m1 #m2 #H1 #H2 destruct
  87 |2: #I1 #I2 #K1 #K2 #_ #m1 #m2 #H1 #H2 destruct
  88 |*: #K1 #K2 #n #_ #m1 #m2 #H1 #H2 destruct
  89 ]
  90 qed-.
  91
  92 lemma lveq_inv_succ: ∀L1,L2,n1,n2. L1 ≋ⓧ*[↑n1, ↑n2] L2 → ⊥.
  93 /2 width=9 by lveq_inv_succ_aux/ qed-.
  94
  95 (* Advanced inversion lemmas ************************************************)
  96
  97 lemma lveq_inv_bind: ∀I1,I2,K1,K2. K1.ⓘ{I1} ≋ⓧ*[0, 0] K2.ⓘ{I2} → K1 ≋ⓧ*[0, 0] K2.
  98 #I1 #I2 #K1 #K2 #H
  99 elim (lveq_inv_zero … H) -H * [| #Z1 #Z2 #Y1 #Y2 #HY ] #H1 #H2 destruct //
 100 qed-.
 101
 102 lemma lveq_inv_atom_atom: ∀n1,n2. ⋆ ≋ⓧ*[n1, n2] ⋆ → ∧∧ 0 = n1 & 0 = n2.
 103 * [2: #n1 ] * [2,4: #n2 ] #H
 104 [ elim (lveq_inv_succ … H)
 105 | elim (lveq_inv_succ_dx … H) -H #Y #_ #H1 #H2 destruct
 106 | elim (lveq_inv_succ_sn … H) -H #Y #_ #H1 #H2 destruct
 107 | /2 width=1 by conj/
 108 ]
 109 qed-.
 110
 111 lemma lveq_inv_bind_atom: ∀I1,K1,n1,n2. K1.ⓘ{I1} ≋ⓧ*[n1, n2] ⋆ →
 112                           ∃∃m1. K1 ≋ⓧ*[m1, 0] ⋆ & BUnit Void = I1 & ↑m1 = n1 & 0 = n2.
 113 #I1 #K1 * [2: #n1 ] * [2,4: #n2 ] #H
 114 [ elim (lveq_inv_succ … H)
 115 | elim (lveq_inv_succ_dx … H) -H #Y #_ #H1 #H2 destruct
 116 | elim (lveq_inv_succ_sn … H) -H #Y #HY #H1 #H2 destruct /2 width=3 by ex4_intro/
 117 | elim (lveq_inv_zero … H) -H *
 118   [ #H1 #H2 destruct
 119   | #Z1 #Z2 #Y1 #Y2 #_ #H1 #H2 destruct
 120   ]
 121 ]
 122 qed-.
 123
 124 lemma lveq_inv_atom_bind: ∀I2,K2,n1,n2. ⋆ ≋ⓧ*[n1, n2] K2.ⓘ{I2} →
 125                           ∃∃m2. ⋆ ≋ⓧ*[0, m2] K2 & BUnit Void = I2 & 0 = n1 & ↑m2 = n2.
 126 #I2 #K2 #n1 #n2 #H
 127 lapply (lveq_sym … H) -H #H
 128 elim (lveq_inv_bind_atom … H) -H
 129 /3 width=3 by lveq_sym, ex4_intro/
 130 qed-.
 131
 132 lemma lveq_inv_pair_pair: ∀I1,I2,K1,K2,V1,V2,n1,n2. K1.ⓑ{I1}V1 ≋ⓧ*[n1, n2] K2.ⓑ{I2}V2 →
 133                           ∧∧ K1 ≋ⓧ*[0, 0] K2 & 0 = n1 & 0 = n2.
 134 #I1 #I2 #K1 #K2 #V1 #V2 * [2: #n1 ] * [2,4: #n2 ] #H
 135 [ elim (lveq_inv_succ … H)
 136 | elim (lveq_inv_succ_dx … H) -H #Y #_ #H1 #H2 destruct
 137 | elim (lveq_inv_succ_sn … H) -H #Y #_ #H1 #H2 destruct
 138 | elim (lveq_inv_zero … H) -H *
 139   [ #H1 #H2 destruct
 140   | #Z1 #Z2 #Y1 #Y2 #HY #H1 #H2 destruct /3 width=1 by and3_intro/
 141   ]
 142 ]
 143 qed-.
 144
 145 lemma lveq_inv_void_succ_sn: ∀L1,L2,n1,n2. L1.ⓧ ≋ⓧ*[↑n1, n2] L2 →
 146                              ∧∧ L1 ≋ ⓧ*[n1, 0] L2 & 0 = n2.
 147 #L1 #L2 #n1 #n2 #H
 148 elim (lveq_inv_succ_sn … H) -H #Y #HY #H1 #H2 destruct /2 width=1 by conj/
 149 qed-.
 150
 151 lemma lveq_inv_void_succ_dx: ∀L1,L2,n1,n2. L1 ≋ⓧ*[n1, ↑n2] L2.ⓧ →
 152                              ∧∧ L1 ≋ ⓧ*[0, n2] L2 & 0 = n1.
 153 #L1 #L2 #n1 #n2 #H
 154 lapply (lveq_sym … H) -H #H
 155 elim (lveq_inv_void_succ_sn … H) -H
 156 /3 width=1 by lveq_sym, conj/
 157 qed-.
 158
 159 (* Advanced forward lemmas **************************************************)
 160
 161 lemma lveq_fwd_gen: ∀L1,L2,n1,n2. L1 ≋ⓧ*[n1, n2] L2 →
 162                     ∨∨ 0 = n1 | 0 = n2.
 163 #L1 #L2 * [2: #n1 ] * [2,4: #n2 ] #H
 164 [ elim (lveq_inv_succ … H) ]
 165 /2 width=1 by or_introl, or_intror/
 166 qed-.
 167
 168 lemma lveq_fwd_pair_sn: ∀I1,K1,L2,V1,n1,n2. K1.ⓑ{I1}V1 ≋ⓧ*[n1, n2] L2 → 0 = n1.
 169 #I1 #K1 #L2 #V1 * [2: #n1 ] // * [2: #n2 ] #H
 170 [ elim (lveq_inv_succ … H)
 171 | elim (lveq_inv_succ_sn … H) -H #Y #_ #H1 #H2 destruct
 172 ]
 173 qed-.
 174
 175 lemma lveq_fwd_pair_dx: ∀I2,L1,K2,V2,n1,n2. L1 ≋ⓧ*[n1, n2] K2.ⓑ{I2}V2 → 0 = n2.
 176 /3 width=6 by lveq_fwd_pair_sn, lveq_sym/ qed-.