matita/matita/matitaScript.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module TA = GrafiteAst
  31
  32 let debug = false
  33 let debug_print = if debug then prerr_endline else ignore
  34
  35   (** raised when one of the script margins (top or bottom) is reached *)
  36 exception Margin
  37 exception NoUnfinishedProof
  38 exception ActionCancelled of string
  39
  40 let safe_substring s i j =
  41   try String.sub s i j with Invalid_argument _ -> assert false
  42
  43 let heading_nl_RE = Pcre.regexp "^\\s*\n\\s*"
  44 let heading_nl_RE' = Pcre.regexp "^(\\s*\n\\s*)"
  45 let only_dust_RE = Pcre.regexp "^(\\s|\n|%%[^\n]*\n)*$"
  46 let multiline_RE = Pcre.regexp "^\n[^\n]+$"
  47 let newline_RE = Pcre.regexp "\n"
  48 let comment_RE = Pcre.regexp "\\(\\*(.|\n)*\\*\\)\n?" ~flags:[`UNGREEDY]
  49
  50 let comment str =
  51   if Pcre.pmatch ~rex:multiline_RE str then
  52     "\n(** " ^ (Pcre.replace ~rex:newline_RE str) ^ " *)"
  53   else
  54     "\n(**\n" ^ str ^ "\n*)"
  55
  56 let strip_comments str =
  57   Pcre.qreplace ~templ:"\n" ~pat:"\n\n" (Pcre.qreplace ~rex:comment_RE str)
  58 ;;
  59
  60 let first_line s =
  61   let s = Pcre.replace ~rex:heading_nl_RE s in
  62   try
  63     let nl_pos = String.index s '\n' in
  64     String.sub s 0 nl_pos
  65   with Not_found -> s
  66
  67 let eval_with_engine include_paths status skipped_txt nonskipped_txt st
  68 =
  69   let parsed_text_length =
  70     String.length skipped_txt + String.length nonskipped_txt
  71   in
  72   let text = skipped_txt ^ nonskipped_txt in
  73   let prefix_len = MatitaGtkMisc.utf8_string_length skipped_txt in
  74   let enriched_history_fragment =
  75    MatitaEngine.eval_ast ~include_paths ~do_heavy_checks:(Helm_registry.get_bool
  76      "matita.do_heavy_checks")
  77     status (text,prefix_len,st)
  78   in
  79   let enriched_history_fragment = List.rev enriched_history_fragment in
  80   (* really fragile *)
  81   let res,_ =
  82     List.fold_left
  83       (fun (acc, to_prepend) (status,alias) ->
  84        match alias with
  85        | None -> (status,to_prepend ^ nonskipped_txt)::acc,""
  86        | Some (_k,value) ->
  87             let newtxt = GrafiteAstPp.pp_alias value in
  88             (status,to_prepend ^ newtxt ^ "\n")::acc, "")
  89       ([],skipped_txt) enriched_history_fragment
  90   in
  91   res,"",parsed_text_length
  92 ;;
  93
  94 let pp_eager_statement_ast = GrafiteAstPp.pp_statement
  95
  96 let eval_nmacro _include_paths (_buffer : GText.buffer) status _unparsed_text parsed_text script mac =
  97   let parsed_text_length = String.length parsed_text in
  98   match mac with
  99   | TA.Screenshot (_,name) ->
 100        let status = script#status in
 101        let _,_,menv,subst,_ = status#obj in
 102        let name = Filename.dirname (script#filename) ^ "/" ^ name in
 103        let sequents =
 104          let selected = Continuationals.Stack.head_goals status#stack in
 105          List.filter (fun (x,_) -> List.mem x selected) menv
 106        in
 107        CicMathView.screenshot status sequents menv subst name;
 108        [status, parsed_text], "", parsed_text_length
 109   | TA.NCheck (_,t) ->
 110       let status = script#status in
 111       let _,_,menv,subst,_ = status#obj in
 112       let ctx =
 113        match Continuationals.Stack.head_goals status#stack with
 114           [] -> []
 115         | g::tl ->
 116            if tl <> [] then
 117             HLog.warn
 118              "Many goals focused. Using the context of the first one\n";
 119            let ctx = try
 120              let _, ctx, _ = NCicUtils.lookup_meta g menv in ctx
 121              with NCicUtils.Meta_not_found _ ->
 122                HLog.warn "Current goal is closed. Using empty context.";
 123                [ ]
 124            in ctx
 125       in
 126       let m, s, status, t =
 127         GrafiteDisambiguate.disambiguate_nterm
 128           status `XTNone ctx menv subst (parsed_text,parsed_text_length,
 129             NotationPt.Cast (t,NotationPt.Implicit `JustOne))
 130           (* XXX use the metasenv, if possible *)
 131       in
 132       MatitaMathView.cicBrowser (Some (`NCic (t,ctx,m,s)));
 133       [status, parsed_text], "", parsed_text_length
 134   | TA.NIntroGuess _loc ->
 135       let names_ref = ref [] in
 136       let s = NTactics.intros_tac ~names_ref [] script#status in
 137       let rex = Pcre.regexp ~flags:[`MULTILINE] "\\A([\\n\\t\\r ]*).*\\Z" in
 138       let nl = Pcre.replace ~rex ~templ:"$1" parsed_text in
 139       [s, nl ^ "#" ^ String.concat " #" !names_ref], "", parsed_text_length
 140   | TA.NAutoInteractive (_loc, (None,a)) ->
 141       let trace_ref = ref [] in
 142       let s = NnAuto.auto_tac ~params:(None,a) ~trace_ref script#status in
 143       let depth =
 144         try List.assoc "depth" a
 145         with Not_found -> ""
 146       in
 147       let width =
 148         try List.assoc "width" a
 149         with Not_found -> ""
 150       in
 151       let trace = "/"^(if int_of_string depth > 1 then depth ^ " width=" ^ width else "")^" by " in
 152       let thms =
 153         match !trace_ref with
 154         | [] -> ""
 155         | thms ->
 156            String.concat ", "
 157              (HExtlib.filter_map (function
 158                | NotationPt.NRef r -> Some (NCicPp.r2s status true r)
 159                | _ -> None)
 160              thms)
 161       in
 162       let rex = Pcre.regexp ~flags:[`MULTILINE] "\\A([\\n\\t\\r ]*).*\\Z" in
 163       let nl = Pcre.replace ~rex ~templ:"$1" parsed_text in
 164       [s, nl ^ trace ^ thms ^ "/"], "", parsed_text_length
 165   | TA.NAutoInteractive (_, (Some _,_)) -> assert false
 166
 167 let rec eval_executable include_paths (buffer : GText.buffer)
 168 status unparsed_text skipped_txt nonskipped_txt script ex loc
 169 =
 170   try
 171    ignore (buffer#move_mark (`NAME "beginning_of_statement")
 172     ~where:((buffer#get_iter_at_mark (`NAME "locked"))#forward_chars
 173        (Glib.Utf8.length skipped_txt))) ;
 174    eval_with_engine include_paths status skipped_txt nonskipped_txt
 175     (TA.Executable (loc, ex))
 176   with
 177      MatitaTypes.Cancel -> [], "", 0
 178    | GrafiteEngine.NMacro (_loc,macro) ->
 179        eval_nmacro include_paths buffer status
 180         unparsed_text (skipped_txt ^ nonskipped_txt) script macro
 181
 182
 183 and eval_statement include_paths (buffer : GText.buffer) status script
 184  statement
 185 =
 186   let st,unparsed_text =
 187     match statement with
 188     | `Raw text ->
 189         if Pcre.pmatch ~rex:only_dust_RE text then raise Margin;
 190         let strm =
 191          GrafiteParser.parsable_statement status
 192           (Ulexing.from_utf8_string text) in
 193         let ast = MatitaEngine.get_ast status include_paths strm in
 194          ast, text
 195     | `Ast (st, text) -> st, text
 196   in
 197   let text_of_loc floc =
 198     let nonskipped_txt,_ = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 199     let start, stop = HExtlib.loc_of_floc floc in
 200     let floc = HExtlib.floc_of_loc (0, start) in
 201     let skipped_txt,_ = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 202     let floc = HExtlib.floc_of_loc (0, stop) in
 203     let txt,len = MatitaGtkMisc.utf8_parsed_text unparsed_text floc in
 204     txt,nonskipped_txt,skipped_txt,len
 205   in
 206   match st with
 207   | GrafiteAst.Executable (loc, ex) ->
 208      let _, nonskipped, skipped, _parsed_text_length = text_of_loc loc in
 209       eval_executable include_paths buffer status unparsed_text
 210        skipped nonskipped script ex loc
 211   | GrafiteAst.Comment (loc, GrafiteAst.Code (_, ex))
 212     when Helm_registry.get_bool "matita.execcomments" ->
 213      let _, nonskipped, skipped, _parsed_text_length = text_of_loc loc in
 214       eval_executable include_paths buffer status unparsed_text
 215        skipped nonskipped script ex loc
 216   | GrafiteAst.Comment (loc, _) ->
 217       let parsed_text, _, _, parsed_text_length = text_of_loc loc in
 218       let remain_len = String.length unparsed_text - parsed_text_length in
 219       let s = String.sub unparsed_text parsed_text_length remain_len in
 220       let s,text,len =
 221        try
 222         eval_statement include_paths buffer status script (`Raw s)
 223        with
 224           HExtlib.Localized (floc, exn) ->
 225            HExtlib.raise_localized_exception
 226              ~offset:(MatitaGtkMisc.utf8_string_length parsed_text) floc exn
 227         | MultiPassDisambiguator.DisambiguationError (offset,errorll) ->
 228            raise
 229             (MultiPassDisambiguator.DisambiguationError
 230               (offset+parsed_text_length, errorll))
 231       in
 232       assert (text=""); (* no macros inside comments, please! *)
 233       (match s with
 234       | (statuses,text)::tl ->
 235          (statuses,parsed_text ^ text)::tl,"",parsed_text_length + len
 236       | [] -> [], "", 0)
 237
 238 let fresh_script_id =
 239   let i = ref 0 in
 240   fun () -> incr i; !i
 241
 242 (** Selection handling
 243  * Two clipboards are used: "clipboard" and "primary".
 244  * "primary" is used by X, when you hit the middle button mouse is content is
 245  *    pasted between applications. In Matita this selection always contain the
 246  *    textual version of the selected term.
 247  * "clipboard" is used inside Matita only and support ATM two different targets:
 248  *    "TERM" and "PATTERN", in the future other targets like "MATHMLCONTENT" may
 249  *    be added
 250  *)
 251 class script ~(parent:GBin.scrolled_window) ~tab_label () =
 252 let source_view =
 253   GSourceView3.source_view
 254     ~auto_indent:true
 255     ~insert_spaces_instead_of_tabs:true ~tab_width:2
 256     ~right_margin_position:80 ~show_right_margin:true
 257     ~smart_home_end:`AFTER
 258     ~packing:parent#add
 259     () in
 260 let buffer = source_view#buffer in
 261 let source_buffer = source_view#source_buffer in
 262 let _ =
 263  source_buffer#connect#notify_can_undo
 264   ~callback:(MatitaMisc.get_gui ())#main#undoMenuItem#misc#set_sensitive in
 265 let _ =
 266  source_buffer#connect#notify_can_redo
 267   ~callback:(MatitaMisc.get_gui ())#main#redoMenuItem#misc#set_sensitive in
 268 let similarsymbols_tag_name = "similarsymbolos" in
 269 let similarsymbols_tag = `NAME similarsymbols_tag_name in
 270 let initial_statuses current baseuri =
 271  let status = new MatitaEngine.status baseuri in
 272  (match current with
 273      Some _current -> NCicLibrary.time_travel status;
 274 (*
 275       (* MATITA 1.0: there is a known bug in invalidation; temporary fix here *)
 276       NCicEnvironment.invalidate () *)
 277    | None -> ());
 278   status
 279 in
 280 let default_buri = "cic:/matita/tests" in
 281 let default_fname = ".unnamed.ma" in
 282 object (self)
 283   val mutable include_paths_ = []
 284   val clipboard = GData.clipboard Gdk.Atom.clipboard
 285   (*val primary = GData.clipboard Gdk.Atom.primary*)
 286   val mutable similarsymbols = []
 287   val mutable similarsymbols_orig = []
 288   val similar_memory = Hashtbl.create 97
 289   val mutable old_used_memory = false
 290
 291   val scriptId = fresh_script_id ()
 292
 293   val mutable filename_ = (None : string option)
 294
 295   method has_name = filename_ <> None
 296
 297   method source_view = source_view
 298
 299   method include_paths =
 300     include_paths_ @
 301     Helm_registry.get_list Helm_registry.string "matita.includes"
 302
 303   method private curdir =
 304     try
 305      let root, _buri, _fname, _tgt =
 306       Librarian.baseuri_of_script ~include_paths:self#include_paths
 307        self#filename
 308      in
 309      root
 310     with Librarian.NoRootFor _ -> Sys.getcwd ()
 311
 312   method buri_of_current_file =
 313     match filename_ with
 314     | None -> default_buri
 315     | Some f ->
 316         try
 317           let _root, buri, _fname, _tgt =
 318             Librarian.baseuri_of_script ~include_paths:self#include_paths f
 319           in
 320           buri
 321         with Librarian.NoRootFor _ | Librarian.FileNotFound _ -> default_buri
 322
 323   method filename = match filename_ with None -> default_fname | Some f -> f
 324
 325   initializer
 326     ignore
 327      (source_view#source_buffer#begin_not_undoable_action ();
 328       self#reset ();
 329       self#template ();
 330       source_view#source_buffer#end_not_undoable_action ());
 331     MatitaMisc.observe_font_size (fun font_size ->
 332      source_view#misc#modify_font_by_name
 333         (sprintf "%s %d" BuildTimeConf.script_font font_size));
 334     source_view#misc#grab_focus ();
 335     ignore(source_view#source_buffer#set_language
 336      (Some MatitaGtkMisc.matita_lang));
 337     ignore(source_view#source_buffer#set_highlight_syntax true);
 338     ignore(source_view#connect#after#paste_clipboard
 339         ~callback:(fun () -> self#clean_dirty_lock));
 340     ignore (GMain.Timeout.add ~ms:300000
 341        ~callback:(fun _ -> self#_saveToBackupFile ();true));
 342     ignore (buffer#connect#modified_changed
 343       (fun _ -> self#set_star buffer#modified));
 344     (* clean_locked is set to true only "during" a PRIMARY paste
 345        operation (i.e. by clicking with the second mouse button) *)
 346     let clean_locked = ref false in
 347     ignore(source_view#event#connect#button_press
 348       ~callback:
 349         (fun button ->
 350           if GdkEvent.Button.button button = 2 then
 351            clean_locked := true;
 352           false
 353         ));
 354     ignore(source_view#event#connect#button_release
 355       ~callback:(fun _button -> clean_locked := false; false));
 356     ignore(source_view#buffer#connect#after#apply_tag
 357      ~callback:(
 358        fun tag ~start:_ ~stop:_ ->
 359         if !clean_locked &&
 360            tag#get_oid = self#locked_tag#get_oid
 361         then
 362          begin
 363           clean_locked := false;
 364           self#clean_dirty_lock;
 365           clean_locked := true
 366          end));
 367     ignore(source_view#source_buffer#connect#after#insert_text
 368      ~callback:(fun iter str ->
 369         if (MatitaMisc.get_gui ())#main#menuitemAutoAltL#active && (str = " " || str = "\n") then
 370           ignore(self#expand_virtual_if_any iter str)));
 371     ignore(source_view#connect#after#populate_popup
 372      ~callback:(fun pre_menu ->
 373        let menu = new GMenu.menu pre_menu in
 374        let menuItems = menu#children in
 375        let undoMenuItem, redoMenuItem =
 376         match menuItems with
 377            [undo;redo;_sep1;cut;copy;paste;delete;_sep2;
 378             _selectall;_sep3;_inputmethod;_insertunicodecharacter] ->
 379               List.iter menu#remove [ copy; cut; delete; paste ];
 380               undo,redo
 381          | _ -> assert false in
 382        let add_menu_item =
 383          let i = ref 2 in (* last occupied position *)
 384          fun ~label ->
 385            incr i;
 386            GMenu.menu_item ~label ~packing:(menu#insert ~pos:!i) () in
 387        let copy = add_menu_item ~label:"Copy" in
 388        let cut = add_menu_item ~label:"Cut" in
 389        let delete = add_menu_item ~label:"Delete" in
 390        let paste = add_menu_item ~label:"Paste" in
 391        let paste_pattern = add_menu_item ~label:"Paste as pattern" in
 392        copy#misc#set_sensitive self#canCopy;
 393        cut#misc#set_sensitive self#canCut;
 394        delete#misc#set_sensitive self#canDelete;
 395        paste#misc#set_sensitive self#canPaste;
 396        paste_pattern#misc#set_sensitive self#canPastePattern;
 397        MatitaGtkMisc.connect_menu_item copy self#copy;
 398        MatitaGtkMisc.connect_menu_item cut self#cut;
 399        MatitaGtkMisc.connect_menu_item delete self#delete;
 400        MatitaGtkMisc.connect_menu_item paste self#paste;
 401        MatitaGtkMisc.connect_menu_item paste_pattern self#pastePattern;
 402        let new_undoMenuItem =
 403         GMenu.menu_item
 404          ~use_mnemonic:true
 405          ~label:"_Undo"
 406          ~packing:(menu#insert ~pos:0) () in
 407        new_undoMenuItem#misc#set_sensitive
 408         undoMenuItem#misc#sensitive;
 409        menu#remove (undoMenuItem :> GMenu.menu_item);
 410        MatitaGtkMisc.connect_menu_item new_undoMenuItem
 411         (fun () -> self#safe_undo);
 412        let new_redoMenuItem =
 413         GMenu.menu_item
 414          ~use_mnemonic:true
 415          ~label:"_Redo"
 416          ~packing:(menu#insert ~pos:1) () in
 417        new_redoMenuItem#misc#set_sensitive
 418         redoMenuItem#misc#sensitive;
 419         menu#remove (redoMenuItem :> GMenu.menu_item);
 420         MatitaGtkMisc.connect_menu_item new_redoMenuItem
 421          (fun () -> self#safe_redo)));
 422
 423   val mutable statements = []    (** executed statements *)
 424
 425   val mutable history = [ initial_statuses None default_buri ]
 426     (** list of states before having executed statements. Head element of this
 427       * list is the current state, last element is the state at the beginning of
 428       * the script.
 429       * Invariant: this list length is 1 + length of statements *)
 430
 431   (** text mark and tag representing locked part of a script *)
 432   val locked_mark =
 433     buffer#create_mark ~name:"locked" ~left_gravity:true buffer#start_iter
 434   val beginning_of_statement_mark =
 435     buffer#create_mark ~name:"beginning_of_statement"
 436      ~left_gravity:true buffer#start_iter
 437   val locked_tag = buffer#create_tag [`BACKGROUND "lightblue"; `EDITABLE false]
 438   val error_tag = buffer#create_tag [`UNDERLINE `SINGLE; `FOREGROUND "red"]
 439
 440   (** unicode handling *)
 441   method nextSimilarSymbol =
 442     let write_similarsymbol s =
 443       let s = Glib.Utf8.from_unichar s in
 444       let iter = source_view#source_buffer#get_iter_at_mark `INSERT in
 445       assert(Glib.Utf8.validate s);
 446       source_view#source_buffer#delete ~start:iter ~stop:(iter#copy#backward_chars 1);
 447       source_view#source_buffer#insert ~iter:(source_view#source_buffer#get_iter_at_mark `INSERT) s;
 448       (try source_view#source_buffer#delete_mark similarsymbols_tag
 449        with GText.No_such_mark _ -> ());
 450       ignore(source_view#source_buffer#create_mark ~name:similarsymbols_tag_name
 451         (source_view#source_buffer#get_iter_at_mark `INSERT));
 452     in
 453     let new_similarsymbol =
 454       try
 455         let iter_ins = source_view#source_buffer#get_iter_at_mark `INSERT in
 456         let iter_lig = source_view#source_buffer#get_iter_at_mark similarsymbols_tag in
 457         not (iter_ins#equal iter_lig)
 458       with GText.No_such_mark _ -> true
 459     in
 460     if new_similarsymbol then
 461       (if not(self#expand_virtual_if_any (source_view#source_buffer#get_iter_at_mark `INSERT) "")then
 462         let last_symbol =
 463           let i = source_view#source_buffer#get_iter_at_mark `INSERT in
 464           Glib.Utf8.first_char (i#get_slice ~stop:(i#copy#backward_chars 1))
 465         in
 466         (match Virtuals.similar_symbols last_symbol with
 467         | [] ->  ()
 468         | eqclass ->
 469             similarsymbols_orig <- eqclass;
 470             let is_used =
 471               try Hashtbl.find similar_memory similarsymbols_orig
 472               with Not_found ->
 473                 let is_used = List.map (fun x -> x,false) eqclass in
 474                 Hashtbl.add similar_memory eqclass is_used;
 475                 is_used
 476             in
 477             let hd, next, tl =
 478               let used, unused =
 479                 List.partition (fun s -> List.assoc s is_used) eqclass
 480               in
 481               match used @ unused with a::b::c -> a,b,c | _ -> assert false
 482             in
 483             let hd, tl =
 484               if hd = last_symbol then next, tl @ [hd] else hd, (next::tl)
 485             in
 486             old_used_memory <- List.assoc hd is_used;
 487             let is_used =
 488               (hd,true) :: List.filter (fun (x,_) -> x <> hd) is_used
 489             in
 490             Hashtbl.replace similar_memory similarsymbols_orig is_used;
 491             write_similarsymbol hd;
 492             similarsymbols <- tl @ [ hd ]))
 493     else
 494       match similarsymbols with
 495       | [] -> ()
 496       | hd :: tl ->
 497           let is_used = Hashtbl.find similar_memory similarsymbols_orig in
 498           let last = HExtlib.list_last tl in
 499           let old_used_for_last = old_used_memory in
 500           old_used_memory <- List.assoc hd is_used;
 501           let is_used =
 502             (hd, true) :: (last,old_used_for_last) ::
 503               List.filter (fun (x,_) -> x <> last && x <> hd) is_used
 504           in
 505           Hashtbl.replace similar_memory similarsymbols_orig is_used;
 506           similarsymbols <- tl @ [ hd ];
 507           write_similarsymbol hd
 508
 509   method private reset_similarsymbols =
 510    similarsymbols <- [];
 511    similarsymbols_orig <- [];
 512    try source_view#source_buffer#delete_mark similarsymbols_tag
 513    with GText.No_such_mark _ -> ()
 514
 515   method private expand_virtual_if_any iter tok =
 516     try
 517      let len = MatitaGtkMisc.utf8_string_length tok in
 518      let last_word =
 519       let prev = iter#copy#backward_chars len in
 520        prev#get_slice ~stop:(prev#copy#backward_find_char
 521         (fun x -> Glib.Unichar.isspace x || x = Glib.Utf8.first_char "\\"))
 522      in
 523      let inplaceof, symb = Virtuals.symbol_of_virtual last_word in
 524      self#reset_similarsymbols;
 525      let s = Glib.Utf8.from_unichar symb in
 526      assert(Glib.Utf8.validate s);
 527      source_view#source_buffer#delete ~start:iter
 528        ~stop:(iter#copy#backward_chars
 529          (MatitaGtkMisc.utf8_string_length inplaceof + len));
 530      source_view#source_buffer#insert ~iter
 531        (if inplaceof.[0] = '\\' then s else (s ^ tok));
 532      true
 533     with Virtuals.Not_a_virtual -> false
 534
 535   (** selections / clipboards handling *)
 536
 537   method markupSelected = MatitaMathView.has_selection ()
 538   method private textSelected =
 539     (source_view#source_buffer#get_iter_at_mark `INSERT)#compare
 540       (source_view#source_buffer#get_iter_at_mark `SEL_BOUND) <> 0
 541   method private markupStored = MatitaMathView.has_clipboard ()
 542   method private textStored = clipboard#text <> None
 543   method canCopy = self#textSelected
 544   method canCut = self#textSelected
 545   method canDelete = self#textSelected
 546   (*CSC: WRONG CODE: we should look in the clipboard instead! *)
 547   method canPaste = self#markupStored || self#textStored
 548   method canPastePattern = self#markupStored
 549
 550   method safe_undo =
 551    (* phase 1: we save the actual status of the marks and we undo *)
 552    let locked_mark = `MARK (self#locked_mark) in
 553    let locked_iter = source_view#buffer#get_iter_at_mark locked_mark in
 554    let locked_iter_offset = locked_iter#offset in
 555    let mark2 =
 556     `MARK
 557       (source_view#buffer#create_mark ~name:"lock_point"
 558         ~left_gravity:true locked_iter) in
 559    source_view#source_buffer#undo ();
 560    (* phase 2: we save the cursor position and we redo, restoring
 561       the previous status of all the marks *)
 562    let cursor_iter = source_view#buffer#get_iter_at_mark `INSERT in
 563    let mark =
 564     `MARK
 565       (source_view#buffer#create_mark ~name:"undo_point"
 566         ~left_gravity:true cursor_iter)
 567    in
 568     source_view#source_buffer#redo ();
 569     let mark_iter = source_view#buffer#get_iter_at_mark mark in
 570     let mark2_iter = source_view#buffer#get_iter_at_mark mark2 in
 571     let mark2_iter = mark2_iter#set_offset locked_iter_offset in
 572      source_view#buffer#move_mark locked_mark ~where:mark2_iter;
 573      source_view#buffer#delete_mark mark;
 574      source_view#buffer#delete_mark mark2;
 575      (* phase 3: if after the undo the cursor was in the locked area,
 576         then we move it there again and we perform a goto *)
 577      if mark_iter#offset < locked_iter_offset then
 578       begin
 579        source_view#buffer#move_mark `INSERT ~where:mark_iter;
 580        self#goto `Cursor ();
 581       end;
 582      (* phase 4: we perform again the undo. This time we are sure that
 583         the text to undo is not locked *)
 584      source_view#source_buffer#undo ();
 585      source_view#misc#grab_focus ()
 586
 587   method safe_redo =
 588    (* phase 1: we save the actual status of the marks, we redo and
 589       we undo *)
 590    let locked_mark = `MARK (self#locked_mark) in
 591    let locked_iter = source_view#buffer#get_iter_at_mark locked_mark in
 592    let locked_iter_offset = locked_iter#offset in
 593    let mark2 =
 594     `MARK
 595       (source_view#buffer#create_mark ~name:"lock_point"
 596         ~left_gravity:true locked_iter) in
 597    source_view#source_buffer#redo ();
 598    source_view#source_buffer#undo ();
 599    (* phase 2: we save the cursor position and we restore
 600       the previous status of all the marks *)
 601    let cursor_iter = source_view#buffer#get_iter_at_mark `INSERT in
 602    let mark =
 603     `MARK
 604       (source_view#buffer#create_mark ~name:"undo_point"
 605         ~left_gravity:true cursor_iter)
 606    in
 607     let mark_iter = source_view#buffer#get_iter_at_mark mark in
 608     let mark2_iter = source_view#buffer#get_iter_at_mark mark2 in
 609     let mark2_iter = mark2_iter#set_offset locked_iter_offset in
 610      source_view#buffer#move_mark locked_mark ~where:mark2_iter;
 611      source_view#buffer#delete_mark mark;
 612      source_view#buffer#delete_mark mark2;
 613      (* phase 3: if after the undo the cursor is in the locked area,
 614         then we move it there again and we perform a goto *)
 615      if mark_iter#offset < locked_iter_offset then
 616       begin
 617        source_view#buffer#move_mark `INSERT ~where:mark_iter;
 618        self#goto `Cursor ();
 619       end;
 620      (* phase 4: we perform again the redo. This time we are sure that
 621         the text to redo is not locked *)
 622      source_view#source_buffer#redo ();
 623      source_view#misc#grab_focus ()
 624
 625
 626   method copy () =
 627    if self#textSelected
 628    then begin
 629      MatitaMathView.empty_clipboard ();
 630      source_view#buffer#copy_clipboard clipboard;
 631    end else
 632      MatitaMathView.copy_selection ()
 633
 634   method cut () =
 635    source_view#buffer#cut_clipboard clipboard;
 636    MatitaMathView.empty_clipboard ()
 637
 638   method delete () =
 639    ignore (source_view#buffer#delete_selection ())
 640
 641   method paste () =
 642     if MatitaMathView.has_clipboard ()
 643     then source_view#buffer#insert (MatitaMathView.paste_clipboard `Term)
 644     else source_view#buffer#paste_clipboard clipboard;
 645     self#clean_dirty_lock
 646
 647   method pastePattern () =
 648     source_view#buffer#insert (MatitaMathView.paste_clipboard `Pattern)
 649
 650   method locked_mark = locked_mark
 651   method locked_tag = locked_tag
 652   method error_tag = error_tag
 653
 654     (* history can't be empty, the invariant above grant that it contains at
 655      * least the init grafite_status *)
 656   method status = match history with s::_ -> s | _ -> assert false
 657
 658   method private _advance ?statement () =
 659    let s = match statement with Some s -> s | None -> self#getFuture in
 660    if self#bos then LibraryClean.clean_baseuris [self#buri_of_current_file];
 661    HLog.debug ("evaluating: " ^ first_line s ^ " ...");
 662    let time1 = Unix.gettimeofday () in
 663    let entries, newtext, parsed_len =
 664     try
 665      eval_statement self#include_paths buffer self#status self (`Raw s)
 666     with End_of_file -> raise Margin
 667    in
 668    let time2 = Unix.gettimeofday () in
 669    HLog.debug ("... done in " ^ string_of_float (time2 -. time1) ^ "s");
 670    let new_statuses, new_statements =
 671      let statuses, texts = List.split entries in
 672      statuses, texts
 673    in
 674    history <- new_statuses @ history;
 675    statements <- new_statements @ statements;
 676    let start = buffer#get_iter_at_mark (`MARK locked_mark) in
 677    let new_text = String.concat "" (List.rev new_statements) in
 678    if statement <> None then
 679      buffer#insert ~iter:start new_text
 680    else begin
 681      let parsed_text = String.sub s 0 parsed_len in
 682      if new_text <> parsed_text then begin
 683        let stop = start#copy#forward_chars (Glib.Utf8.length parsed_text) in
 684        buffer#delete ~start ~stop;
 685        buffer#insert ~iter:start new_text;
 686      end;
 687    end;
 688    self#moveMark (Glib.Utf8.length new_text);
 689    buffer#insert ~iter:(buffer#get_iter_at_mark (`MARK locked_mark)) newtext
 690
 691   method private _retract offset status new_statements new_history =
 692     NCicLibrary.time_travel status;
 693     statements <- new_statements;
 694     history <- new_history;
 695     self#moveMark (- offset)
 696
 697   method advance ?statement () =
 698     try
 699       self#_advance ?statement ();
 700       self#notify
 701     with
 702     | Margin -> self#notify
 703     | Not_found -> assert false
 704     | Invalid_argument "Array.make" -> HLog.error "The script is too big!\n"
 705     | exc -> self#notify; raise exc
 706
 707   method retract () =
 708     try
 709       let cmp,new_statements,new_history,status =
 710        match statements,history with
 711           stat::statements, _::(status::_ as history) ->
 712            assert (Glib.Utf8.validate stat);
 713            Glib.Utf8.length stat, statements, history, status
 714        | [],[_] -> raise Margin
 715        | _,_ -> assert false
 716       in
 717        self#_retract cmp status new_statements new_history;
 718        self#notify
 719     with
 720     | Margin -> self#notify
 721     | Invalid_argument "Array.make" -> HLog.error "The script is too big!\n"
 722     | exc -> self#notify; raise exc
 723
 724   method private getFuture =
 725     let lock = buffer#get_iter_at_mark (`MARK locked_mark) in
 726     let text = buffer#get_text ~start:lock ~stop:buffer#end_iter () in
 727     text
 728
 729   method expandAllVirtuals =
 730     let lock = buffer#get_iter_at_mark (`MARK locked_mark) in
 731     let text = buffer#get_text ~start:lock ~stop:buffer#end_iter () in
 732     buffer#delete ~start:lock ~stop:buffer#end_iter;
 733     let text = Pcre.replace ~pat:":=" ~templ:"\\def" text in
 734     let text = Pcre.replace ~pat:"->" ~templ:"\\to" text in
 735     let text = Pcre.replace ~pat:"=>" ~templ:"\\Rightarrow" text in
 736     let text =
 737       Pcre.substitute_substrings
 738         ~subst:(fun str ->
 739            let pristine = Pcre.get_substring str 0 in
 740            let input =
 741              if pristine.[0] = ' ' then
 742                String.sub pristine 1 (String.length pristine -1)
 743              else pristine
 744            in
 745            let input =
 746              if input.[String.length input-1] = ' ' then
 747                String.sub input 0 (String.length input -1)
 748              else input
 749            in
 750            let before, after =
 751              if input = "\\forall" ||
 752                 input = "\\lambda" ||
 753                 input = "\\exists" then "","" else " ", " "
 754            in
 755            try
 756              before ^ Glib.Utf8.from_unichar
 757                (snd (Virtuals.symbol_of_virtual input)) ^ after
 758            with Virtuals.Not_a_virtual -> pristine)
 759         ~pat:" ?\\\\[a-zA-Z]+ ?" text
 760     in
 761     buffer#insert ~iter:lock text
 762
 763   (** @param rel_offset relative offset from current position of locked_mark *)
 764   method private moveMark rel_offset =
 765     let mark = `MARK locked_mark in
 766     let old_insert = buffer#get_iter_at_mark `INSERT in
 767     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 768     let current_mark_pos = buffer#get_iter_at_mark mark in
 769     let new_mark_pos =
 770       match rel_offset with
 771       | 0 -> current_mark_pos
 772       | n when n > 0 -> current_mark_pos#forward_chars n
 773       | n (* when n < 0 *) -> current_mark_pos#backward_chars (abs n)
 774     in
 775     buffer#move_mark mark ~where:new_mark_pos;
 776     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:new_mark_pos;
 777     buffer#move_mark `INSERT old_insert;
 778     let mark_position = buffer#get_iter_at_mark mark in
 779     if source_view#move_mark_onscreen mark then
 780      begin
 781       buffer#move_mark mark mark_position;
 782       source_view#scroll_to_mark ~use_align:true ~xalign:1.0 ~yalign:0.1 mark;
 783      end;
 784     let time0 = Unix.gettimeofday () in
 785     GtkThread.sync (fun () -> while Glib.Main.pending () do ignore(Glib.Main.iteration false); done) ();
 786     let time1 = Unix.gettimeofday () in
 787     HLog.debug ("... refresh done in " ^ string_of_float (time1 -. time0) ^ "s")
 788
 789   method clean_dirty_lock =
 790     let lock_mark_iter = buffer#get_iter_at_mark (`MARK locked_mark) in
 791     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 792     buffer#apply_tag locked_tag ~start:buffer#start_iter ~stop:lock_mark_iter
 793
 794   val mutable observers = []
 795
 796   method addObserver (o: GrafiteTypes.status -> unit) =
 797     observers <- o :: observers
 798
 799   method private notify =
 800     let status = self#status in
 801     List.iter (fun o -> o status) observers
 802
 803   method activate =
 804     NCicLibrary.replace self#status;
 805     self#notify
 806
 807   method loadFromFile f =
 808     buffer#set_text (HExtlib.input_file f);
 809     self#reset_buffer;
 810     buffer#set_modified false
 811
 812   method assignFileName file =
 813    match file with
 814       None ->
 815        tab_label#set_text default_fname;
 816        filename_ <- None;
 817        include_paths_ <- [];
 818        self#reset_buffer
 819     | Some file ->
 820        let f = Librarian.absolutize file in
 821         tab_label#set_text (Filename.basename f);
 822         filename_ <- Some f;
 823         include_paths_ <- MatitaEngine.read_include_paths ~include_paths:[] f;
 824         self#reset_buffer
 825
 826   method set_star b =
 827    tab_label#set_text ((if b then "*" else "")^Filename.basename self#filename);
 828    tab_label#misc#set_tooltip_text
 829     ("URI: " ^ self#buri_of_current_file ^ "\nPATH: " ^ self#filename);
 830
 831   method saveToFile () =
 832     if self#has_name then
 833       let oc = open_out self#filename in
 834       output_string oc (buffer#get_text ~start:buffer#start_iter
 835                         ~stop:buffer#end_iter ());
 836       close_out oc;
 837       self#set_star false;
 838       buffer#set_modified false
 839     else
 840       HLog.error "Can't save, no filename selected"
 841
 842   method private _saveToBackupFile () =
 843     if buffer#modified then
 844       begin
 845         let f = self#filename ^ "~" in
 846         let oc = open_out f in
 847         output_string oc (buffer#get_text ~start:buffer#start_iter
 848                             ~stop:buffer#end_iter ());
 849         close_out oc;
 850         HLog.debug ("backup " ^ f ^ " saved")
 851       end
 852
 853   method private reset_buffer =
 854     statements <- [];
 855     history <- [ initial_statuses (Some self#status) self#buri_of_current_file ];
 856     self#notify;
 857     buffer#remove_tag locked_tag ~start:buffer#start_iter ~stop:buffer#end_iter;
 858     buffer#move_mark (`MARK locked_mark) ~where:buffer#start_iter
 859
 860   method reset () =
 861     self#reset_buffer;
 862     source_buffer#begin_not_undoable_action ();
 863     buffer#delete ~start:buffer#start_iter ~stop:buffer#end_iter;
 864     source_buffer#end_not_undoable_action ();
 865     buffer#set_modified false;
 866
 867   method template () =
 868     let template = HExtlib.input_file BuildTimeConf.script_template in
 869     buffer#insert ~iter:(buffer#get_iter `START) template;
 870     buffer#set_modified false;
 871     self#set_star false;
 872
 873   method goto (pos: [`Top | `Bottom | `Cursor]) () =
 874   try
 875     let old_locked_mark =
 876      `MARK
 877        (buffer#create_mark ~name:"old_locked_mark"
 878          ~left_gravity:true (buffer#get_iter_at_mark (`MARK locked_mark))) in
 879     let getpos _ = buffer#get_iter_at_mark (`MARK locked_mark) in
 880     let getoldpos _ = buffer#get_iter_at_mark old_locked_mark in
 881     let dispose_old_locked_mark () = buffer#delete_mark old_locked_mark in
 882     match pos with
 883     | `Top ->
 884         dispose_old_locked_mark ();
 885         self#reset_buffer;
 886         self#notify
 887     | `Bottom ->
 888         (try
 889           let rec dowhile () =
 890             self#_advance ();
 891             let newpos = getpos () in
 892             if (getoldpos ())#compare newpos < 0 then
 893               begin
 894                 buffer#move_mark old_locked_mark newpos;
 895                 dowhile ()
 896               end
 897           in
 898           dowhile ();
 899           dispose_old_locked_mark ();
 900           self#notify
 901         with
 902         | Margin -> dispose_old_locked_mark (); self#notify
 903         | exc -> dispose_old_locked_mark (); self#notify; raise exc)
 904     | `Cursor ->
 905         let locked_iter () = buffer#get_iter_at_mark (`NAME "locked") in
 906         let cursor_iter () = buffer#get_iter_at_mark `INSERT in
 907         let remember =
 908          `MARK
 909            (buffer#create_mark ~name:"initial_insert"
 910              ~left_gravity:true (cursor_iter ())) in
 911         let dispose_remember () = buffer#delete_mark remember in
 912         let remember_iter () =
 913          buffer#get_iter_at_mark (`NAME "initial_insert") in
 914         let cmp () = (locked_iter ())#offset - (remember_iter ())#offset in
 915         let icmp = cmp () in
 916         let forward_until_cursor () = (* go forward until locked > cursor *)
 917           let rec aux () =
 918             self#_advance ();
 919             if cmp () < 0 && (getoldpos ())#compare (getpos ()) < 0
 920             then
 921              begin
 922               buffer#move_mark old_locked_mark (getpos ());
 923               aux ()
 924              end
 925           in
 926           aux ()
 927         in
 928         let rec back_until_cursor len = (* go backward until locked < cursor *)
 929          function
 930             statements, ((status)::_ as history)
 931             when len <= 0 ->
 932              self#_retract (icmp - len) status statements
 933               history
 934           | statement::tl1, _::tl2 ->
 935              back_until_cursor (len - MatitaGtkMisc.utf8_string_length statement) (tl1,tl2)
 936           | _,_ -> assert false
 937         in
 938         (try
 939           begin
 940            if icmp < 0 then       (* locked < cursor *)
 941              (forward_until_cursor (); self#notify)
 942            else if icmp > 0 then  (* locked > cursor *)
 943              (back_until_cursor icmp (statements,history); self#notify)
 944            else                  (* cursor = locked *)
 945                ()
 946           end ;
 947           dispose_remember ();
 948           dispose_old_locked_mark ();
 949         with
 950         | Margin -> dispose_remember (); dispose_old_locked_mark (); self#notify
 951         | exc -> dispose_remember (); dispose_old_locked_mark ();
 952                  self#notify; raise exc)
 953   with Invalid_argument "Array.make" ->
 954      HLog.error "The script is too big!\n"
 955
 956   method bos =
 957     match history with
 958     | _::[] -> true
 959     | _ -> false
 960
 961   method eos =
 962     let rec is_there_only_comments status s =
 963       if Pcre.pmatch ~rex:only_dust_RE s then raise Margin;
 964       let strm =
 965        GrafiteParser.parsable_statement status
 966         (Ulexing.from_utf8_string s)in
 967       match GrafiteParser.parse_statement status strm with
 968       | GrafiteAst.Comment (loc,_) ->
 969           let _,parsed_text_length = MatitaGtkMisc.utf8_parsed_text s loc in
 970           (* CSC: why +1 in the following lines ???? *)
 971           let parsed_text_length = parsed_text_length + 1 in
 972           let remain_len = String.length s - parsed_text_length in
 973           let next = String.sub s parsed_text_length remain_len in
 974           is_there_only_comments status next
 975       | GrafiteAst.Executable _ -> false
 976     in
 977     try is_there_only_comments self#status self#getFuture
 978     with
 979     | NCicLibrary.IncludedFileNotCompiled _
 980     | HExtlib.Localized _
 981     | CicNotationParser.Parse_error _ -> false
 982     | Margin | End_of_file -> true
 983     | Invalid_argument "Array.make" -> false
 984
 985   (* debug *)
 986   method dump () =
 987     HLog.debug "script status:";
 988     HLog.debug ("history size: " ^ string_of_int (List.length history));
 989     HLog.debug (sprintf "%d statements:" (List.length statements));
 990     List.iter HLog.debug statements;
 991     HLog.debug ("Current file name: " ^ self#filename);
 992
 993   method has_parent (p : GObj.widget) = parent#coerce#misc#get_oid = p#misc#get_oid
 994 end
 995
 996 let _script = ref []
 997
 998 let script ~parent ~tab_label ()
 999 =
1000   let s = new script ~parent ~tab_label () in
1001   _script := s::!_script;
1002   s
1003
1004 let at_page page =
1005  let notebook = (MatitaMisc.get_gui ())#main#scriptNotebook in
1006  let parent = notebook#get_nth_page page in
1007   try
1008    List.find (fun s -> s#has_parent parent) !_script
1009   with
1010    Not_found -> assert false
1011 ;;
1012
1013 let current () =
1014  at_page ((MatitaMisc.get_gui ())#main#scriptNotebook#current_page)
1015
1016 let destroy page =
1017  let s = at_page page in
1018   _script := List.filter ((<>) s) !_script
1019 ;;
1020
1021 let iter_scripts f = List.iter f !_script;;
1022
1023 let _ =
1024  CicMathView.register_matita_script_current (current :> unit -> < advance: ?statement:string -> unit -> unit; status: GrafiteTypes.status >)
1025 ;;