matita/matita/matitaGtkMisc.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 exception PopupClosed
  29 open Printf
  30
  31 let wrap_callback0 f = fun _ -> try f () with Not_found -> assert false
  32 let wrap_callback1 f = fun _ -> try f () with Not_found -> assert false
  33 let wrap_callback2 f = fun _ -> try f () with Not_found -> assert false
  34
  35 let connect_button (button: #GButton.button) callback =
  36   ignore (button#connect#clicked (wrap_callback0 callback))
  37
  38 let connect_toggle_button (button: #GButton.toggle_button) callback =
  39   ignore (button#connect#toggled (wrap_callback1 callback))
  40
  41 let connect_menu_item (menu_item: #GMenu.menu_item) callback =
  42   ignore (menu_item#connect#activate (wrap_callback2 callback))
  43
  44 let connect_key (ev:GObj.event_ops) ?(modifiers = []) ?(stop = false) key
  45   callback
  46 =
  47   ignore (ev#connect#key_press (fun key' ->
  48     let modifiers' = GdkEvent.Key.state key' in
  49     (match key' with
  50     | key' when GdkEvent.Key.keyval key' = key
  51           && List.for_all (fun m -> List.mem m modifiers') modifiers ->
  52         callback ();
  53         stop
  54     | _ -> false)))
  55
  56 let toggle_widget_visibility ~(widget: GObj.widget)
  57                               ~(check: GMenu.check_menu_item)
  58 =
  59   ignore (check#connect#toggled (fun _ ->
  60     if check#active then widget#misc#show () else widget#misc#hide ()))
  61
  62 let toggle_window_visibility ~(window: GWindow.window)
  63                               ~(check: GMenu.check_menu_item)
  64 =
  65   ignore (check#connect#toggled (fun _ ->
  66     if check#active then window#show () else window#misc#hide ()));
  67   ignore (window#event#connect#delete (fun _ ->
  68     window#misc#hide ();
  69     check#set_active false;
  70     true))
  71
  72 let toggle_win ?(check: GMenu.check_menu_item option) (win: GWindow.window) () =
  73   if win#is_active then win#misc#hide () else win#show ();
  74   match check with
  75   | None -> ()
  76   | Some check -> check#set_active (not check#active)
  77
  78 let toggle_callback ~callback ~(check: GMenu.check_menu_item) =
  79   ignore (check#connect#toggled (fun _ -> callback check#active))
  80
  81 class multiStringListModel ~cols (tree_view: GTree.view) =
  82   let column_list = new GTree.column_list in
  83   let text_columns =
  84     let rec aux = function
  85       | 0 -> []
  86       | n -> column_list#add Gobject.Data.string :: aux (n - 1)
  87     in
  88     aux cols
  89   in
  90   let list_store = GTree.list_store column_list in
  91   let renderers =
  92     List.map
  93     (fun text_column ->
  94       (GTree.cell_renderer_text [], ["text", text_column]))
  95     text_columns
  96   in
  97   let view_columns =
  98     List.map
  99       (fun renderer -> GTree.view_column ~renderer ())
 100       renderers
 101   in
 102   object (self)
 103     val text_columns = text_columns
 104
 105     initializer
 106       tree_view#set_model (Some (list_store :> GTree.model));
 107       List.iter
 108         (fun view_column -> ignore (tree_view#append_column view_column))
 109         view_columns
 110
 111     method list_store = list_store
 112
 113     method easy_mappend slist =
 114       let tree_iter = list_store#append () in
 115       List.iter2
 116         (fun s text_column ->
 117         list_store#set ~row:tree_iter ~column:text_column s)
 118         slist text_columns
 119
 120     method easy_minsert pos s =
 121       let tree_iter = list_store#insert pos in
 122       List.iter2
 123         (fun s text_column ->
 124         list_store#set ~row:tree_iter ~column:text_column s)
 125         s text_columns
 126
 127     method easy_mselection () =
 128       List.map
 129         (fun tree_path ->
 130           let iter = list_store#get_iter tree_path in
 131           List.map
 132             (fun text_column ->
 133             list_store#get ~row:iter ~column:text_column)
 134           text_columns)
 135         tree_view#selection#get_selected_rows
 136   end
 137
 138 class stringListModel (tree_view: GTree.view) =
 139   object (self)
 140     inherit multiStringListModel ~cols:1 tree_view as multi
 141
 142     method list_store = multi#list_store
 143
 144     method easy_append s =
 145       multi#easy_mappend [s]
 146
 147     method easy_insert pos s =
 148       multi#easy_minsert pos [s]
 149
 150     method easy_selection () =
 151       let m = List.map
 152         (fun tree_path ->
 153           let iter = self#list_store#get_iter tree_path in
 154           List.map
 155             (fun text_column ->
 156             self#list_store#get ~row:iter ~column:text_column)
 157           text_columns)
 158         tree_view#selection#get_selected_rows
 159       in
 160       List.map (function [x] -> x | _ -> assert false) m
 161   end
 162
 163 class taggedStringListModel ~(tags:(string * GdkPixbuf.pixbuf) list)
 164   (tree_view: GTree.view)
 165 =
 166   let column_list = new GTree.column_list in
 167   let tag_column = column_list#add Gobject.Data.gobject in
 168   let text_column = column_list#add Gobject.Data.string in
 169   let list_store = GTree.list_store column_list in
 170   let text_renderer = (GTree.cell_renderer_text [], ["text", text_column]) in
 171   let tag_renderer = (GTree.cell_renderer_pixbuf [], ["pixbuf", tag_column]) in
 172   let text_vcolumn = GTree.view_column ~renderer:text_renderer () in
 173   let tag_vcolumn = GTree.view_column ~renderer:tag_renderer () in
 174   let lookup_pixbuf tag =
 175     try List.assoc tag tags with Not_found -> assert false
 176   in
 177   object (self)
 178     initializer
 179       tree_view#set_model (Some (list_store :> GTree.model));
 180       ignore (tree_view#append_column tag_vcolumn);
 181       ignore (tree_view#append_column text_vcolumn)
 182
 183     method list_store = list_store
 184
 185     method easy_append ~tag s =
 186       let tree_iter = list_store#append () in
 187       list_store#set ~row:tree_iter ~column:text_column s;
 188       list_store#set ~row:tree_iter ~column:tag_column (lookup_pixbuf tag)
 189
 190     method easy_insert pos ~tag s =
 191       let tree_iter = list_store#insert pos in
 192       list_store#set ~row:tree_iter ~column:text_column s;
 193       list_store#set ~row:tree_iter ~column:tag_column (lookup_pixbuf tag)
 194
 195     method easy_selection () =
 196       List.map
 197         (fun tree_path ->
 198           let iter = list_store#get_iter tree_path in
 199           list_store#get ~row:iter ~column:text_column)
 200         tree_view#selection#get_selected_rows
 201   end
 202
 203 class recordModel (tree_view:GTree.view) =
 204   let cols_list = new GTree.column_list in
 205   let text_col = cols_list#add Gobject.Data.string in
 206 (*   let combo_col = cols_list#add (Gobject.Data.gobject_by_name "GtkListStore") in *)
 207   let combo_col = cols_list#add Gobject.Data.int in
 208   let toggle_col = cols_list#add Gobject.Data.boolean in
 209   let list_store = GTree.list_store cols_list in
 210   let text_rend = (GTree.cell_renderer_text [], ["text", text_col]) in
 211   let combo_rend = GTree.cell_renderer_combo [] in
 212 (*   let combo_rend = (GTree.cell_renderer_combo [], [|+"model", combo_col+|]) in *)
 213   let toggle_rend =
 214     (GTree.cell_renderer_toggle [`ACTIVATABLE true], ["active", toggle_col])
 215   in
 216   let text_vcol = GTree.view_column ~renderer:text_rend () in
 217   let combo_vcol = GTree.view_column ~renderer:(combo_rend, []) () in
 218   let _ =
 219     combo_vcol#set_cell_data_func combo_rend
 220       (fun _ _ ->
 221         prerr_endline "qui";
 222         let model, col =
 223           GTree.store_of_list Gobject.Data.string ["a"; "b"; "c"]
 224         in
 225         combo_rend#set_properties [
 226           `MODEL (Some (model :> GTree.model));
 227           `TEXT_COLUMN col
 228         ])
 229   in
 230   let toggle_vcol = GTree.view_column ~renderer:toggle_rend () in
 231   object (self)
 232     initializer
 233       tree_view#set_model (Some (list_store :> GTree.model));
 234       ignore (tree_view#append_column text_vcol);
 235       ignore (tree_view#append_column combo_vcol);
 236       ignore (tree_view#append_column toggle_vcol)
 237
 238     method list_store = list_store
 239
 240     method easy_append s (combo:int) (toggle:bool) =
 241       let tree_iter = list_store#append () in
 242       list_store#set ~row:tree_iter ~column:text_col s;
 243       list_store#set ~row:tree_iter ~column:combo_col combo;
 244       list_store#set ~row:tree_iter ~column:toggle_col toggle
 245   end
 246
 247 class type gui =
 248   object
 249     method newUriDialog:          unit -> MatitaGeneratedGui.uriChoiceDialog
 250     method newConfirmationDialog: unit -> MatitaGeneratedGui.confirmationDialog
 251     method newEmptyDialog:        unit -> MatitaGeneratedGui.emptyDialog
 252   end
 253
 254 let popup_message
 255   ~title ~message ~buttons ~callback
 256   ?(message_type=`QUESTION) ?parent ?(use_markup=true)
 257   ?(destroy_with_parent=true) ?(allow_grow=false) ?(allow_shrink=false)
 258   ?icon ?(modal=true) ?(resizable=false) ?screen ?type_hint
 259   ?(position=`CENTER_ON_PARENT) ?wm_name ?wm_class ?border_width ?width
 260   ?height ?(show=true) ()
 261 =
 262   let m =
 263     GWindow.message_dialog
 264       ~message ~use_markup ~message_type ~buttons ?parent ~destroy_with_parent
 265       ~title ~allow_grow ~allow_shrink ?icon ~modal ~resizable ?screen
 266       ?type_hint ~position ?wm_name ?wm_class ?border_width ?width ?height
 267       ~show ()
 268   in
 269   ignore(m#connect#response
 270     ~callback:(fun a ->  GMain.Main.quit ();callback a));
 271   ignore(m#connect#close
 272     ~callback:(fun _ -> GMain.Main.quit ();raise PopupClosed));
 273   GtkThread.main ();
 274   m#destroy ()
 275
 276 let popup_message_lowlevel
 277   ~title ~message ?(no_separator=true) ~callback ~message_type ~buttons
 278   ?parent  ?(destroy_with_parent=true) ?(allow_grow=false) ?(allow_shrink=false)
 279   ?icon ?(modal=true) ?(resizable=false) ?screen ?type_hint
 280   ?(position=`CENTER_ON_PARENT) ?wm_name ?wm_class ?border_width ?width
 281   ?height ?(show=true) ()
 282 =
 283   let m =
 284     GWindow.dialog
 285       ~no_separator
 286       ?parent ~destroy_with_parent
 287       ~title ~allow_grow ~allow_shrink ?icon ~modal ~resizable ?screen
 288       ?type_hint ~position ?wm_name ?wm_class ?border_width ?width ?height
 289       ~show:false ()
 290   in
 291   let stock =
 292     match message_type with
 293     | `WARNING -> `DIALOG_WARNING
 294     | `INFO -> `DIALOG_INFO
 295     | `ERROR ->`DIALOG_ERROR
 296     | `QUESTION -> `DIALOG_QUESTION
 297   in
 298   let image = GMisc.image ~stock ~icon_size:`DIALOG () in
 299   let label = GMisc.label ~markup:message () in
 300   label#set_line_wrap true;
 301   let hbox = GPack.hbox ~spacing:10 () in
 302   hbox#pack ~from:`START ~expand:true ~fill:true (image:>GObj.widget);
 303   hbox#pack ~from:`START ~expand:true ~fill:true (label:>GObj.widget);
 304   m#vbox#pack ~from:`START
 305     ~padding:20 ~expand:true ~fill:true (hbox:>GObj.widget);
 306   List.iter (fun (x, y) ->
 307     m#add_button_stock x y;
 308     if y = `CANCEL then
 309       m#set_default_response y
 310   ) buttons;
 311   ignore(m#connect#response
 312     ~callback:(fun a ->  GMain.Main.quit ();callback a));
 313   ignore(m#connect#close
 314     ~callback:(fun _ -> GMain.Main.quit ();callback `POPUPCLOSED));
 315   if show = true then
 316       m#show ();
 317   GtkThread.main ();
 318   m#destroy ()
 319
 320
 321 let ask_confirmation ~title ~message ?parent () =
 322   let rc = ref `YES in
 323   let callback =
 324     function
 325     | `YES -> rc := `YES
 326     | `NO -> rc := `NO
 327     | `CANCEL -> rc := `CANCEL
 328     | `DELETE_EVENT -> rc := `CANCEL
 329     | `POPUPCLOSED -> rc := `CANCEL
 330   in
 331   let buttons = [`YES,`YES ; `NO,`NO ; `CANCEL,`CANCEL] in
 332     popup_message_lowlevel
 333       ~title ~message ~message_type:`WARNING ~callback ~buttons ?parent ();
 334     !rc
 335
 336 let report_error ~title ~message ?parent () =
 337   let callback _ = () in
 338   let buttons = GWindow.Buttons.ok in
 339   try
 340     popup_message
 341       ~title ~message ~message_type:`ERROR ~callback ~buttons ?parent ()
 342   with
 343   | PopupClosed -> ()
 344
 345
 346 let ask_text ~(gui:#gui) ?(title = "") ?(message = "") ?(multiline = false)
 347   ?default ()
 348 =
 349   let dialog = gui#newEmptyDialog () in
 350   dialog#emptyDialog#set_title title;
 351   dialog#emptyDialogLabel#set_label message;
 352   let result = ref None in
 353   let return r =
 354     result := r;
 355     dialog#emptyDialog#destroy ();
 356     GMain.Main.quit ()
 357   in
 358   ignore (dialog#emptyDialog#event#connect#delete (fun _ -> true));
 359   if multiline then begin (* multiline input required: use a TextView widget *)
 360     let win =
 361       GBin.scrolled_window ~width:400 ~height:150 ~hpolicy:`NEVER
 362         ~vpolicy:`ALWAYS ~packing:dialog#emptyDialogVBox#add ()
 363     in
 364     let view = GText.view ~wrap_mode:`CHAR ~packing:win#add () in
 365     let buffer = view#buffer in
 366     (match default with
 367     | None -> ()
 368     | Some text ->
 369         buffer#set_text text;
 370         buffer#select_range buffer#start_iter buffer#end_iter);
 371     view#misc#grab_focus ();
 372     connect_button dialog#emptyDialogOkButton (fun _ ->
 373       return (Some (buffer#get_text ())))
 374   end else begin (* monoline input required: use a TextEntry widget *)
 375     let entry = GEdit.entry ~packing:dialog#emptyDialogVBox#add () in
 376     (match default with
 377     | None -> ()
 378     | Some text ->
 379         entry#set_text text;
 380         entry#select_region ~start:0 ~stop:max_int);
 381     entry#misc#grab_focus ();
 382     connect_button dialog#emptyDialogOkButton (fun _ ->
 383       return (Some entry#text))
 384   end;
 385   connect_button dialog#emptyDialogCancelButton (fun _ ->return None);
 386   dialog#emptyDialog#show ();
 387   GtkThread.main ();
 388   (match !result with None -> raise MatitaTypes.Cancel | Some r -> r)
 389
 390 let utf8_parsed_text s floc =
 391   let start, stop = HExtlib.loc_of_floc floc in
 392   let start_bytes = Glib.Utf8.offset_to_pos s ~pos:0 ~off:start in
 393   let stop_bytes = Glib.Utf8.offset_to_pos s ~pos:0 ~off:stop in
 394   if (stop_bytes < start_bytes) then
 395     Printf.sprintf "ERROR (%d > %d)" start_bytes stop_bytes, 0
 396   else
 397   let bytes = stop_bytes - start_bytes in
 398   try
 399     String.sub s start_bytes bytes, bytes
 400   with Invalid_argument _ ->
 401     Printf.sprintf "ERROR (%s/%d/%d)" s start_bytes bytes, 0
 402
 403 let utf8_string_length s =
 404   if BuildTimeConf.debug then
 405     assert(Glib.Utf8.validate s);
 406   Glib.Utf8.length s
 407
 408 let escape_pango_markup text =
 409    let text = Pcre.replace ~pat:"&" ~templ:"&amp;" text in
 410    let text = Pcre.replace ~pat:"<" ~templ:"&lt;" text in
 411    let text = Pcre.replace ~pat:"'" ~templ:"&apos;" text in
 412    let text = Pcre.replace ~pat:"\"" ~templ:"&quot;" text in
 413    text
 414 ;;
 415
 416 let matita_lang =
 417  let source_language_manager =
 418   GSourceView2.source_language_manager ~default:true in
 419  source_language_manager#set_search_path
 420   (BuildTimeConf.runtime_base_dir ::
 421     source_language_manager#search_path);
 422  match source_language_manager#language "grafite" with
 423  | None ->
 424      HLog.error(sprintf "can't load a language file for \"grafite\" in %s"
 425       BuildTimeConf.runtime_base_dir);
 426      assert false
 427  | Some x -> x
 428 ;;