matita/matita/contribs/lambdadelta/static_2/syntax/tdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/notation/relations/stareq_4.ma".
  16 include "static_2/syntax/item_sd.ma".
  17 include "static_2/syntax/term.ma".
  18
  19 (* DEGREE-BASED EQUIVALENCE ON TERMS ****************************************)
  20
  21 inductive tdeq (h) (o): relation term ≝
  22 | tdeq_sort: ∀s1,s2,d. deg h o s1 d → deg h o s2 d → tdeq h o (⋆s1) (⋆s2)
  23 | tdeq_lref: ∀i. tdeq h o (#i) (#i)
  24 | tdeq_gref: ∀l. tdeq h o (§l) (§l)
  25 | tdeq_pair: ∀I,V1,V2,T1,T2. tdeq h o V1 V2 → tdeq h o T1 T2 → tdeq h o (②{I}V1.T1) (②{I}V2.T2)
  26 .
  27
  28 interpretation
  29    "context-free degree-based equivalence (term)"
  30    'StarEq h o T1 T2 = (tdeq h o T1 T2).
  31
  32 (* Basic properties *********************************************************)
  33
  34 lemma tdeq_refl: ∀h,o. reflexive … (tdeq h o).
  35 #h #o #T elim T -T /2 width=1 by tdeq_pair/
  36 * /2 width=1 by tdeq_lref, tdeq_gref/
  37 #s elim (deg_total h o s) /2 width=3 by tdeq_sort/
  38 qed.
  39
  40 lemma tdeq_sym: ∀h,o. symmetric … (tdeq h o).
  41 #h #o #T1 #T2 #H elim H -T1 -T2
  42 /2 width=3 by tdeq_sort, tdeq_lref, tdeq_gref, tdeq_pair/
  43 qed-.
  44
  45 (* Basic inversion lemmas ***************************************************)
  46
  47 fact tdeq_inv_sort1_aux: ∀h,o,X,Y. X ≛[h, o] Y → ∀s1. X = ⋆s1 →
  48                          ∃∃s2,d. deg h o s1 d & deg h o s2 d & Y = ⋆s2.
  49 #h #o #X #Y * -X -Y
  50 [ #s1 #s2 #d #Hs1 #Hs2 #s #H destruct /2 width=5 by ex3_2_intro/
  51 | #i #s #H destruct
  52 | #l #s #H destruct
  53 | #I #V1 #V2 #T1 #T2 #_ #_ #s #H destruct
  54 ]
  55 qed-.
  56
  57 lemma tdeq_inv_sort1: ∀h,o,Y,s1. ⋆s1 ≛[h, o] Y →
  58                       ∃∃s2,d. deg h o s1 d & deg h o s2 d & Y = ⋆s2.
  59 /2 width=3 by tdeq_inv_sort1_aux/ qed-.
  60
  61 fact tdeq_inv_lref1_aux: ∀h,o,X,Y. X ≛[h, o] Y → ∀i. X = #i → Y = #i.
  62 #h #o #X #Y * -X -Y //
  63 [ #s1 #s2 #d #_ #_ #j #H destruct
  64 | #I #V1 #V2 #T1 #T2 #_ #_ #j #H destruct
  65 ]
  66 qed-.
  67
  68 lemma tdeq_inv_lref1: ∀h,o,Y,i. #i ≛[h, o] Y → Y = #i.
  69 /2 width=5 by tdeq_inv_lref1_aux/ qed-.
  70
  71 fact tdeq_inv_gref1_aux: ∀h,o,X,Y. X ≛[h, o] Y → ∀l. X = §l → Y = §l.
  72 #h #o #X #Y * -X -Y //
  73 [ #s1 #s2 #d #_ #_ #k #H destruct
  74 | #I #V1 #V2 #T1 #T2 #_ #_ #k #H destruct
  75 ]
  76 qed-.
  77
  78 lemma tdeq_inv_gref1: ∀h,o,Y,l. §l ≛[h, o] Y → Y = §l.
  79 /2 width=5 by tdeq_inv_gref1_aux/ qed-.
  80
  81 fact tdeq_inv_pair1_aux: ∀h,o,X,Y. X ≛[h, o] Y → ∀I,V1,T1. X = ②{I}V1.T1 →
  82                          ∃∃V2,T2. V1 ≛[h, o] V2 & T1 ≛[h, o] T2 & Y = ②{I}V2.T2.
  83 #h #o #X #Y * -X -Y
  84 [ #s1 #s2 #d #_ #_ #J #W1 #U1 #H destruct
  85 | #i #J #W1 #U1 #H destruct
  86 | #l #J #W1 #U1 #H destruct
  87 | #I #V1 #V2 #T1 #T2 #HV #HT #J #W1 #U1 #H destruct /2 width=5 by ex3_2_intro/
  88 ]
  89 qed-.
  90
  91 lemma tdeq_inv_pair1: ∀h,o,I,V1,T1,Y. ②{I}V1.T1 ≛[h, o] Y →
  92                       ∃∃V2,T2. V1 ≛[h, o] V2 & T1 ≛[h, o] T2 & Y = ②{I}V2.T2.
  93 /2 width=3 by tdeq_inv_pair1_aux/ qed-.
  94
  95 lemma tdeq_inv_sort2: ∀h,o,X1,s2. X1 ≛[h, o] ⋆s2 →
  96                       ∃∃s1,d. deg h o s1 d & deg h o s2 d & X1 = ⋆s1.
  97 #h #o #X1 #s2 #H
  98 elim (tdeq_inv_sort1 h o X1 s2)
  99 /2 width=5 by tdeq_sym, ex3_2_intro/
 100 qed-.
 101
 102 lemma tdeq_inv_pair2: ∀h,o,I,X1,V2,T2. X1 ≛[h, o] ②{I}V2.T2 →
 103                       ∃∃V1,T1. V1 ≛[h, o] V2 & T1 ≛[h, o] T2 & X1 = ②{I}V1.T1.
 104 #h #o #I #X1 #V2 #T2 #H
 105 elim (tdeq_inv_pair1 h o I V2 T2 X1)
 106 [ #V1 #T1 #HV #HT #H destruct ]
 107 /3 width=5 by tdeq_sym, ex3_2_intro/
 108 qed-.
 109
 110 (* Advanced inversion lemmas ************************************************)
 111
 112 lemma tdeq_inv_sort1_deg: ∀h,o,Y,s1. ⋆s1 ≛[h, o] Y → ∀d. deg h o s1 d →
 113                           ∃∃s2. deg h o s2 d & Y = ⋆s2.
 114 #h #o #Y #s1 #H #d #Hs1 elim (tdeq_inv_sort1 … H) -H
 115 #s2 #x #Hx <(deg_mono h o … Hx … Hs1) -s1 -d /2 width=3 by ex2_intro/
 116 qed-.
 117
 118 lemma tdeq_inv_sort_deg: ∀h,o,s1,s2. ⋆s1 ≛[h, o] ⋆s2 →
 119                          ∀d1,d2. deg h o s1 d1 → deg h o s2 d2 →
 120                          d1 = d2.
 121 #h #o #s1 #y #H #d1 #d2 #Hs1 #Hy
 122 elim (tdeq_inv_sort1_deg … H … Hs1) -s1 #s2 #Hs2 #H destruct
 123 <(deg_mono h o … Hy … Hs2) -s2 -d1 //
 124 qed-.
 125
 126 lemma tdeq_inv_pair: ∀h,o,I1,I2,V1,V2,T1,T2. ②{I1}V1.T1 ≛[h, o] ②{I2}V2.T2 →
 127                      ∧∧ I1 = I2 & V1 ≛[h, o] V2 & T1 ≛[h, o] T2.
 128 #h #o #I1 #I2 #V1 #V2 #T1 #T2 #H elim (tdeq_inv_pair1 … H) -H
 129 #V0 #T0 #HV #HT #H destruct /2 width=1 by and3_intro/
 130 qed-.
 131
 132 lemma tdeq_inv_pair_xy_x: ∀h,o,I,V,T. ②{I}V.T ≛[h, o] V → ⊥.
 133 #h #o #I #V elim V -V
 134 [ #J #T #H elim (tdeq_inv_pair1 … H) -H #X #Y #_ #_ #H destruct
 135 | #J #X #Y #IHX #_ #T #H elim (tdeq_inv_pair … H) -H #H #HY #_ destruct /2 width=2 by/
 136 ]
 137 qed-.
 138
 139 lemma tdeq_inv_pair_xy_y: ∀h,o,I,T,V. ②{I}V.T ≛[h, o] T → ⊥.
 140 #h #o #I #T elim T -T
 141 [ #J #V #H elim (tdeq_inv_pair1 … H) -H #X #Y #_ #_ #H destruct
 142 | #J #X #Y #_ #IHY #V #H elim (tdeq_inv_pair … H) -H #H #_ #HY destruct /2 width=2 by/
 143 ]
 144 qed-.
 145
 146 (* Basic forward lemmas *****************************************************)
 147
 148 lemma tdeq_fwd_atom1: ∀h,o,I,Y. ⓪{I} ≛[h, o] Y → ∃J. Y = ⓪{J}.
 149 #h #o * #x #Y #H [ elim (tdeq_inv_sort1 … H) -H ]
 150 /3 width=4 by tdeq_inv_gref1, tdeq_inv_lref1, ex_intro/
 151 qed-.
 152
 153 (* Advanced properties ******************************************************)
 154
 155 lemma tdeq_dec: ∀h,o,T1,T2. Decidable (T1 ≛[h, o] T2).
 156 #h #o #T1 elim T1 -T1 [ * #s1 | #I1 #V1 #T1 #IHV #IHT ] * [1,3,5,7: * #s2 |*: #I2 #V2 #T2 ]
 157 [ elim (deg_total h o s1) #d1 #H1
 158   elim (deg_total h o s2) #d2 #H2
 159   elim (eq_nat_dec d1 d2) #Hd12 destruct /3 width=3 by tdeq_sort, or_introl/
 160   @or_intror #H
 161   lapply (tdeq_inv_sort_deg … H … H1 H2) -H -H1 -H2 /2 width=1 by/
 162 |2,3,13:
 163   @or_intror #H
 164   elim (tdeq_inv_sort1 … H) -H #x1 #x2 #_ #_ #H destruct
 165 |4,6,14:
 166   @or_intror #H
 167   lapply (tdeq_inv_lref1 … H) -H #H destruct
 168 |5:
 169   elim (eq_nat_dec s1 s2) #Hs12 destruct /2 width=1 by or_introl/
 170   @or_intror #H
 171   lapply (tdeq_inv_lref1 … H) -H #H destruct /2 width=1 by/
 172 |7,8,15:
 173   @or_intror #H
 174   lapply (tdeq_inv_gref1 … H) -H #H destruct
 175 |9:
 176   elim (eq_nat_dec s1 s2) #Hs12 destruct /2 width=1 by or_introl/
 177   @or_intror #H
 178   lapply (tdeq_inv_gref1 … H) -H #H destruct /2 width=1 by/
 179 |10,11,12:
 180   @or_intror #H
 181   elim (tdeq_inv_pair1 … H) -H #X1 #X2 #_ #_ #H destruct
 182 |16:
 183   elim (eq_item2_dec I1 I2) #HI12 destruct
 184   [ elim (IHV V2) -IHV #HV12
 185     elim (IHT T2) -IHT #HT12
 186     [ /3 width=1 by tdeq_pair, or_introl/ ]
 187   ]
 188   @or_intror #H
 189   elim (tdeq_inv_pair … H) -H /2 width=1 by/
 190 ]
 191 qed-.
 192
 193 (* Negated inversion lemmas *************************************************)
 194
 195 lemma tdneq_inv_pair: ∀h,o,I1,I2,V1,V2,T1,T2.
 196                       (②{I1}V1.T1 ≛[h, o] ②{I2}V2.T2 → ⊥) →
 197                       ∨∨ I1 = I2 → ⊥
 198                       |  (V1 ≛[h, o] V2 → ⊥)
 199                       |  (T1 ≛[h, o] T2 → ⊥).
 200 #h #o #I1 #I2 #V1 #V2 #T1 #T2 #H12
 201 elim (eq_item2_dec I1 I2) /3 width=1 by or3_intro0/ #H destruct
 202 elim (tdeq_dec h o V1 V2) /3 width=1 by or3_intro1/
 203 elim (tdeq_dec h o T1 T2) /4 width=1 by tdeq_pair, or3_intro2/
 204 qed-.