matita/matita/lib/basics/relations.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "basics/logic.ma".
  13
  14 (********** predicates *********)
  15
  16 definition predicate: Type[0] → Type[0]
  17 ≝ λA.A→Prop.
  18
  19 (********** relations **********)
  20 definition relation : Type[0] → Type[0]
  21 ≝ λA.A→A→Prop.
  22
  23 definition relation2 : Type[0] → Type[0] → Type[0]
  24 ≝ λA,B.A→B→Prop.
  25
  26 definition relation3 : Type[0] → Type[0] → Type[0] → Type[0]
  27 ≝ λA,B,C.A→B→C→Prop.
  28
  29 definition relation4 : Type[0] → Type[0] → Type[0] → Type[0] → Type[0]
  30 ≝ λA,B,C,D.A→B→C→D→Prop.
  31
  32 definition reflexive: ∀A.∀R :relation A.Prop
  33 ≝ λA.λR.∀x:A.R x x.
  34
  35 definition symmetric: ∀A.∀R: relation A.Prop
  36 ≝ λA.λR.∀x,y:A.R x y → R y x.
  37
  38 definition transitive: ∀A.∀R:relation A.Prop
  39 ≝ λA.λR.∀x,y,z:A.R x y → R y z → R x z.
  40
  41 definition irreflexive: ∀A.∀R:relation A.Prop
  42 ≝ λA.λR.∀x:A.¬(R x x).
  43
  44 definition cotransitive: ∀A.∀R:relation A.Prop
  45 ≝ λA.λR.∀x,y:A.R x y → ∀z:A. R x z ∨ R z y.
  46
  47 definition tight_apart: ∀A.∀eq,ap:relation A.Prop
  48 ≝ λA.λeq,ap.∀x,y:A. (¬(ap x y) → eq x y) ∧
  49 (eq x y → ¬(ap x y)).
  50
  51 definition antisymmetric: ∀A.∀R:relation A.Prop
  52 ≝ λA.λR.∀x,y:A. R x y → ¬(R y x).
  53
  54 definition singlevalued: ∀A,B. predicate (relation2 A B) ≝ λA,B,R.
  55                          ∀a,b1. R a b1 → ∀b2. R a b2 → b1 = b2.
  56
  57 definition confluent1: ∀A. relation A → predicate A ≝ λA,R,a0.
  58                        ∀a1. R a0 a1 → ∀a2. R a0 a2 →
  59                        ∃∃a. R a1 a & R a2 a.
  60
  61 definition confluent: ∀A. predicate (relation A) ≝ λA,R.
  62                       ∀a0. confluent1 … R a0.
  63
  64 (* Reflexive closure ************)
  65
  66 definition RC: ∀A:Type[0]. relation A → relation A ≝
  67                λA,R,x,y. R … x y ∨ x = y.
  68
  69 lemma RC_reflexive: ∀A,R. reflexive A (RC … R).
  70 /2 width=1/ qed.
  71
  72 (********** operations **********)
  73 definition Rcomp ≝ λA.λR1,R2:relation A.λa1,a2.
  74   ∃am.R1 a1 am ∧ R2 am a2.
  75 interpretation "relation composition" 'compose R1 R2 = (Rcomp ? R1 R2).
  76
  77 definition Runion ≝ λA.λR1,R2:relation A.λa,b. R1 a b ∨ R2 a b.
  78 interpretation "union of relations" 'union R1 R2 = (Runion ? R1 R2).
  79
  80 definition Rintersection ≝ λA.λR1,R2:relation A.λa,b.R1 a b ∧ R2 a b.
  81 interpretation "interesecion of relations" 'intersects R1 R2 = (Rintersection ? R1 R2).
  82
  83 definition inv ≝ λA.λR:relation A.λa,b.R b a.
  84
  85 (*********** sub relation ***********)
  86 definition subR ≝ λA.λR,S:relation A.(∀a,b. R a b → S a b).
  87 interpretation "relation inclusion" 'subseteq R S = (subR ? R S).
  88
  89 lemma sub_reflexive :
  90   ∀T.∀R:relation T.R ⊆ R.
  91 #T #R #x //
  92 qed.
  93
  94 lemma sub_comp_l:  ∀A.∀R,R1,R2:relation A.
  95   R1 ⊆ R2 → R1 ∘ R ⊆ R2 ∘ R.
  96 #A #R #R1 #R2 #Hsub #a #b * #c * /4/
  97 qed.
  98
  99 lemma sub_comp_r:  ∀A.∀R,R1,R2:relation A.
 100   R1 ⊆ R2 → R ∘ R1 ⊆ R ∘ R2.
 101 #A #R #R1 #R2 #Hsub #a #b * #c * /4/
 102 qed.
 103
 104 lemma sub_assoc_l: ∀A.∀R1,R2,R3:relation A.
 105   R1 ∘ (R2 ∘ R3) ⊆ (R1 ∘ R2) ∘ R3.
 106 #A #R1 #R2 #R3 #a #b * #c * #Hac * #d * /5/
 107 qed.
 108
 109 lemma sub_assoc_r: ∀A.∀R1,R2,R3:relation A.
 110   (R1 ∘ R2) ∘ R3 ⊆ R1 ∘ (R2 ∘ R3).
 111 #A #R1 #R2 #R3 #a #b * #c * * #d * /5 width=5/
 112 qed.
 113
 114 (************* functions ************)
 115
 116 definition compose ≝
 117   λA,B,C:Type[0].λf:B→C.λg:A→B.λx:A.f (g x).
 118
 119 interpretation "function composition" 'compose f g = (compose ? ? ? f g).
 120
 121 definition injective: ∀A,B:Type[0].∀ f:A→B.Prop
 122 ≝ λA,B.λf.∀x,y:A.f x = f y → x=y.
 123
 124 definition surjective: ∀A,B:Type[0].∀f:A→B.Prop
 125 ≝λA,B.λf.∀z:B.∃x:A.z = f x.
 126
 127 definition commutative: ∀A:Type[0].∀f:A→A→A.Prop
 128 ≝ λA.λf.∀x,y.f x y = f y x.
 129
 130 definition commutative2: ∀A,B:Type[0].∀f:A→A→B.Prop
 131 ≝ λA,B.λf.∀x,y.f x y = f y x.
 132
 133 definition associative: ∀A:Type[0].∀f:A→A→A.Prop
 134 ≝ λA.λf.∀x,y,z.f (f x y) z = f x (f y z).
 135
 136 (* functions and relations *)
 137 definition monotonic : ∀A:Type[0].∀R:A→A→Prop.
 138 ∀f:A→A.Prop ≝
 139 λA.λR.λf.∀x,y:A.R x y → R (f x) (f y).
 140
 141 (* functions and functions *)
 142 definition distributive: ∀A:Type[0].∀f,g:A→A→A.Prop
 143 ≝ λA.λf,g.∀x,y,z:A. f x (g y z) = g (f x y) (f x z).
 144
 145 definition distributive2: ∀A,B:Type[0].∀f:A→B→B.∀g:B→B→B.Prop
 146 ≝ λA,B.λf,g.∀x:A.∀y,z:B. f x (g y z) = g (f x y) (f x z).
 147
 148 lemma injective_compose : ∀A,B,C,f,g.
 149 injective A B f → injective B C g → injective A C (λx.g (f x)).
 150 /3/; qed-.
 151
 152 (* extensional equality *)
 153
 154 (* moved inside sets.ma
 155 definition exteqP: ∀A:Type[0].∀P,Q:A→Prop.Prop ≝
 156 λA.λP,Q.∀a.iff (P a) (Q a). *)
 157
 158 definition exteqR: ∀A,B:Type[0].∀R,S:A→B→Prop.Prop ≝
 159 λA,B.λR,S.∀a.∀b.iff (R a b) (S a b).
 160
 161 definition exteqF: ∀A,B:Type[0].∀f,g:A→B.Prop ≝
 162 λA,B.λf,g.∀a.f a = g a.
 163
 164 (*
 165 notation " x \eqP y " non associative with precedence 45
 166 for @{'eqP A $x $y}.
 167
 168 interpretation "functional extentional equality"
 169 'eqP A x y = (exteqP A x y). *)
 170
 171 notation "x \eqR y" non associative with precedence 45
 172 for @{'eqR ? ? x y}.
 173
 174 interpretation "functional extentional equality"
 175 'eqR A B R S = (exteqR A B R S).
 176
 177 notation " f \eqF g " non associative with precedence 45
 178 for @{'eqF ? ? f g}.
 179
 180 interpretation "functional extentional equality"
 181 'eqF A B f g = (exteqF A B f g).
 182
 183 (********** relations on unboxed pairs **********)
 184
 185 definition bi_relation: Type[0] → Type[0] → Type[0]
 186 ≝ λA,B.A→B→A→B→Prop.
 187
 188 definition bi_reflexive: ∀A,B. ∀R:bi_relation A B. Prop
 189 ≝ λA,B,R. ∀a,b. R a b a b.
 190
 191 definition bi_symmetric: ∀A,B. ∀R: bi_relation A B. Prop ≝ λA,B,R.
 192                          ∀a1,a2,b1,b2. R a2 b2 a1 b1 → R a1 b1 a2 b2.
 193
 194 definition bi_transitive: ∀A,B. ∀R: bi_relation A B. Prop ≝ λA,B,R.
 195                           ∀a1,a,b1,b. R a1 b1 a b →
 196                           ∀a2,b2. R a b a2 b2 → R a1 b1 a2 b2.
 197
 198 definition bi_RC: ∀A,B:Type[0]. bi_relation A B → bi_relation A B ≝
 199                   λA,B,R,a1,b1,a2,b2. R … a1 b1 a2 b2 ∨ (a1 = a2 ∧ b1 = b2).
 200
 201 lemma bi_RC_reflexive: ∀A,B,R. bi_reflexive A B (bi_RC … R).
 202 /3 width=1/ qed.
 203
 204 (********** relations on unboxed triples **********)
 205
 206 definition tri_relation: Type[0] → Type[0] → Type[0] → Type[0]
 207 ≝ λA,B,C.A→B→C→A→B→C→Prop.
 208
 209 definition tri_reflexive: ∀A,B,C. ∀R:tri_relation A B C. Prop
 210 ≝ λA,B,C,R. ∀a,b,c. R a b c a b c.
 211
 212 definition tri_symmetric: ∀A,B,C. ∀R: tri_relation A B C. Prop ≝ λA,B,C,R.
 213                           ∀a1,a2,b1,b2,c1,c2.
 214                           R a2 b2 c2 a1 b1 c1 → R a1 b1 c1 a2 b2 c2.
 215
 216 definition tri_transitive: ∀A,B,C. ∀R: tri_relation A B C. Prop ≝ λA,B,C,R.
 217                            ∀a1,a,b1,b,c1,c. R a1 b1 c1 a b c →
 218                            ∀a2,b2,c2. R a b c a2 b2 c2 → R a1 b1 c1 a2 b2 c2.