matita/matita/contribs/lambdadelta/static_2/syntax/tdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/notation/relations/stareq_4.ma".
  16 include "static_2/syntax/item_sd.ma".
  17 include "static_2/syntax/term.ma".
  18
  19 (* DEGREE-BASED EQUIVALENCE ON TERMS ****************************************)
  20
  21 inductive tdeq (h) (o): relation term ≝
  22 | tdeq_sort: ∀s1,s2,d. deg h o s1 d → deg h o s2 d → tdeq h o (⋆s1) (⋆s2)
  23 | tdeq_lref: ∀i. tdeq h o (#i) (#i)
  24 | tdeq_gref: ∀l. tdeq h o (§l) (§l)
  25 | tdeq_pair: ∀I,V1,V2,T1,T2. tdeq h o V1 V2 → tdeq h o T1 T2 → tdeq h o (②{I}V1.T1) (②{I}V2.T2)
  26 .
  27
  28 interpretation
  29    "context-free degree-based equivalence (term)"
  30    'StarEq h o T1 T2 = (tdeq h o T1 T2).
  31
  32 (* Basic properties *********************************************************)
  33
  34 lemma tdeq_refl: ∀h,o. reflexive … (tdeq h o).
  35 #h #o #T elim T -T /2 width=1 by tdeq_pair/
  36 * /2 width=1 by tdeq_lref, tdeq_gref/
  37 #s elim (deg_total h o s) /2 width=3 by tdeq_sort/
  38 qed.
  39
  40 lemma tdeq_sym: ∀h,o. symmetric … (tdeq h o).
  41 #h #o #T1 #T2 #H elim H -T1 -T2
  42 /2 width=3 by tdeq_sort, tdeq_lref, tdeq_gref, tdeq_pair/
  43 qed-.
  44
  45 (* Basic inversion lemmas ***************************************************)
  46
  47 fact tdeq_inv_sort1_aux: ∀h,o,X,Y. X ≛[h, o] Y → ∀s1. X = ⋆s1 →
  48                          ∃∃s2,d. deg h o s1 d & deg h o s2 d & Y = ⋆s2.
  49 #h #o #X #Y * -X -Y
  50 [ #s1 #s2 #d #Hs1 #Hs2 #s #H destruct /2 width=5 by ex3_2_intro/
  51 | #i #s #H destruct
  52 | #l #s #H destruct
  53 | #I #V1 #V2 #T1 #T2 #_ #_ #s #H destruct
  54 ]
  55 qed-.
  56
  57 lemma tdeq_inv_sort1: ∀h,o,Y,s1. ⋆s1 ≛[h, o] Y →
  58                       ∃∃s2,d. deg h o s1 d & deg h o s2 d & Y = ⋆s2.
  59 /2 width=3 by tdeq_inv_sort1_aux/ qed-.
  60
  61 fact tdeq_inv_lref1_aux: ∀h,o,X,Y. X ≛[h, o] Y → ∀i. X = #i → Y = #i.
  62 #h #o #X #Y * -X -Y //
  63 [ #s1 #s2 #d #_ #_ #j #H destruct
  64 | #I #V1 #V2 #T1 #T2 #_ #_ #j #H destruct
  65 ]
  66 qed-.
  67
  68 lemma tdeq_inv_lref1: ∀h,o,Y,i. #i ≛[h, o] Y → Y = #i.
  69 /2 width=5 by tdeq_inv_lref1_aux/ qed-.
  70
  71 fact tdeq_inv_gref1_aux: ∀h,o,X,Y. X ≛[h, o] Y → ∀l. X = §l → Y = §l.
  72 #h #o #X #Y * -X -Y //
  73 [ #s1 #s2 #d #_ #_ #k #H destruct
  74 | #I #V1 #V2 #T1 #T2 #_ #_ #k #H destruct
  75 ]
  76 qed-.
  77
  78 lemma tdeq_inv_gref1: ∀h,o,Y,l. §l ≛[h, o] Y → Y = §l.
  79 /2 width=5 by tdeq_inv_gref1_aux/ qed-.
  80
  81 fact tdeq_inv_pair1_aux: ∀h,o,X,Y. X ≛[h, o] Y → ∀I,V1,T1. X = ②{I}V1.T1 →
  82                          ∃∃V2,T2. V1 ≛[h, o] V2 & T1 ≛[h, o] T2 & Y = ②{I}V2.T2.
  83 #h #o #X #Y * -X -Y
  84 [ #s1 #s2 #d #_ #_ #J #W1 #U1 #H destruct
  85 | #i #J #W1 #U1 #H destruct
  86 | #l #J #W1 #U1 #H destruct
  87 | #I #V1 #V2 #T1 #T2 #HV #HT #J #W1 #U1 #H destruct /2 width=5 by ex3_2_intro/
  88 ]
  89 qed-.
  90
  91 lemma tdeq_inv_pair1: ∀h,o,I,V1,T1,Y. ②{I}V1.T1 ≛[h, o] Y →
  92                       ∃∃V2,T2. V1 ≛[h, o] V2 & T1 ≛[h, o] T2 & Y = ②{I}V2.T2.
  93 /2 width=3 by tdeq_inv_pair1_aux/ qed-.
  94
  95 lemma tdeq_inv_pair2: ∀h,o,I,X1,V2,T2. X1 ≛[h, o] ②{I}V2.T2 →
  96                       ∃∃V1,T1. V1 ≛[h, o] V2 & T1 ≛[h, o] T2 & X1 = ②{I}V1.T1.
  97 #h #o #I #X1 #V2 #T2 #H
  98 elim (tdeq_inv_pair1 h o I V2 T2 X1)
  99 [ #V1 #T1 #HV #HT #H destruct ]
 100 /3 width=5 by tdeq_sym, ex3_2_intro/
 101 qed-.
 102
 103 (* Advanced inversion lemmas ************************************************)
 104
 105 lemma tdeq_inv_sort1_deg: ∀h,o,Y,s1. ⋆s1 ≛[h, o] Y → ∀d. deg h o s1 d →
 106                           ∃∃s2. deg h o s2 d & Y = ⋆s2.
 107 #h #o #Y #s1 #H #d #Hs1 elim (tdeq_inv_sort1 … H) -H
 108 #s2 #x #Hx <(deg_mono h o … Hx … Hs1) -s1 -d /2 width=3 by ex2_intro/
 109 qed-.
 110
 111 lemma tdeq_inv_sort_deg: ∀h,o,s1,s2. ⋆s1 ≛[h, o] ⋆s2 →
 112                          ∀d1,d2. deg h o s1 d1 → deg h o s2 d2 →
 113                          d1 = d2.
 114 #h #o #s1 #y #H #d1 #d2 #Hs1 #Hy
 115 elim (tdeq_inv_sort1_deg … H … Hs1) -s1 #s2 #Hs2 #H destruct
 116 <(deg_mono h o … Hy … Hs2) -s2 -d1 //
 117 qed-.
 118
 119 lemma tdeq_inv_pair: ∀h,o,I1,I2,V1,V2,T1,T2. ②{I1}V1.T1 ≛[h, o] ②{I2}V2.T2 →
 120                      ∧∧ I1 = I2 & V1 ≛[h, o] V2 & T1 ≛[h, o] T2.
 121 #h #o #I1 #I2 #V1 #V2 #T1 #T2 #H elim (tdeq_inv_pair1 … H) -H
 122 #V0 #T0 #HV #HT #H destruct /2 width=1 by and3_intro/
 123 qed-.
 124
 125 lemma tdeq_inv_pair_xy_x: ∀h,o,I,V,T. ②{I}V.T ≛[h, o] V → ⊥.
 126 #h #o #I #V elim V -V
 127 [ #J #T #H elim (tdeq_inv_pair1 … H) -H #X #Y #_ #_ #H destruct
 128 | #J #X #Y #IHX #_ #T #H elim (tdeq_inv_pair … H) -H #H #HY #_ destruct /2 width=2 by/
 129 ]
 130 qed-.
 131
 132 lemma tdeq_inv_pair_xy_y: ∀h,o,I,T,V. ②{I}V.T ≛[h, o] T → ⊥.
 133 #h #o #I #T elim T -T
 134 [ #J #V #H elim (tdeq_inv_pair1 … H) -H #X #Y #_ #_ #H destruct
 135 | #J #X #Y #_ #IHY #V #H elim (tdeq_inv_pair … H) -H #H #_ #HY destruct /2 width=2 by/
 136 ]
 137 qed-.
 138
 139 (* Basic forward lemmas *****************************************************)
 140
 141 lemma tdeq_fwd_atom1: ∀h,o,I,Y. ⓪{I} ≛[h, o] Y → ∃J. Y = ⓪{J}.
 142 #h #o * #x #Y #H [ elim (tdeq_inv_sort1 … H) -H ]
 143 /3 width=4 by tdeq_inv_gref1, tdeq_inv_lref1, ex_intro/
 144 qed-.
 145
 146 (* Advanced properties ******************************************************)
 147
 148 lemma tdeq_dec: ∀h,o,T1,T2. Decidable (T1 ≛[h, o] T2).
 149 #h #o #T1 elim T1 -T1 [ * #s1 | #I1 #V1 #T1 #IHV #IHT ] * [1,3,5,7: * #s2 |*: #I2 #V2 #T2 ]
 150 [ elim (deg_total h o s1) #d1 #H1
 151   elim (deg_total h o s2) #d2 #H2
 152   elim (eq_nat_dec d1 d2) #Hd12 destruct /3 width=3 by tdeq_sort, or_introl/
 153   @or_intror #H
 154   lapply (tdeq_inv_sort_deg … H … H1 H2) -H -H1 -H2 /2 width=1 by/
 155 |2,3,13:
 156   @or_intror #H
 157   elim (tdeq_inv_sort1 … H) -H #x1 #x2 #_ #_ #H destruct
 158 |4,6,14:
 159   @or_intror #H
 160   lapply (tdeq_inv_lref1 … H) -H #H destruct
 161 |5:
 162   elim (eq_nat_dec s1 s2) #Hs12 destruct /2 width=1 by or_introl/
 163   @or_intror #H
 164   lapply (tdeq_inv_lref1 … H) -H #H destruct /2 width=1 by/
 165 |7,8,15:
 166   @or_intror #H
 167   lapply (tdeq_inv_gref1 … H) -H #H destruct
 168 |9:
 169   elim (eq_nat_dec s1 s2) #Hs12 destruct /2 width=1 by or_introl/
 170   @or_intror #H
 171   lapply (tdeq_inv_gref1 … H) -H #H destruct /2 width=1 by/
 172 |10,11,12:
 173   @or_intror #H
 174   elim (tdeq_inv_pair1 … H) -H #X1 #X2 #_ #_ #H destruct
 175 |16:
 176   elim (eq_item2_dec I1 I2) #HI12 destruct
 177   [ elim (IHV V2) -IHV #HV12
 178     elim (IHT T2) -IHT #HT12
 179     [ /3 width=1 by tdeq_pair, or_introl/ ]
 180   ]
 181   @or_intror #H
 182   elim (tdeq_inv_pair … H) -H /2 width=1 by/
 183 ]
 184 qed-.
 185
 186 (* Negated inversion lemmas *************************************************)
 187
 188 lemma tdneq_inv_pair: ∀h,o,I1,I2,V1,V2,T1,T2.
 189                       (②{I1}V1.T1 ≛[h, o] ②{I2}V2.T2 → ⊥) →
 190                       ∨∨ I1 = I2 → ⊥
 191                       |  (V1 ≛[h, o] V2 → ⊥)
 192                       |  (T1 ≛[h, o] T2 → ⊥).
 193 #h #o #I1 #I2 #V1 #V2 #T1 #T2 #H12
 194 elim (eq_item2_dec I1 I2) /3 width=1 by or3_intro0/ #H destruct
 195 elim (tdeq_dec h o V1 V2) /3 width=1 by or3_intro1/
 196 elim (tdeq_dec h o T1 T2) /4 width=1 by tdeq_pair, or3_intro2/
 197 qed-.