matita/matita/lib/basics/types.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_______________________________________________________________ *)
  11
  12 include "basics/logic.ma".
  13
  14 (* void *)
  15 inductive void : Type[0] ≝.
  16
  17 (* unit *)
  18 inductive unit : Type[0] ≝ it: unit.
  19
  20 (* sum *)
  21 inductive Sum (A,B:Type[0]) : Type[0] ≝
  22   inl : A → Sum A B
  23 | inr : B → Sum A B.
  24
  25 interpretation "Disjoint union" 'plus A B = (Sum A B).
  26
  27 (* option *)
  28 inductive option (A:Type[0]) : Type[0] ≝
  29    None : option A
  30  | Some : A → option A.
  31
  32 definition option_map : ∀A,B:Type[0]. (A → B) → option A → option B ≝
  33 λA,B,f,o. match o with [ None ⇒ None B | Some a ⇒ Some B (f a) ].
  34
  35 lemma option_map_none : ∀A,B,f,x.
  36   option_map A B f x = None B → x = None A.
  37 #A #B #f * [ // | #a #E whd in E:(??%?); destruct ]
  38 qed.
  39
  40 lemma option_map_some : ∀A,B,f,x,v.
  41   option_map A B f x = Some B v → ∃y. x = Some ? y ∧ f y = v.
  42 #A #B #f *
  43 [ #v normalize #E destruct
  44 | #y #v normalize #E %{y} destruct % //
  45 ] qed.
  46
  47 definition option_map_def : ∀A,B:Type[0]. (A → B) → B → option A → B ≝
  48 λA,B,f,d,o. match o with [ None ⇒ d | Some a ⇒ f a ].
  49
  50 lemma refute_none_by_refl : ∀A,B:Type[0]. ∀P:A → B. ∀Q:B → Type[0]. ∀x:option A. ∀H:x = None ? → False.
  51   (∀v. x = Some ? v → Q (P v)) →
  52   Q (match x return λy.x = y → ? with [ Some v ⇒ λ_. P v | None ⇒ λE. match H E in False with [ ] ] (refl ? x)).
  53 #A #B #P #Q *
  54 [ #H cases (H (refl ??))
  55 | #a #H #p normalize @p @refl
  56 ] qed.
  57
  58 (* dependent pair *)
  59 record DPair (A:Type[0]) (f:A→Type[0]) : Type[0] ≝ {
  60     dpi1: A
  61   ; dpi2: f dpi1
  62   }.
  63
  64 interpretation "DPair" 'dpair x = (DPair ? x).
  65
  66 interpretation "mk_DPair" 'mk_DPair x y = (mk_DPair ?? x y).
  67
  68 (* sigma *)
  69 record Sig (A:Type[0]) (f:A→Prop) : Type[0] ≝ {
  70     pi1: A
  71   ; pi2: f pi1
  72   }.
  73
  74 interpretation "Sigma" 'sigma x = (Sig ? x).
  75
  76 interpretation "mk_Sig" 'dp x y = (mk_Sig ?? x y).
  77
  78 (* Prod *)
  79
  80 record Prod (A,B:Type[0]) : Type[0] ≝ {
  81    fst: A
  82  ; snd: B
  83  }.
  84
  85 interpretation "Pair construction" 'pair x y = (mk_Prod ? ? x y).
  86
  87 interpretation "Product" 'product x y = (Prod x y).
  88
  89 interpretation "pair pi1" 'pi1 = (fst ? ?).
  90 interpretation "pair pi2" 'pi2 = (snd ? ?).
  91 interpretation "pair pi1" 'pi1a x = (fst ? ? x).
  92 interpretation "pair pi2" 'pi2a x = (snd ? ? x).
  93 interpretation "pair pi1" 'pi1b x y = (fst ? ? x y).
  94 interpretation "pair pi2" 'pi2b x y = (snd ? ? x y).
  95
  96 notation "π1" with precedence 10 for @{ (proj1 ??) }.
  97 notation "π2" with precedence 10 for @{ (proj2 ??) }.
  98
  99 (* Yeah, I probably ought to do something more general... *)
 100 notation "hvbox(\langle term 19 a, break term 19 b, break term 19 c\rangle)"
 101 with precedence 90 for @{ 'triple $a $b $c}.
 102 interpretation "Triple construction" 'triple x y z = (mk_Prod ? ? (mk_Prod ? ? x y) z).
 103
 104 notation "hvbox(\langle term 19 a, break term 19 b, break term 19 c, break term 19 d\rangle)"
 105 with precedence 90 for @{ 'quadruple $a $b $c $d}.
 106 interpretation "Quadruple construction" 'quadruple w x y z = (mk_Prod ? ? (mk_Prod ? ? w x) (mk_Prod ? ? y z)).
 107
 108
 109 theorem eq_pair_fst_snd: ∀A,B.∀p:A × B.
 110   p = 〈 \fst p, \snd p 〉.
 111 #A #B #p (cases p) // qed.
 112
 113 lemma fst_eq : ∀A,B.∀a:A.∀b:B. \fst 〈a,b〉 = a.
 114 // qed.
 115
 116 lemma snd_eq : ∀A,B.∀a:A.∀b:B. \snd 〈a,b〉 = b.
 117 // qed.
 118
 119 notation > "hvbox('let' 〈ident x,ident y〉 ≝ t 'in' s)"
 120  with precedence 10
 121 for @{ match $t with [ mk_Prod ${ident x} ${ident y} ⇒ $s ] }.
 122
 123 notation < "hvbox('let' \nbsp hvbox(〈ident x,ident y〉 \nbsp≝ break t \nbsp 'in' \nbsp) break s)"
 124  with precedence 10
 125 for @{ match $t with [ mk_Prod (${ident x}:$X) (${ident y}:$Y) ⇒ $s ] }.
 126
 127 (* Also extracts an equality proof (useful when not using Russell). *)
 128 notation > "hvbox('let' 〈ident x,ident y〉 'as' ident E ≝ t 'in' s)"
 129  with precedence 10
 130 for @{ match $t return λx.x = $t → ? with [ mk_Prod ${ident x} ${ident y} ⇒
 131         λ${ident E}.$s ] (refl ? $t) }.
 132
 133 notation < "hvbox('let' \nbsp hvbox(〈ident x,ident y〉 \nbsp 'as'\nbsp ident E\nbsp ≝ break t \nbsp 'in' \nbsp) break s)"
 134  with precedence 10
 135 for @{ match $t return λ${ident k}:$X.$eq $T $k $t → ? with [ mk_Prod (${ident x}:$U) (${ident y}:$W) ⇒
 136         λ${ident E}:$e.$s ] ($refl $T $t) }.
 137
 138 notation > "hvbox('let' 〈ident x,ident y,ident z〉 'as' ident E ≝ t 'in' s)"
 139  with precedence 10
 140 for @{ match $t return λx.x = $t → ? with [ mk_Prod ${fresh xy} ${ident z} ⇒
 141        match ${fresh xy} return λx. ? = $t → ? with [ mk_Prod ${ident x} ${ident y} ⇒
 142         λ${ident E}.$s ] ] (refl ? $t) }.
 143
 144 notation < "hvbox('let' \nbsp hvbox(〈ident x,ident y,ident z〉 \nbsp'as'\nbsp ident E\nbsp ≝ break t \nbsp 'in' \nbsp) break s)"
 145  with precedence 10
 146 for @{ match $t return λ${ident x}.$eq $T $x $t → $U with [ mk_Prod (${fresh xy}:$V) (${ident z}:$Z) ⇒
 147        match ${fresh xy} return λ${ident y}. $eq $R $r $t → ? with [ mk_Prod (${ident x}:$L) (${ident y}:$I) ⇒
 148         λ${ident E}:$J.$s ] ] ($refl $A $t) }.
 149
 150 notation > "hvbox('let' 〈ident w,ident x,ident y,ident z〉 ≝ t 'in' s)"
 151  with precedence 10
 152 for @{ match $t with [ mk_Prod ${fresh wx} ${fresh yz} ⇒ match ${fresh wx} with [ mk_Prod ${ident w} ${ident x} ⇒ match ${fresh yz} with [ mk_Prod ${ident y} ${ident z} ⇒ $s ] ] ] }.
 153
 154 notation > "hvbox('let' 〈ident x,ident y,ident z〉 ≝ t 'in' s)"
 155  with precedence 10
 156 for @{ match $t with [ mk_Prod ${fresh xy} ${ident z} ⇒ match ${fresh xy} with [ mk_Prod ${ident x} ${ident y} ⇒ $s ] ] }.
 157
 158 (* This appears to upset automation (previously provable results require greater
 159    depth or just don't work), so use example rather than lemma to prevent it
 160    being indexed. *)
 161 example contract_pair : ∀A,B.∀e:A×B. (let 〈a,b〉 ≝ e in 〈a,b〉) = e.
 162 #A #B * // qed.
 163
 164 lemma extract_pair : ∀A,B,C,D.  ∀u:A×B. ∀Q:A → B → C×D. ∀x,y.
 165 ((let 〈a,b〉 ≝ u in Q a b) = 〈x,y〉) →
 166 ∃a,b. 〈a,b〉 = u ∧ Q a b = 〈x,y〉.
 167 #A #B #C #D * #a #b #Q #x #y normalize #E1 %{a} %{b} % try @refl @E1 qed.
 168
 169 lemma breakup_pair : ∀A,B,C:Type[0].∀x. ∀R:C → Prop. ∀P:A → B → C.
 170   R (P (\fst x) (\snd x)) → R (let 〈a,b〉 ≝ x in P a b).
 171 #A #B #C *; normalize /2/
 172 qed.
 173
 174 lemma pair_elim:
 175   ∀A,B,C: Type[0].
 176   ∀T: A → B → C.
 177   ∀p.
 178   ∀P: A×B → C → Prop.
 179     (∀lft, rgt. p = 〈lft,rgt〉 → P 〈lft,rgt〉 (T lft rgt)) →
 180       P p (let 〈lft, rgt〉 ≝ p in T lft rgt).
 181  #A #B #C #T * /2/
 182 qed.
 183
 184 lemma pair_elim2:
 185   ∀A,B,C,C': Type[0].
 186   ∀T: A → B → C.
 187   ∀T': A → B → C'.
 188   ∀p.
 189   ∀P: A×B → C → C' → Prop.
 190     (∀lft, rgt. p = 〈lft,rgt〉 → P 〈lft,rgt〉 (T lft rgt) (T' lft rgt)) →
 191       P p (let 〈lft, rgt〉 ≝ p in T lft rgt) (let 〈lft, rgt〉 ≝ p in T' lft rgt).
 192  #A #B #C #C' #T #T' * /2/
 193 qed.
 194
 195 (* Useful for avoiding destruct's full normalization. *)
 196 lemma pair_eq1: ∀A,B. ∀a1,a2:A. ∀b1,b2:B. 〈a1,b1〉 = 〈a2,b2〉 → a1 = a2.
 197 #A #B #a1 #a2 #b1 #b2 #H destruct //
 198 qed.
 199
 200 lemma pair_eq2: ∀A,B. ∀a1,a2:A. ∀b1,b2:B. 〈a1,b1〉 = 〈a2,b2〉 → b1 = b2.
 201 #A #B #a1 #a2 #b1 #b2 #H destruct //
 202 qed.
 203
 204 lemma pair_destruct_1:
 205  ∀A,B.∀a:A.∀b:B.∀c. 〈a,b〉 = c → a = \fst c.
 206  #A #B #a #b *; /2/
 207 qed.
 208
 209 lemma pair_destruct_2:
 210  ∀A,B.∀a:A.∀b:B.∀c. 〈a,b〉 = c → b = \snd c.
 211  #A #B #a #b *; /2/
 212 qed.