matita/matita/lib/basics/relations.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "basics/logic.ma".
  13
  14 (********** predicates *********)
  15
  16 definition predicate: Type[0] → Type[0]
  17 ≝ λA.A→Prop.
  18
  19 (********** relations **********)
  20 definition relation : Type[0] → Type[0]
  21 ≝ λA.A→A→Prop.
  22
  23 definition relation2 : Type[0] → Type[0] → Type[0]
  24 ≝ λA,B.A→B→Prop.
  25
  26 definition relation3 : Type[0] → Type[0] → Type[0] → Type[0]
  27 ≝ λA,B,C.A→B→C→Prop.
  28
  29 definition reflexive: ∀A.∀R :relation A.Prop
  30 ≝ λA.λR.∀x:A.R x x.
  31
  32 definition symmetric: ∀A.∀R: relation A.Prop
  33 ≝ λA.λR.∀x,y:A.R x y → R y x.
  34
  35 definition transitive: ∀A.∀R:relation A.Prop
  36 ≝ λA.λR.∀x,y,z:A.R x y → R y z → R x z.
  37
  38 definition irreflexive: ∀A.∀R:relation A.Prop
  39 ≝ λA.λR.∀x:A.¬(R x x).
  40
  41 definition cotransitive: ∀A.∀R:relation A.Prop
  42 ≝ λA.λR.∀x,y:A.R x y → ∀z:A. R x z ∨ R z y.
  43
  44 definition tight_apart: ∀A.∀eq,ap:relation A.Prop
  45 ≝ λA.λeq,ap.∀x,y:A. (¬(ap x y) → eq x y) ∧
  46 (eq x y → ¬(ap x y)).
  47
  48 definition antisymmetric: ∀A.∀R:relation A.Prop
  49 ≝ λA.λR.∀x,y:A. R x y → ¬(R y x).
  50
  51 (********** operations **********)
  52 definition Rcomp ≝ λA.λR1,R2:relation A.λa1,a2.
  53   ∃am.R1 a1 am ∧ R2 am a2.
  54 interpretation "relation composition" 'compose R1 R2 = (Rcomp ? R1 R2).
  55
  56 definition Runion ≝ λA.λR1,R2:relation A.λa,b. R1 a b ∨ R2 a b.
  57 interpretation "union of relations" 'union R1 R2 = (Runion ? R1 R2).
  58
  59 definition Rintersection ≝ λA.λR1,R2:relation A.λa,b.R1 a b ∧ R2 a b.
  60 interpretation "interesecion of relations" 'intersects R1 R2 = (Rintersection ? R1 R2).
  61
  62 definition inv ≝ λA.λR:relation A.λa,b.R b a.
  63
  64 (*********** sub relation ***********)
  65 definition subR ≝ λA.λR,S:relation A.(∀a,b. R a b → S a b).
  66 interpretation "relation inclusion" 'subseteq R S = (subR ? R S).
  67
  68 lemma sub_reflexive :
  69   ∀T.∀R:relation T.R ⊆ R.
  70 #T #R #x //
  71 qed.
  72
  73 lemma sub_comp_l:  ∀A.∀R,R1,R2:relation A.
  74   R1 ⊆ R2 → R1 ∘ R ⊆ R2 ∘ R.
  75 #A #R #R1 #R2 #Hsub #a #b * #c * /4/
  76 qed.
  77
  78 lemma sub_comp_r:  ∀A.∀R,R1,R2:relation A.
  79   R1 ⊆ R2 → R ∘ R1 ⊆ R ∘ R2.
  80 #A #R #R1 #R2 #Hsub #a #b * #c * /4/
  81 qed.
  82
  83 lemma sub_assoc_l: ∀A.∀R1,R2,R3:relation A.
  84   R1 ∘ (R2 ∘ R3) ⊆ (R1 ∘ R2) ∘ R3.
  85 #A #R1 #R2 #R3 #a #b * #c * #Hac * #d * /5/
  86 qed.
  87
  88 lemma sub_assoc_r: ∀A.∀R1,R2,R3:relation A.
  89   (R1 ∘ R2) ∘ R3 ⊆ R1 ∘ (R2 ∘ R3).
  90 #A #R1 #R2 #R3 #a #b * #c * * #d * /5 width=5/
  91 qed.
  92
  93 (************* functions ************)
  94
  95 definition compose ≝
  96   λA,B,C:Type[0].λf:B→C.λg:A→B.λx:A.f (g x).
  97
  98 interpretation "function composition" 'compose f g = (compose ? ? ? f g).
  99
 100 definition injective: ∀A,B:Type[0].∀ f:A→B.Prop
 101 ≝ λA,B.λf.∀x,y:A.f x = f y → x=y.
 102
 103 definition surjective: ∀A,B:Type[0].∀f:A→B.Prop
 104 ≝λA,B.λf.∀z:B.∃x:A.z = f x.
 105
 106 definition commutative: ∀A:Type[0].∀f:A→A→A.Prop
 107 ≝ λA.λf.∀x,y.f x y = f y x.
 108
 109 definition commutative2: ∀A,B:Type[0].∀f:A→A→B.Prop
 110 ≝ λA,B.λf.∀x,y.f x y = f y x.
 111
 112 definition associative: ∀A:Type[0].∀f:A→A→A.Prop
 113 ≝ λA.λf.∀x,y,z.f (f x y) z = f x (f y z).
 114
 115 (* functions and relations *)
 116 definition monotonic : ∀A:Type[0].∀R:A→A→Prop.
 117 ∀f:A→A.Prop ≝
 118 λA.λR.λf.∀x,y:A.R x y → R (f x) (f y).
 119
 120 (* functions and functions *)
 121 definition distributive: ∀A:Type[0].∀f,g:A→A→A.Prop
 122 ≝ λA.λf,g.∀x,y,z:A. f x (g y z) = g (f x y) (f x z).
 123
 124 definition distributive2: ∀A,B:Type[0].∀f:A→B→B.∀g:B→B→B.Prop
 125 ≝ λA,B.λf,g.∀x:A.∀y,z:B. f x (g y z) = g (f x y) (f x z).
 126
 127 lemma injective_compose : ∀A,B,C,f,g.
 128 injective A B f → injective B C g → injective A C (λx.g (f x)).
 129 /3/; qed-.
 130
 131 (* extensional equality *)
 132
 133 (* moved inside sets.ma
 134 definition exteqP: ∀A:Type[0].∀P,Q:A→Prop.Prop ≝
 135 λA.λP,Q.∀a.iff (P a) (Q a). *)
 136
 137 definition exteqR: ∀A,B:Type[0].∀R,S:A→B→Prop.Prop ≝
 138 λA,B.λR,S.∀a.∀b.iff (R a b) (S a b).
 139
 140 definition exteqF: ∀A,B:Type[0].∀f,g:A→B.Prop ≝
 141 λA,B.λf,g.∀a.f a = g a.
 142
 143 (*
 144 notation " x \eqP y " non associative with precedence 45
 145 for @{'eqP A $x $y}.
 146
 147 interpretation "functional extentional equality"
 148 'eqP A x y = (exteqP A x y). *)
 149
 150 notation "x \eqR y" non associative with precedence 45
 151 for @{'eqR ? ? x y}.
 152
 153 interpretation "functional extentional equality"
 154 'eqR A B R S = (exteqR A B R S).
 155
 156 notation " f \eqF g " non associative with precedence 45
 157 for @{'eqF ? ? f g}.
 158
 159 interpretation "functional extentional equality"
 160 'eqF A B f g = (exteqF A B f g).
 161
 162 (********** relations on unboxed pairs **********)
 163
 164 definition bi_relation: Type[0] → Type[0] → Type[0]
 165 ≝ λA,B.A→B→A→B→Prop.
 166
 167 definition bi_reflexive: ∀A,B. ∀R:bi_relation A B. Prop
 168 ≝ λA,B,R. ∀x,y. R x y x y.
 169
 170 definition bi_transitive: ∀A,B. ∀R: bi_relation A B. Prop ≝ λA,B,R.
 171                           ∀a1,a,b1,b. R a1 b1 a b →
 172                           ∀a2,b2. R a b a2 b2 → R a1 b1 a2 b2.