matita/matita/lib/basics/finset.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_______________________________________________________________ *)
  11
  12 include "basics/lists/listb.ma".
  13
  14 (****** DeqSet: a set with a decidable equality ******)
  15
  16 record FinSet : Type[1] ≝
  17 { FinSetcarr:> DeqSet;
  18   enum: list FinSetcarr;
  19   enum_unique: uniqueb FinSetcarr enum = true;
  20   enum_complete : ∀x:FinSetcarr. memb ? x enum = true
  21 }.
  22
  23 notation < "𝐅" non associative with precedence 90
  24  for @{'bigF}.
  25 interpretation "FinSet" 'bigF = (mk_FinSet ???).
  26
  27 (* bool *)
  28 lemma bool_enum_unique: uniqueb ? [true;false] = true.
  29 // qed.
  30
  31 lemma bool_enum_complete: ∀x:bool. memb ? x [true;false] = true.
  32 * // qed.
  33
  34 definition FinBool ≝
  35   mk_FinSet DeqBool [true;false] bool_enum_unique bool_enum_complete.
  36
  37 unification hint  0 ≔ ;
  38     X ≟ FinBool
  39 (* ---------------------------------------- *) ⊢
  40     bool ≡ FinSetcarr X.
  41
  42 (* nat segment *)
  43
  44 lemma eqbnat_true : ∀n,m. eqb n m = true ↔ n = m.
  45 #n #m % [@eqb_true_to_eq | @eq_to_eqb_true]
  46 qed.
  47
  48 definition DeqNat ≝ mk_DeqSet nat eqb eqbnat_true.
  49
  50 lemma lt_to_le : ∀n,m. n < m → n ≤ m.
  51 /2/ qed-.
  52
  53 let rec enumnaux n m ≝
  54   match n return (λn.n ≤ m → list (Σx.x < m)) with
  55     [ O ⇒ λh.[ ] | S p ⇒ λh:p < m.(mk_Sig ?? p h)::enumnaux p m (lt_to_le p m h)].
  56
  57 definition enumn ≝ λn.enumnaux n n (le_n n).
  58
  59 definition Nat_to ≝ λn. DeqSig DeqNat (λi.i<n).
  60
  61 (* lemma prova : ∀n. carr (Nat_to n) = (Σx.x<n). // *)
  62
  63 lemma memb_enumn: ∀m,n,i:DeqNat. ∀h:n ≤ m. ∀k: i < m. n ≤ i →
  64   (¬ (memb (Nat_to m) (mk_Sig ?? i k) (enumnaux n m h))) = true.
  65 #m #n elim n -n // #n #Hind #i #ltm #k #ltni @sym_eq @noteq_to_eqnot @sym_not_eq
  66 % #H cases (orb_true_l … H)
  67   [#H1 @(absurd … (\P H1)) % #Hfalse
  68    cut (∀A,P,a,a1,h,h1.mk_Sig A P a h = mk_Sig A P a1 h1 → a = a1)
  69    [#A #P #a #a1 #h #h1 #H destruct (H) %] #Hcut
  70     lapply (Hcut nat (λi.i<m) i n ? ? Hfalse) #Hfalse @(absurd … ltni)
  71     @le_to_not_lt >Hfalse @le_n
  72   |<(notb_notb (memb …)) >Hind normalize /2/
  73   ]
  74 qed.
  75
  76
  77 lemma enumn_unique_aux: ∀n,m. ∀h:n ≤ m. uniqueb (Nat_to m) (enumnaux n m h) = true.
  78 #n elim n -n // #n #Hind #m #h @true_to_andb_true // @memb_enumn //
  79 qed.
  80
  81 lemma enumn_unique: ∀n.uniqueb (Nat_to n) (enumn n) = true.
  82 #n @enumn_unique_aux
  83 qed.
  84
  85 (* definition ltb ≝ λn,m.leb (S n) m. *)
  86 lemma enumn_complete_aux: ∀n,m,i.∀h:n ≤m.∀k:i<m.i<n →
  87   memb (Nat_to m) (mk_Sig ?? i k) (enumnaux n m h) = true.
  88 #n elim n -n
  89   [normalize #n #i #_ #_ #Hfalse @False_ind /2/
  90   |#n #Hind #m #i #h #k #lein whd in ⊢ (??%?);
  91    cases (le_to_or_lt_eq … (le_S_S_to_le … lein))
  92     [#ltin cut (eqb (Nat_to m) (mk_Sig ?? i k) (mk_Sig ?? n h) = false)
  93       [normalize @not_eq_to_eqb_false @lt_to_not_eq @ltin]
  94        #Hcut >Hcut @Hind //
  95     |#eqin cut (eqb (Nat_to m) (mk_Sig ?? i k) (mk_Sig ?? n h) = true)
  96      [normalize @eq_to_eqb_true //
  97      |#Hcut >Hcut %
  98     ]
  99   ]
 100 qed.
 101
 102 lemma enumn_complete: ∀n.∀i:Nat_to n. memb ? i (enumn n) = true.
 103 #n whd in ⊢ (%→?); * #i #ltin @enumn_complete_aux //
 104 qed.
 105
 106 definition initN ≝ λn.
 107   mk_FinSet (Nat_to n) (enumn n) (enumn_unique n) (enumn_complete n).
 108
 109 example tipa: ∀n.∃x: initN (S n). pi1 … x = n.
 110 #n @ex_intro [whd @mk_Sig [@n | @le_n] | //] qed.
 111
 112 (* sum *)
 113 definition enum_sum ≝ λA,B:DeqSet.λl1.λl2.
 114   (map ?? (inl A B) l1) @ (map ?? (inr A B) l2).
 115
 116 lemma enum_sum_def : ∀A,B:FinSet.∀l1,l2. enum_sum A B l1 l2 =
 117   (map ?? (inl A B) l1) @ (map ?? (inr A B) l2).
 118 // qed.
 119
 120 lemma enum_sum_unique: ∀A,B:DeqSet.∀l1,l2.
 121   uniqueb A l1 = true → uniqueb B l2 = true →
 122     uniqueb ? (enum_sum A B l1 l2) = true.
 123 #A #B #l1 #l2 elim l1
 124   [#_ #ul2 @unique_map_inj // #b1 #b2 #Hinr destruct //
 125   |#a #tl #Hind #uA #uB @true_to_andb_true
 126     [@sym_eq @noteq_to_eqnot % #H
 127      cases (memb_append … (sym_eq … H))
 128       [#H1 @(absurd (memb ? a tl = true))
 129         [@(memb_map_inj …H1) #a1 #a2 #Hinl destruct //
 130         |<(andb_true_l … uA) @eqnot_to_noteq //
 131         ]
 132       |elim l2
 133         [normalize #H destruct
 134         |#b #tlB #Hind #membH cases (orb_true_l … membH)
 135           [#H lapply (\P H) #H1 destruct |@Hind]
 136         ]
 137       ]
 138     |@Hind // @(andb_true_r … uA)
 139     ]
 140   ]
 141 qed.
 142
 143 lemma enum_sum_complete: ∀A,B:DeqSet.∀l1,l2.
 144   (∀x:A. memb A x l1 = true) →
 145   (∀x:B. memb B x l2 = true) →
 146     ∀x:DeqSum A B. memb ? x (enum_sum A B l1 l2) = true.
 147 #A #B #l1 #l2 #Hl1 #Hl2 *
 148   [#a @memb_append_l1 @memb_map @Hl1
 149   |#b @memb_append_l2 @memb_map @Hl2
 150   ]
 151 qed.
 152
 153 definition FinSum ≝ λA,B:FinSet.
 154   mk_FinSet (DeqSum A B)
 155    (enum_sum A B (enum A) (enum B))
 156    (enum_sum_unique … (enum_unique A) (enum_unique B))
 157    (enum_sum_complete … (enum_complete A) (enum_complete B)).
 158
 159 include alias "basics/types.ma".
 160
 161 unification hint  0 ≔ C1,C2;
 162     T1 ≟ FinSetcarr C1,
 163     T2 ≟ FinSetcarr C2,
 164     X ≟ FinSum C1 C2
 165 (* ---------------------------------------- *) ⊢
 166     T1+T2 ≡ FinSetcarr X.
 167
 168 (* prod *)
 169
 170 definition enum_prod ≝ λA,B:DeqSet.λl1.λl2.
 171   compose ??? (mk_Prod A B) l1 l2.
 172
 173 axiom enum_prod_unique: ∀A,B,l1,l2.
 174   uniqueb A l1 = true → uniqueb B l2 = true →
 175   uniqueb ? (enum_prod A B l1 l2) = true.
 176
 177 lemma enum_prod_complete:∀A,B:DeqSet.∀l1,l2.
 178   (∀a. memb A a l1 = true) → (∀b.memb B b l2 = true) →
 179     ∀p. memb ? p (enum_prod A B l1 l2) = true.
 180 #A #B #l1 #l2 #Hl1 #Hl2 * #a #b @memb_compose //
 181 qed.
 182
 183 definition FinProd ≝
 184 λA,B:FinSet.mk_FinSet (DeqProd A B)
 185   (enum_prod A B (enum A) (enum B))
 186   (enum_prod_unique A B … (enum_unique A) (enum_unique B))
 187   (enum_prod_complete A B … (enum_complete A) (enum_complete B)).
 188
 189 unification hint  0 ≔ C1,C2;
 190     T1 ≟ FinSetcarr C1,
 191     T2 ≟ FinSetcarr C2,
 192     X ≟ FinProd C1 C2
 193 (* ---------------------------------------- *) ⊢
 194     T1×T2 ≡ FinSetcarr X.
 195