matita/matita/contribs/lambdadelta/static_2/syntax/term.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/xoa/ex_1_3.ma".
  16 include "static_2/notation/functions/item0_1.ma".
  17 include "static_2/notation/functions/snitem2_3.ma".
  18 include "static_2/notation/functions/snbind2_4.ma".
  19 include "static_2/notation/functions/snbind2pos_3.ma".
  20 include "static_2/notation/functions/snbind2neg_3.ma".
  21 include "static_2/notation/functions/snflat2_3.ma".
  22 include "static_2/notation/functions/star_1.ma".
  23 include "static_2/notation/functions/lref_1.ma".
  24 include "static_2/notation/functions/gref_1.ma".
  25 include "static_2/notation/functions/snabbr_3.ma".
  26 include "static_2/notation/functions/snabbrpos_2.ma".
  27 include "static_2/notation/functions/snabbrneg_2.ma".
  28 include "static_2/notation/functions/snabst_3.ma".
  29 include "static_2/notation/functions/snabstpos_2.ma".
  30 include "static_2/notation/functions/snabstneg_2.ma".
  31 include "static_2/notation/functions/snappl_2.ma".
  32 include "static_2/notation/functions/sncast_2.ma".
  33 include "static_2/syntax/item.ma".
  34
  35 (* TERMS ********************************************************************)
  36
  37 (* terms *)
  38 inductive term: Type[0] ≝
  39   | TAtom: item0 → term               (* atomic item construction *)
  40   | TPair: item2 → term → term → term (* binary item construction *)
  41 .
  42
  43 interpretation "term construction (atomic)"
  44    'Item0 I = (TAtom I).
  45
  46 interpretation "term construction (binary)"
  47    'SnItem2 I T1 T2 = (TPair I T1 T2).
  48
  49 interpretation "term binding construction (binary)"
  50    'SnBind2 p I T1 T2 = (TPair (Bind2 p I) T1 T2).
  51
  52 interpretation "term positive binding construction (binary)"
  53    'SnBind2Pos I T1 T2 = (TPair (Bind2 true I) T1 T2).
  54
  55 interpretation "term negative binding construction (binary)"
  56    'SnBind2Neg I T1 T2 = (TPair (Bind2 false I) T1 T2).
  57
  58 interpretation "term flat construction (binary)"
  59    'SnFlat2 I T1 T2 = (TPair (Flat2 I) T1 T2).
  60
  61 interpretation "sort (term)"
  62    'Star s = (TAtom (Sort s)).
  63
  64 interpretation "local reference (term)"
  65    'LRef i = (TAtom (LRef i)).
  66
  67 interpretation "global reference (term)"
  68    'GRef l = (TAtom (GRef l)).
  69
  70 interpretation "abbreviation (term)"
  71    'SnAbbr p T1 T2 = (TPair (Bind2 p Abbr) T1 T2).
  72
  73 interpretation "positive abbreviation (term)"
  74    'SnAbbrPos T1 T2 = (TPair (Bind2 true Abbr) T1 T2).
  75
  76 interpretation "negative abbreviation (term)"
  77    'SnAbbrNeg T1 T2 = (TPair (Bind2 false Abbr) T1 T2).
  78
  79 interpretation "abstraction (term)"
  80    'SnAbst p T1 T2 = (TPair (Bind2 p Abst) T1 T2).
  81
  82 interpretation "positive abstraction (term)"
  83    'SnAbstPos T1 T2 = (TPair (Bind2 true Abst) T1 T2).
  84
  85 interpretation "negative abstraction (term)"
  86    'SnAbstNeg T1 T2 = (TPair (Bind2 false Abst) T1 T2).
  87
  88 interpretation "application (term)"
  89    'SnAppl T1 T2 = (TPair (Flat2 Appl) T1 T2).
  90
  91 interpretation "native type annotation (term)"
  92    'SnCast T1 T2 = (TPair (Flat2 Cast) T1 T2).
  93
  94 (* Basic properties *********************************************************)
  95
  96 lemma abst_dec (X): ∨∨ ∃∃p,W,T. X = ⓛ{p}W.T
  97                      | (∀p,W,T. X = ⓛ{p}W.T → ⊥).
  98 * [ #I | * [ #p * | #I ] #V #T ]
  99 [3: /3 width=4 by ex1_3_intro, or_introl/ ]
 100 @or_intror #q #W #U #H destruct
 101 qed-.
 102
 103 (* Basic_1: was: term_dec *)
 104 lemma eq_term_dec: ∀T1,T2:term. Decidable (T1 = T2).
 105 #T1 elim T1 -T1 #I1 [| #V1 #T1 #IHV1 #IHT1 ] * #I2 [2,4: #V2 #T2 ]
 106 [1,4: @or_intror #H destruct
 107 | elim (eq_item2_dec I1 I2) #HI
 108   [ elim (IHV1 V2) -IHV1 #HV
 109     [ elim (IHT1 T2) -IHT1 /2 width=1 by or_introl/ #HT ]
 110   ]
 111   @or_intror #H destruct /2 width=1 by/
 112 | elim (eq_item0_dec I1 I2) /2 width=1 by or_introl/ #HI
 113   @or_intror #H destruct /2 width=1 by/
 114 ]
 115 qed-.
 116
 117 (* Basic inversion lemmas ***************************************************)
 118
 119 fact destruct_tatom_tatom_aux: ∀I1,I2. ⓪{I1} = ⓪{I2} → I1 = I2.
 120 #I1 #I2 #H destruct //
 121 qed-.
 122
 123 fact destruct_tpair_tpair_aux: ∀I1,I2,T1,T2,V1,V2. ②{I1}T1.V1 = ②{I2}T2.V2 →
 124                                ∧∧T1 = T2 & I1 = I2 & V1 = V2.
 125 #I1 #I2 #T1 #T2 #V1 #V2 #H destruct /2 width=1 by and3_intro/
 126 qed-.
 127
 128 lemma discr_tpair_xy_x: ∀I,T,V. ②{I}V.T = V → ⊥.
 129 #I #T #V elim V -V
 130 [ #J #H destruct
 131 | #J #W #U #IHW #_ #H elim (destruct_tpair_tpair_aux … H) -H /2 width=1 by/ (**) (* destruct lemma needed *)
 132 ]
 133 qed-.
 134
 135 (* Basic_1: was: thead_x_y_y *)
 136 lemma discr_tpair_xy_y: ∀I,V,T. ②{I}V.T = T → ⊥.
 137 #I #V #T elim T -T
 138 [ #J #H destruct
 139 | #J #W #U #_ #IHU #H elim (destruct_tpair_tpair_aux … H) -H /2 width=1 by/ (**) (* destruct lemma needed *)
 140 ]
 141 qed-.
 142
 143 lemma eq_false_inv_tpair_sn: ∀I,V1,T1,V2,T2.
 144                              (②{I}V1.T1 = ②{I}V2.T2 → ⊥) →
 145                              (V1 = V2 → ⊥) ∨ (V1 = V2 ∧ (T1 = T2 → ⊥)).
 146 #I #V1 #T1 #V2 #T2 #H
 147 elim (eq_term_dec V1 V2) /3 width=1 by or_introl/ #HV12 destruct
 148 @or_intror @conj // #HT12 destruct /2 width=1 by/
 149 qed-.
 150
 151 lemma eq_false_inv_tpair_dx: ∀I,V1,T1,V2,T2.
 152                              (②{I} V1. T1 = ②{I}V2.T2 → ⊥) →
 153                              (T1 = T2 → ⊥) ∨ (T1 = T2 ∧ (V1 = V2 → ⊥)).
 154 #I #V1 #T1 #V2 #T2 #H
 155 elim (eq_term_dec T1 T2) /3 width=1 by or_introl/ #HT12 destruct
 156 @or_intror @conj // #HT12 destruct /2 width=1 by/
 157 qed-.
 158
 159 (* Basic_1: removed theorems 3:
 160             not_void_abst not_abbr_void not_abst_void
 161 *)