matita/matitaInit.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 type thingsToInitilaize =
  29   ConfigurationFile | Db | Environment | Getter | Makelib | CmdLine | Registry
  30
  31 exception FailedToInitialize of thingsToInitilaize
  32
  33 let wants s l =
  34   List.iter (
  35     fun item ->
  36       if not (List.exists (fun x -> x = item) l) then
  37         raise (FailedToInitialize item))
  38   s
  39
  40 let already_configured s l =
  41   List.for_all (fun item -> List.exists (fun x -> x = item) l) s
  42
  43 let conffile = ref BuildTimeConf.matita_conf
  44
  45 let registry_defaults = [
  46   "matita.debug",                "false";
  47   "matita.external_editor",      "gvim -f -c 'go %p' %f";
  48   "matita.preserve",             "false";
  49   "matita.profile",              "true";
  50   "matita.system",               "false";
  51   "matita.verbosity",            "1";
  52   "matita.bench",                "false";
  53   "matita.paste_unicode_as_tex", "false";
  54   "matita.noinnertypes",         "false";
  55   "matita.do_heavy_checks",      "true";
  56     (** verbosity level: 1 is the default, 0 is intuitively "quiet", > 1 is
  57      * intuitively verbose *)
  58 ]
  59
  60 let set_registry_values =
  61   List.iter
  62     (fun key, value ->
  63        if not (Helm_registry.has key) then Helm_registry.set ~key ~value)
  64
  65 let fill_registry init_status =
  66   if not (already_configured [ Registry ] init_status) then begin
  67     set_registry_values registry_defaults;
  68     Registry :: init_status
  69   end else
  70     init_status
  71
  72 let load_configuration init_status =
  73   if not (already_configured [ConfigurationFile] init_status) then
  74     begin
  75       Helm_registry.load_from !conffile;
  76       if not (Helm_registry.has "user.name") then begin
  77         let login = (Unix.getpwuid (Unix.getuid ())).Unix.pw_name in
  78         Helm_registry.set "user.name" login
  79       end;
  80       let home = Helm_registry.get_string "matita.basedir" in
  81       let user_conf_file = home ^ "/matita.conf.xml" in
  82       if HExtlib.is_regular user_conf_file then
  83         begin
  84           HLog.message ("Loading additional conf file from " ^ user_conf_file);
  85           try
  86             Helm_registry.load_from user_conf_file
  87           with exn ->
  88             HLog.error
  89               ("While loading conf file: " ^ snd (MatitaExcPp.to_string exn))
  90         end;
  91       ConfigurationFile::init_status
  92     end
  93   else
  94     init_status
  95
  96 let initialize_db init_status =
  97   wants [ ConfigurationFile; CmdLine ] init_status;
  98   if not (already_configured [ Db ] init_status) then
  99     begin
 100       if not (Helm_registry.get_bool "matita.system") then
 101         MetadataTypes.ownerize_tables (Helm_registry.get "matita.owner");
 102       LibraryDb.create_owner_environment ();
 103       Db::init_status
 104     end
 105   else
 106     init_status
 107
 108 let initialize_makelib init_status =
 109   wants [ConfigurationFile] init_status;
 110   if not (already_configured [Makelib] init_status) then
 111     begin
 112       MatitamakeLib.initialize ();
 113       Makelib::init_status
 114     end
 115   else
 116     init_status
 117
 118 let initialize_environment init_status =
 119   wants [CmdLine] init_status;
 120   if not (already_configured [Getter;Environment] init_status) then
 121     begin
 122       Http_getter.init ();
 123       if Helm_registry.get_bool "matita.system" then
 124         Http_getter_storage.activate_system_mode ();
 125       CicEnvironment.set_trust (* environment trust *)
 126         (let trust =
 127           Helm_registry.get_opt_default Helm_registry.get_bool
 128             ~default:true "matita.environment_trust" in
 129          fun _ -> trust);
 130       Getter::Environment::init_status
 131     end
 132   else
 133     init_status
 134
 135 let status = ref []
 136
 137 let usages = Hashtbl.create 11 (** app name (e.g. "matitac") -> usage string *)
 138 let _ =
 139   List.iter
 140     (fun (name, s) -> Hashtbl.replace usages name s)
 141     [ "matitac",
 142         Printf.sprintf "MatitaC v%s
 143 Usage: matitac [ OPTION ... ] FILE
 144 Options:"
 145           BuildTimeConf.version;
 146       "gragrep",
 147         Printf.sprintf "Grafite Grep v%s
 148 Usage: gragrep [ -r ] PATH
 149 Options:"
 150           BuildTimeConf.version;
 151       "matitaprover",
 152         Printf.sprintf "Matita's prover v%s
 153 Usage: matitaprover [ -tptppath ] FILE.p
 154 Options:"
 155           BuildTimeConf.version;
 156       "matita",
 157         Printf.sprintf "Matita v%s
 158 Usage: matita [ OPTION ... ] [ FILE ... ]
 159 Options:"
 160           BuildTimeConf.version;
 161       "cicbrowser",
 162         Printf.sprintf
 163           "CIC Browser v%s
 164 Usage: cicbrowser [ URL | WHELP QUERY ]
 165 Options:"
 166           BuildTimeConf.version;
 167       "matitadep",
 168         Printf.sprintf "MatitaDep v%s
 169 Usage: matitadep [ OPTION ... ] FILE ...
 170 Options:"
 171           BuildTimeConf.version;
 172       "matitaclean",
 173         Printf.sprintf "MatitaClean v%s
 174 Usage: matitaclean all
 175        matitaclean [ (FILE | URI) ... ]
 176 Options:"
 177           BuildTimeConf.version;
 178       "matitamake",
 179         Printf.sprintf "MatitaMake v%s
 180 Usage: matitamake [ OPTION ... ] (init | clean | list | destroy | build)
 181   init
 182     Parameters: name (the name of the development, required)
 183                 root (the directory in which the delopment is rooted,
 184                       optional, default is current working directory)
 185     Description: tells matitamake that a new development radicated
 186       in the current working directory should be handled.
 187   clean
 188     Parameters: name (the name of the development to destroy, optional)
 189       If omitted the development that holds the current working
 190       directory is used (if any).
 191     Description: clean the develpoment.
 192   list
 193     Parameters:
 194     Description: lists the known developments and their roots.
 195   destroy
 196     Parameters: name (the name of the development to destroy, required)
 197     Description: deletes a development (only from matitamake metadat, no
 198       .ma files will be deleted).
 199   build
 200     Parameters: name (the name of the development to build, required)
 201     Description: completely builds the develpoment.
 202   publish
 203     Parameters: name (the name of the development to publish, required)
 204     Description: cleans the development in the user space, rebuilds it
 205       in the system space ('ro' repositories, that for this operation
 206       becames writable).
 207 Notes:
 208   If target is omitted an 'all' will be used as the default.
 209   With -build you can build a development wherever it is.
 210   If you specify a target it implicitly refers to the development that
 211   holds the current working directory (if any).
 212 Options:"
 213           BuildTimeConf.version;
 214     ]
 215 let default_usage =
 216   Printf.sprintf
 217     "Matita v%s\nUsage: matita [ ARG ]\nOptions:" BuildTimeConf.version
 218
 219 let usage () =
 220   let basename = Filename.basename Sys.argv.(0) in
 221   let usage_key =
 222     try Filename.chop_extension basename with Invalid_argument  _ -> basename
 223   in
 224   try Hashtbl.find usages usage_key with Not_found -> default_usage
 225
 226 let extra_cmdline_specs = ref []
 227 let add_cmdline_spec l = extra_cmdline_specs := l @ !extra_cmdline_specs
 228
 229 let parse_cmdline init_status =
 230   if not (already_configured [CmdLine] init_status) then begin
 231     wants [Registry] init_status;
 232     let includes = ref [] in
 233     let default_includes = [
 234       ".";
 235       BuildTimeConf.stdlib_dir_devel;
 236       BuildTimeConf.stdlib_dir_installed ; ]
 237     in
 238     let absolutize s =
 239       if Pcre.pmatch ~pat:"^/" s then s else Sys.getcwd() ^"/"^s
 240     in
 241     let args = ref [] in
 242     let add_l l = fun s -> l := s :: !l in
 243     let reduce_verbosity () =
 244       Helm_registry.set_int "matita.verbosity"
 245         (Helm_registry.get_int "matita.verbosity" - 1) in
 246     let print_version () =
 247             Printf.printf "%s\n" BuildTimeConf.version;exit 0 in
 248     let increase_verbosity () =
 249       Helm_registry.set_int "matita.verbosity"
 250         (Helm_registry.get_int "matita.verbosity" + 1) in
 251     let no_innertypes () =
 252       Helm_registry.set_bool "matita.noinnertypes" true in
 253     let set_baseuri s =
 254       match Str.split (Str.regexp "::") s with
 255       | [path; uri] -> Helm_registry.set "matita.baseuri"
 256           (HExtlib.normalize_path (absolutize path)^" "^uri)
 257       | _ -> raise (Failure "bad baseuri, use -b 'path::uri'")
 258     in
 259     let arg_spec =
 260       let std_arg_spec = [
 261         "-b", Arg.String set_baseuri, "<path::uri> forces the baseuri of path";
 262         "-I", Arg.String (add_l includes),
 263           ("<path> Adds path to the list of searched paths for the "
 264            ^ "include command");
 265         "-conffile", Arg.Set_string conffile,
 266           (Printf.sprintf ("<filename> Read configuration from filename"
 267              ^^ "\n    Default: %s")
 268             BuildTimeConf.matita_conf);
 269         "-force",
 270             Arg.Unit (fun () -> Helm_registry.set_bool "matita.force" true),
 271             ("Force actions that would not be executed per default");
 272         "-noprofile",
 273           Arg.Unit (fun () -> Helm_registry.set_bool "matita.profile" false),
 274           "Turns off profiling printings";
 275         "-noinnertypes", Arg.Unit no_innertypes,
 276           "Turns off inner types generation while publishing";
 277         "-profile-only",
 278           Arg.String (fun rex -> Helm_registry.set "matita.profile_only" rex),
 279           "Activates only profiler with label matching the provided regex";
 280         "-bench",
 281           Arg.Unit (fun () -> Helm_registry.set_bool "matita.bench" true),
 282           "Turns on parsable output on stdout, that is timings for matitac...";
 283         "-preserve",
 284           Arg.Unit (fun () -> Helm_registry.set_bool "matita.preserve" true),
 285           "Turns off automatic baseuri cleaning";
 286         "-q", Arg.Unit reduce_verbosity, "Reduce verbosity";
 287         "-system", Arg.Unit (fun () ->
 288               Helm_registry.set_bool "matita.system" true),
 289             ("Act on the system library instead of the user one"
 290              ^ "\n    WARNING: not for the casual user");
 291         "-v", Arg.Unit increase_verbosity, "Increase verbosity";
 292         "--version", Arg.Unit print_version, "Prints version";
 293       ] in
 294       let debug_arg_spec =
 295         if BuildTimeConf.debug then
 296           [ "-debug",
 297             Arg.Unit (fun () -> Helm_registry.set_bool "matita.debug" true),
 298               ("Do not catch top-level exception "
 299               ^ "(useful for backtrace inspection)");
 300             "-onepass",
 301             Arg.Unit (fun () -> GrafiteDisambiguator.only_one_pass := true),
 302             "Enable only one disambiguation pass";
 303           ]
 304         else []
 305       in
 306       std_arg_spec @ debug_arg_spec @ !extra_cmdline_specs
 307     in
 308     let set_list ~key l =
 309       Helm_registry.set_list Helm_registry.of_string ~key ~value:l
 310     in
 311     Arg.parse arg_spec (add_l args) (usage ());
 312     let includes =
 313       List.map (fun x -> HExtlib.normalize_path (absolutize x))
 314        ((List.rev !includes) @ default_includes)
 315     in
 316     set_list ~key:"matita.includes" includes;
 317     let args = List.rev (List.filter (fun x -> x <> "") !args) in
 318     set_list ~key:"matita.args" args;
 319     HExtlib.set_profiling_printings
 320       (fun s ->
 321         Helm_registry.get_bool "matita.profile" &&
 322         Pcre.pmatch
 323           ~pat:(Helm_registry.get_opt_default
 324                   Helm_registry.string ~default:".*" "matita.profile_only")
 325           s);
 326     CmdLine :: init_status
 327   end else
 328     init_status
 329
 330 let die_usage () =
 331   print_endline (usage ());
 332   exit 1
 333
 334 let conf_components =
 335   [ load_configuration; fill_registry; parse_cmdline]
 336
 337 let other_components =
 338   [ initialize_makelib; initialize_db; initialize_environment ]
 339
 340 let initialize_all () =
 341   status :=
 342     List.fold_left (fun s f -> f s) !status
 343     (conf_components @ other_components)
 344 (*     initialize_notation
 345       (initialize_environment
 346         (initialize_db
 347           (initialize_makelib
 348             (load_configuration
 349               (parse_cmdline !status))))) *)
 350
 351 let parse_cmdline_and_configuration_file () =
 352   status := List.fold_left (fun s f -> f s) !status conf_components
 353
 354 let initialize_environment () =
 355   status := initialize_environment !status
 356
 357 let _ =
 358   Inversion_principle.init ()