matita/matita/contribs/lambdadelta/static_2/syntax/term_simple.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/notation/relations/simple_1.ma".
  16 include "static_2/syntax/term.ma".
  17
  18 (* SIMPLE (NEUTRAL) TERMS ***************************************************)
  19
  20 inductive simple: predicate term ≝
  21    | simple_atom: ∀I. simple (⓪{I})
  22    | simple_flat: ∀I,V,T. simple (ⓕ{I}V.T)
  23 .
  24
  25 interpretation "simple (term)" 'Simple T = (simple T).
  26
  27 (* Basic inversion lemmas ***************************************************)
  28
  29 fact simple_inv_bind_aux: ∀T. 𝐒⦃T⦄ → ∀p,J,W,U. T = ⓑ{p,J}W.U → ⊥.
  30 #T * -T
  31 [ #I #p #J #W #U #H destruct
  32 | #I #V #T #a #J #W #U #H destruct
  33 ]
  34 qed-.
  35
  36 lemma simple_inv_bind: ∀p,I,V,T. 𝐒⦃ⓑ{p,I} V. T⦄ → ⊥.
  37 /2 width=7 by simple_inv_bind_aux/ qed-.
  38
  39 lemma simple_inv_pair: ∀I,V,T. 𝐒⦃②{I}V.T⦄ → ∃J. I = Flat2 J.
  40 * /2 width=2 by ex_intro/
  41 #p #I #V #T #H elim (simple_inv_bind … H)
  42 qed-.