matita/matitaGtkMisc.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 exception PopupClosed
  29 open Printf
  30
  31 let wrap_callback0 f = fun _ -> try f () with Not_found -> assert false
  32 let wrap_callback1 f = fun _ -> try f () with Not_found -> assert false
  33 let wrap_callback2 f = fun _ -> try f () with Not_found -> assert false
  34
  35 let connect_button (button: #GButton.button) callback =
  36   ignore (button#connect#clicked (wrap_callback0 callback))
  37
  38 let connect_toggle_button (button: #GButton.toggle_button) callback =
  39   ignore (button#connect#toggled (wrap_callback1 callback))
  40
  41 let connect_menu_item (menu_item: #GMenu.menu_item) callback =
  42   ignore (menu_item#connect#activate (wrap_callback2 callback))
  43
  44 let connect_key (ev:GObj.event_ops) ?(modifiers = []) ?(stop = false) key
  45   callback
  46 =
  47   ignore (ev#connect#key_press (fun key' ->
  48     let modifiers' = GdkEvent.Key.state key' in
  49     (match key' with
  50     | key' when GdkEvent.Key.keyval key' = key
  51           && List.for_all (fun m -> List.mem m modifiers') modifiers ->
  52         callback ();
  53         stop
  54     | _ -> false)))
  55
  56 let toggle_widget_visibility ~(widget: GObj.widget)
  57                               ~(check: GMenu.check_menu_item)
  58 =
  59   ignore (check#connect#toggled (fun _ ->
  60     if check#active then widget#misc#show () else widget#misc#hide ()))
  61
  62 let toggle_window_visibility ~(window: GWindow.window)
  63                               ~(check: GMenu.check_menu_item)
  64 =
  65   ignore (check#connect#toggled (fun _ ->
  66     if check#active then window#show () else window#misc#hide ()));
  67   ignore (window#event#connect#delete (fun _ ->
  68     window#misc#hide ();
  69     check#set_active false;
  70     true))
  71
  72 let toggle_win ?(check: GMenu.check_menu_item option) (win: GWindow.window) () =
  73   if win#is_active then win#misc#hide () else win#show ();
  74   match check with
  75   | None -> ()
  76   | Some check -> check#set_active (not check#active)
  77
  78 let toggle_callback ~callback ~(check: GMenu.check_menu_item) =
  79   ignore (check#connect#toggled (fun _ -> callback check#active))
  80
  81 let add_key_binding key callback (evbox: GBin.event_box) =
  82   ignore (evbox#event#connect#key_press (function
  83     | key' when GdkEvent.Key.keyval key' = key ->
  84         callback ();
  85         false
  86     | _ -> false))
  87
  88 class multiStringListModel ~cols (tree_view: GTree.view) =
  89   let column_list = new GTree.column_list in
  90   let text_columns =
  91     let rec aux = function
  92       | 0 -> []
  93       | n -> column_list#add Gobject.Data.string :: aux (n - 1)
  94     in
  95     aux cols
  96   in
  97   let list_store = GTree.list_store column_list in
  98   let renderers =
  99     List.map
 100     (fun text_column ->
 101       (GTree.cell_renderer_text [], ["text", text_column]))
 102     text_columns
 103   in
 104   let view_columns =
 105     List.map
 106       (fun renderer -> GTree.view_column ~renderer ())
 107       renderers
 108   in
 109   object (self)
 110     val text_columns = text_columns
 111
 112     initializer
 113       tree_view#set_model (Some (list_store :> GTree.model));
 114       List.iter
 115         (fun view_column -> ignore (tree_view#append_column view_column))
 116         view_columns
 117
 118     method list_store = list_store
 119
 120     method easy_mappend slist =
 121       let tree_iter = list_store#append () in
 122       List.iter2
 123         (fun s text_column ->
 124         list_store#set ~row:tree_iter ~column:text_column s)
 125         slist text_columns
 126
 127     method easy_minsert pos s =
 128       let tree_iter = list_store#insert pos in
 129       List.iter2
 130         (fun s text_column ->
 131         list_store#set ~row:tree_iter ~column:text_column s)
 132         s text_columns
 133
 134     method easy_mselection () =
 135       List.map
 136         (fun tree_path ->
 137           let iter = list_store#get_iter tree_path in
 138           List.map
 139             (fun text_column ->
 140             list_store#get ~row:iter ~column:text_column)
 141           text_columns)
 142         tree_view#selection#get_selected_rows
 143   end
 144
 145 class stringListModel (tree_view: GTree.view) =
 146   object (self)
 147     inherit multiStringListModel ~cols:1 tree_view as multi
 148
 149     method list_store = multi#list_store
 150
 151     method easy_append s =
 152       multi#easy_mappend [s]
 153
 154     method easy_insert pos s =
 155       multi#easy_minsert pos [s]
 156
 157     method easy_selection () =
 158       let m = List.map
 159         (fun tree_path ->
 160           let iter = self#list_store#get_iter tree_path in
 161           List.map
 162             (fun text_column ->
 163             self#list_store#get ~row:iter ~column:text_column)
 164           text_columns)
 165         tree_view#selection#get_selected_rows
 166       in
 167       List.map (function [x] -> x | _ -> assert false) m
 168   end
 169
 170 class taggedStringListModel ~(tags:(string * GdkPixbuf.pixbuf) list)
 171   (tree_view: GTree.view)
 172 =
 173   let column_list = new GTree.column_list in
 174   let tag_column = column_list#add Gobject.Data.gobject in
 175   let text_column = column_list#add Gobject.Data.string in
 176   let list_store = GTree.list_store column_list in
 177   let text_renderer = (GTree.cell_renderer_text [], ["text", text_column]) in
 178   let tag_renderer = (GTree.cell_renderer_pixbuf [], ["pixbuf", tag_column]) in
 179   let text_vcolumn = GTree.view_column ~renderer:text_renderer () in
 180   let tag_vcolumn = GTree.view_column ~renderer:tag_renderer () in
 181   let lookup_pixbuf tag =
 182     try List.assoc tag tags with Not_found -> assert false
 183   in
 184   object (self)
 185     initializer
 186       tree_view#set_model (Some (list_store :> GTree.model));
 187       ignore (tree_view#append_column tag_vcolumn);
 188       ignore (tree_view#append_column text_vcolumn)
 189
 190     method list_store = list_store
 191
 192     method easy_append ~tag s =
 193       let tree_iter = list_store#append () in
 194       list_store#set ~row:tree_iter ~column:text_column s;
 195       list_store#set ~row:tree_iter ~column:tag_column (lookup_pixbuf tag)
 196
 197     method easy_insert pos ~tag s =
 198       let tree_iter = list_store#insert pos in
 199       list_store#set ~row:tree_iter ~column:text_column s;
 200       list_store#set ~row:tree_iter ~column:tag_column (lookup_pixbuf tag)
 201
 202     method easy_selection () =
 203       List.map
 204         (fun tree_path ->
 205           let iter = list_store#get_iter tree_path in
 206           list_store#get ~row:iter ~column:text_column)
 207         tree_view#selection#get_selected_rows
 208   end
 209
 210 class recordModel (tree_view:GTree.view) =
 211   let cols_list = new GTree.column_list in
 212   let text_col = cols_list#add Gobject.Data.string in
 213 (*   let combo_col = cols_list#add (Gobject.Data.gobject_by_name "GtkListStore") in *)
 214   let combo_col = cols_list#add Gobject.Data.int in
 215   let toggle_col = cols_list#add Gobject.Data.boolean in
 216   let list_store = GTree.list_store cols_list in
 217   let text_rend = (GTree.cell_renderer_text [], ["text", text_col]) in
 218   let combo_rend = GTree.cell_renderer_combo [] in
 219 (*   let combo_rend = (GTree.cell_renderer_combo [], [|+"model", combo_col+|]) in *)
 220   let toggle_rend =
 221     (GTree.cell_renderer_toggle [`ACTIVATABLE true], ["active", toggle_col])
 222   in
 223   let text_vcol = GTree.view_column ~renderer:text_rend () in
 224   let combo_vcol = GTree.view_column ~renderer:(combo_rend, []) () in
 225   let _ =
 226     combo_vcol#set_cell_data_func combo_rend
 227       (fun _ _ ->
 228         prerr_endline "qui";
 229         let model, col =
 230           GTree.store_of_list Gobject.Data.string ["a"; "b"; "c"]
 231         in
 232         combo_rend#set_properties [
 233           `MODEL (Some (model :> GTree.model));
 234           `TEXT_COLUMN col
 235         ])
 236   in
 237   let toggle_vcol = GTree.view_column ~renderer:toggle_rend () in
 238   object (self)
 239     initializer
 240       tree_view#set_model (Some (list_store :> GTree.model));
 241       ignore (tree_view#append_column text_vcol);
 242       ignore (tree_view#append_column combo_vcol);
 243       ignore (tree_view#append_column toggle_vcol)
 244
 245     method list_store = list_store
 246
 247     method easy_append s (combo:int) (toggle:bool) =
 248       let tree_iter = list_store#append () in
 249       list_store#set ~row:tree_iter ~column:text_col s;
 250       list_store#set ~row:tree_iter ~column:combo_col combo;
 251       list_store#set ~row:tree_iter ~column:toggle_col toggle
 252   end
 253
 254 class type gui =
 255   object
 256     method newUriDialog:          unit -> MatitaGeneratedGui.uriChoiceDialog
 257     method newConfirmationDialog: unit -> MatitaGeneratedGui.confirmationDialog
 258     method newEmptyDialog:        unit -> MatitaGeneratedGui.emptyDialog
 259   end
 260
 261 let popup_message
 262   ~title ~message ~buttons ~callback
 263   ?(message_type=`QUESTION) ?parent ?(use_markup=true)
 264   ?(destroy_with_parent=true) ?(allow_grow=false) ?(allow_shrink=false)
 265   ?icon ?(modal=true) ?(resizable=false) ?screen ?type_hint
 266   ?(position=`CENTER_ON_PARENT) ?wm_name ?wm_class ?border_width ?width
 267   ?height ?(show=true) ()
 268 =
 269   let m =
 270     GWindow.message_dialog
 271       ~message ~use_markup ~message_type ~buttons ?parent ~destroy_with_parent
 272       ~title ~allow_grow ~allow_shrink ?icon ~modal ~resizable ?screen
 273       ?type_hint ~position ?wm_name ?wm_class ?border_width ?width ?height
 274       ~show ()
 275   in
 276   ignore(m#connect#response
 277     ~callback:(fun a ->  GMain.Main.quit ();callback a));
 278   ignore(m#connect#close
 279     ~callback:(fun _ -> GMain.Main.quit ();raise PopupClosed));
 280   GtkThread.main ();
 281   m#destroy ()
 282
 283 let popup_message_lowlevel
 284   ~title ~message ?(no_separator=true) ~callback ~message_type ~buttons
 285   ?parent  ?(destroy_with_parent=true) ?(allow_grow=false) ?(allow_shrink=false)
 286   ?icon ?(modal=true) ?(resizable=false) ?screen ?type_hint
 287   ?(position=`CENTER_ON_PARENT) ?wm_name ?wm_class ?border_width ?width
 288   ?height ?(show=true) ()
 289 =
 290   let m =
 291     GWindow.dialog
 292       ~no_separator
 293       ?parent ~destroy_with_parent
 294       ~title ~allow_grow ~allow_shrink ?icon ~modal ~resizable ?screen
 295       ?type_hint ~position ?wm_name ?wm_class ?border_width ?width ?height
 296       ~show:false ()
 297   in
 298   let stock =
 299     match message_type with
 300     | `WARNING -> `DIALOG_WARNING
 301     | `INFO -> `DIALOG_INFO
 302     | `ERROR ->`DIALOG_ERROR
 303     | `QUESTION -> `DIALOG_QUESTION
 304   in
 305   let image = GMisc.image ~stock ~icon_size:`DIALOG () in
 306   let label = GMisc.label ~markup:message () in
 307   label#set_line_wrap true;
 308   let hbox = GPack.hbox ~spacing:10 () in
 309   hbox#pack ~from:`START ~expand:true ~fill:true (image:>GObj.widget);
 310   hbox#pack ~from:`START ~expand:true ~fill:true (label:>GObj.widget);
 311   m#vbox#pack ~from:`START
 312     ~padding:20 ~expand:true ~fill:true (hbox:>GObj.widget);
 313   List.iter (fun (x, y) ->
 314     m#add_button_stock x y;
 315     if y = `CANCEL then
 316       m#set_default_response y
 317   ) buttons;
 318   ignore(m#connect#response
 319     ~callback:(fun a ->  GMain.Main.quit ();callback a));
 320   ignore(m#connect#close
 321     ~callback:(fun _ -> GMain.Main.quit ();callback `POPUPCLOSED));
 322   if show = true then
 323       m#show ();
 324   GtkThread.main ();
 325   m#destroy ()
 326
 327
 328 let ask_confirmation ~title ~message ?parent () =
 329   let rc = ref `YES in
 330   let callback =
 331     function
 332     | `YES -> rc := `YES
 333     | `NO -> rc := `NO
 334     | `CANCEL -> rc := `CANCEL
 335     | `DELETE_EVENT -> rc := `CANCEL
 336     | `POPUPCLOSED -> rc := `CANCEL
 337   in
 338   let buttons = [`YES,`YES ; `NO,`NO ; `CANCEL,`CANCEL] in
 339     popup_message_lowlevel
 340       ~title ~message ~message_type:`WARNING ~callback ~buttons ?parent ();
 341     !rc
 342
 343 let report_error ~title ~message ?parent () =
 344   let callback _ = () in
 345   let buttons = GWindow.Buttons.ok in
 346   try
 347     popup_message
 348       ~title ~message ~message_type:`ERROR ~callback ~buttons ?parent ()
 349   with
 350   | PopupClosed -> ()
 351
 352
 353 let ask_text ~(gui:#gui) ?(title = "") ?(message = "") ?(multiline = false)
 354   ?default ()
 355 =
 356   let dialog = gui#newEmptyDialog () in
 357   dialog#emptyDialog#set_title title;
 358   dialog#emptyDialogLabel#set_label message;
 359   let result = ref None in
 360   let return r =
 361     result := r;
 362     dialog#emptyDialog#destroy ();
 363     GMain.Main.quit ()
 364   in
 365   ignore (dialog#emptyDialog#event#connect#delete (fun _ -> true));
 366   if multiline then begin (* multiline input required: use a TextView widget *)
 367     let win =
 368       GBin.scrolled_window ~width:400 ~height:150 ~hpolicy:`NEVER
 369         ~vpolicy:`ALWAYS ~packing:dialog#emptyDialogVBox#add ()
 370     in
 371     let view = GText.view ~wrap_mode:`CHAR ~packing:win#add () in
 372     let buffer = view#buffer in
 373     (match default with
 374     | None -> ()
 375     | Some text ->
 376         buffer#set_text text;
 377         buffer#select_range buffer#start_iter buffer#end_iter);
 378     view#misc#grab_focus ();
 379     connect_button dialog#emptyDialogOkButton (fun _ ->
 380       return (Some (buffer#get_text ())))
 381   end else begin (* monoline input required: use a TextEntry widget *)
 382     let entry = GEdit.entry ~packing:dialog#emptyDialogVBox#add () in
 383     (match default with
 384     | None -> ()
 385     | Some text ->
 386         entry#set_text text;
 387         entry#select_region ~start:0 ~stop:max_int);
 388     entry#misc#grab_focus ();
 389     connect_button dialog#emptyDialogOkButton (fun _ ->
 390       return (Some entry#text))
 391   end;
 392   connect_button dialog#emptyDialogCancelButton (fun _ ->return None);
 393   dialog#emptyDialog#show ();
 394   GtkThread.main ();
 395   (match !result with None -> raise MatitaTypes.Cancel | Some r -> r)
 396
 397 let utf8_parsed_text s floc =
 398   let start, stop = HExtlib.loc_of_floc floc in
 399   let start_bytes = Glib.Utf8.offset_to_pos s ~pos:0 ~off:start in
 400   let stop_bytes = Glib.Utf8.offset_to_pos s ~pos:0 ~off:stop in
 401   assert(stop_bytes >= start_bytes);
 402   let bytes = stop_bytes - start_bytes in
 403   try
 404     String.sub s start_bytes bytes, bytes
 405   with Invalid_argument _ ->
 406     Printf.eprintf "%s/%d/%d\n" s start_bytes bytes;
 407     assert false
 408
 409
 410 let utf8_string_length s =
 411   if BuildTimeConf.debug then
 412     assert(Glib.Utf8.validate s);
 413   Glib.Utf8.length s
 414