matita/matita/contribs/lambdadelta/static_2/syntax/tdeq_tdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/syntax/tdeq.ma".
  16
  17 (* SORT-IRRELEVANT EQUIVALENCE ON TERMS *************************************)
  18
  19 (* Main properties **********************************************************)
  20
  21 theorem tdeq_trans: Transitive … tdeq.
  22 #T1 #T #H elim H -T1 -T
  23 [ #s1 #s #X #H
  24   elim (tdeq_inv_sort1 … H) -s /2 width=1 by tdeq_sort/
  25 | #i1 #i #H <(tdeq_inv_lref1 … H) -H //
  26 | #l1 #l #H <(tdeq_inv_gref1 … H) -H //
  27 | #I #V1 #V #T1 #T #_ #_ #IHV #IHT #X #H
  28   elim (tdeq_inv_pair1 … H) -H /3 width=1 by tdeq_pair/
  29 ]
  30 qed-.
  31
  32 theorem tdeq_canc_sn: left_cancellable … tdeq.
  33 /3 width=3 by tdeq_trans, tdeq_sym/ qed-.
  34
  35 theorem tdeq_canc_dx: right_cancellable … tdeq.
  36 /3 width=3 by tdeq_trans, tdeq_sym/ qed-.
  37
  38 theorem tdeq_repl: ∀T1,T2. T1 ≛ T2 →
  39                    ∀U1. T1 ≛ U1 → ∀U2. T2 ≛ U2 → U1 ≛ U2.
  40 /3 width=3 by tdeq_canc_sn, tdeq_trans/ qed-.
  41
  42 (* Negated main properies ***************************************************)
  43
  44 theorem tdeq_tdneq_trans: ∀T1,T. T1 ≛ T → ∀T2. (T ≛ T2 → ⊥) → T1 ≛ T2 → ⊥.
  45 /3 width=3 by tdeq_canc_sn/ qed-.
  46
  47 theorem tdneq_tdeq_canc_dx: ∀T1,T. (T1 ≛ T → ⊥) → ∀T2. T2 ≛ T → T1 ≛ T2 → ⊥.
  48 /3 width=3 by tdeq_trans/ qed-.