matita/matitaMathView.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://cs.unibo.it/helm/.
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 open GrafiteTypes
  31 open MatitaGtkMisc
  32 open MatitaGuiTypes
  33
  34 module Stack = Continuationals.Stack
  35
  36 (** inherit from this class if you want to access current script *)
  37 class scriptAccessor =
  38 object (self)
  39   method private script = MatitaScript.current ()
  40 end
  41
  42 let cicBrowsers = ref []
  43 let gui_instance = ref None
  44 let set_gui gui = gui_instance := Some gui
  45 let get_gui () =
  46   match !gui_instance with
  47   | None -> assert false
  48   | Some gui -> gui
  49
  50 let default_font_size () =
  51   Helm_registry.get_opt_default Helm_registry.int
  52     ~default:BuildTimeConf.default_font_size "matita.font_size"
  53 let current_font_size = ref ~-1
  54 let increase_font_size () = incr current_font_size
  55 let decrease_font_size () = decr current_font_size
  56 let reset_font_size () = current_font_size := default_font_size ()
  57
  58   (* is there any lablgtk2 constant corresponding to the various mouse
  59    * buttons??? *)
  60 let left_button = 1
  61 let middle_button = 2
  62 let right_button = 3
  63
  64 let near (x1, y1) (x2, y2) =
  65   let distance = sqrt (((x2 -. x1) ** 2.) +. ((y2 -. y1) ** 2.)) in
  66   (distance < 4.)
  67
  68 let xlink_ns = Gdome.domString "http://www.w3.org/1999/xlink"
  69 let helm_ns = Gdome.domString "http://www.cs.unibo.it/helm"
  70 let href_ds = Gdome.domString "href"
  71 let xref_ds = Gdome.domString "xref"
  72
  73 let domImpl = Gdome.domImplementation ()
  74
  75   (** Gdome.element of a MathML document whose rendering should be blank. Used
  76   * by cicBrowser to render "about:blank" document *)
  77 let empty_mathml = lazy (
  78   domImpl#createDocument ~namespaceURI:(Some DomMisc.mathml_ns)
  79     ~qualifiedName:(Gdome.domString "math") ~doctype:None)
  80
  81 let empty_boxml = lazy (
  82   domImpl#createDocument ~namespaceURI:(Some DomMisc.boxml_ns)
  83     ~qualifiedName:(Gdome.domString "box") ~doctype:None)
  84
  85   (** shown for goals closed by side effects *)
  86 let closed_goal_mathml = lazy (
  87   domImpl#createDocumentFromURI ~uri:BuildTimeConf.closed_xml ())
  88
  89 (* ids_to_terms should not be passed here, is just for debugging *)
  90 let find_root_id annobj id ids_to_father_ids ids_to_terms ids_to_inner_types =
  91   let find_parent id ids =
  92     let rec aux id =
  93 (*       (prerr_endline (sprintf "id %s = %s" id
  94         (try
  95           CicPp.ppterm (Hashtbl.find ids_to_terms id)
  96         with Not_found -> "NONE"))); *)
  97       if List.mem id ids then Some id
  98       else
  99         (match
 100           (try Hashtbl.find ids_to_father_ids id with Not_found -> None)
 101         with
 102         | None -> None
 103         | Some id' -> aux id')
 104     in
 105     aux id
 106   in
 107   let return_father id ids =
 108     match find_parent id ids with
 109     | None -> assert false
 110     | Some parent_id -> parent_id
 111   in
 112   let mk_ids terms = List.map CicUtil.id_of_annterm terms in
 113   let inner_types =
 114    Hashtbl.fold
 115     (fun _ types acc ->
 116       match types.Cic2acic.annexpected with
 117          None -> types.Cic2acic.annsynthesized :: acc
 118        | Some ty -> ty :: types.Cic2acic.annsynthesized :: acc
 119     ) ids_to_inner_types [] in
 120   match annobj with
 121   | Cic.AConstant (_, _, _, Some bo, ty, _, _)
 122   | Cic.AVariable (_, _, Some bo, ty, _, _)
 123   | Cic.ACurrentProof (_, _, _, _, bo, ty, _, _) ->
 124       return_father id (mk_ids (ty :: bo :: inner_types))
 125   | Cic.AConstant (_, _, _, None, ty, _, _)
 126   | Cic.AVariable (_, _, None, ty, _, _) ->
 127       return_father id (mk_ids (ty::inner_types))
 128   | Cic.AInductiveDefinition _ ->
 129       assert false  (* TODO *)
 130
 131   (** @return string content of a dom node having a single text child node, e.g.
 132    * <m:mi xlink:href="...">bool</m:mi> *)
 133 let string_of_dom_node node =
 134   match node#get_firstChild with
 135   | None -> ""
 136   | Some node ->
 137       (try
 138         let text = new Gdome.text_of_node node in
 139         text#get_data#to_string
 140       with GdomeInit.DOMCastException _ -> "")
 141
 142 let name_of_hypothesis = function
 143   | Some (Cic.Name s, _) -> s
 144   | _ -> assert false
 145
 146 let id_of_node (node: Gdome.element) =
 147   let xref_attr =
 148     node#getAttributeNS ~namespaceURI:helm_ns ~localName:xref_ds in
 149   try
 150     List.hd (HExtlib.split ~sep:' ' xref_attr#to_string)
 151   with Failure _ -> assert false
 152
 153 type selected_term =
 154   | SelTerm of Cic.term * string option (* term, parent hypothesis (if any) *)
 155   | SelHyp of string * Cic.context (* hypothesis, context *)
 156
 157 let hrefs_of_elt elt =
 158   let localName = href_ds in
 159   if elt#hasAttributeNS ~namespaceURI:xlink_ns ~localName then
 160     let text =
 161       (elt#getAttributeNS ~namespaceURI:xlink_ns ~localName)#to_string in
 162     Some (HExtlib.split text)
 163   else
 164     None
 165
 166 class clickableMathView obj =
 167 let text_width = 80 in
 168 object (self)
 169   inherit GMathViewAux.multi_selection_math_view obj
 170
 171   val mutable href_callback: (string -> unit) option = None
 172   method set_href_callback f = href_callback <- f
 173
 174   val mutable _cic_info = None
 175   method private set_cic_info info = _cic_info <- info
 176   method private cic_info = _cic_info
 177
 178   val normal_cursor = Gdk.Cursor.create `LEFT_PTR
 179   val href_cursor = Gdk.Cursor.create `HAND1
 180
 181   initializer
 182     self#set_font_size !current_font_size;
 183     ignore (self#connect#selection_changed self#choose_selection_cb);
 184     ignore (self#event#connect#button_press self#button_press_cb);
 185     ignore (self#event#connect#button_release self#button_release_cb);
 186     ignore (self#event#connect#selection_clear self#selection_clear_cb);
 187     ignore (self#connect#element_over self#element_over_cb);
 188     ignore (self#coerce#misc#connect#selection_get self#selection_get_cb)
 189
 190   val mutable button_press_x = -1.
 191   val mutable button_press_y = -1.
 192   val mutable selection_changed = false
 193   val mutable href_statusbar_msg:
 194     (GMisc.statusbar_context * Gtk.statusbar_message) option = None
 195     (* <statusbar ctxt, statusbar msg> *)
 196
 197   method private selection_get_cb ctxt ~info ~time =
 198     let text =
 199       match ctxt#target with
 200       | "PATTERN" -> self#text_of_selection `Pattern
 201       | "TERM" | _ -> self#text_of_selection `Term
 202     in
 203     match text with
 204     | None -> ()
 205     | Some s -> ctxt#return s
 206
 207   method private text_of_selection fmt =
 208     match self#get_selections with
 209     | [] -> None
 210     | node :: _ -> Some (self#string_of_node ~paste_kind:fmt node)
 211
 212   method private selection_clear_cb sel_event =
 213     self#remove_selections;
 214     (GData.clipboard Gdk.Atom.clipboard)#clear ();
 215     false
 216
 217   method private button_press_cb gdk_button =
 218     let button = GdkEvent.Button.button gdk_button in
 219     if  button = left_button then begin
 220       button_press_x <- GdkEvent.Button.x gdk_button;
 221       button_press_y <- GdkEvent.Button.y gdk_button;
 222       selection_changed <- false
 223     end else if button = right_button then
 224       self#popup_contextual_menu (GdkEvent.Button.time gdk_button);
 225     false
 226
 227   method private element_over_cb (elt_opt, _, _, _) =
 228     let win () = self#misc#window in
 229     let leave_href () =
 230       Gdk.Window.set_cursor (win ()) normal_cursor;
 231       HExtlib.iter_option (fun (ctxt, msg) -> ctxt#remove msg)
 232         href_statusbar_msg
 233     in
 234     match elt_opt with
 235     | Some elt ->
 236         (match hrefs_of_elt elt with
 237         | Some ((_ :: _) as hrefs) ->
 238             Gdk.Window.set_cursor (win ()) href_cursor;
 239             let msg_text = (* now create statusbar msg and store it *)
 240               match hrefs with
 241               | [ href ] -> sprintf "Hyperlink to %s" href
 242               | _ -> sprintf "Hyperlinks to: %s" (String.concat ", " hrefs) in
 243             let ctxt = (get_gui ())#main#statusBar#new_context ~name:"href" in
 244             let msg = ctxt#push msg_text in
 245             href_statusbar_msg <- Some (ctxt, msg)
 246         | _ -> leave_href ())
 247     | None -> leave_href ()
 248
 249   method private tactic_text_pattern_of_node node =
 250    let id = id_of_node node in
 251    let cic_info, unsh_sequent = self#get_cic_info id in
 252    match self#get_term_by_id cic_info id with
 253    | SelTerm (t, father_hyp) ->
 254        let sequent = self#sequent_of_id ~paste_kind:`Pattern id in
 255        let text = self#string_of_cic_sequent ~output_type:`Pattern sequent in
 256        (match father_hyp with
 257        | None -> None, [], Some text
 258        | Some hyp_name -> None, [ hyp_name, text ], None)
 259    | SelHyp (hyp_name, _ctxt) -> None, [ hyp_name, "%" ], None
 260
 261   method private tactic_text_of_node node =
 262    let id = id_of_node node in
 263    let cic_info, unsh_sequent = self#get_cic_info id in
 264    match self#get_term_by_id cic_info id with
 265    | SelTerm (t, father_hyp) ->
 266        let sequent = self#sequent_of_id ~paste_kind:`Term id in
 267        let text = self#string_of_cic_sequent ~output_type:`Term sequent in
 268        text
 269    | SelHyp (hyp_name, _ctxt) -> hyp_name
 270
 271     (** @return a pattern structure which contains pretty printed terms *)
 272   method private tactic_text_pattern_of_selection =
 273     match self#get_selections with
 274     | [] -> assert false (* this method is invoked only if there's a sel. *)
 275     | node :: _ -> self#tactic_text_pattern_of_node node
 276
 277   method private popup_contextual_menu time =
 278     let menu = GMenu.menu () in
 279     let add_menu_item ?(menu = menu) ?stock ?label () =
 280       GMenu.image_menu_item ?stock ?label ~packing:menu#append () in
 281     let check = add_menu_item ~label:"Check" () in
 282     let reductions_menu_item = GMenu.menu_item ~label:"βδιζ-reduce" () in
 283     let tactics_menu_item = GMenu.menu_item ~label:"Apply tactic" () in
 284     menu#append reductions_menu_item;
 285     menu#append tactics_menu_item;
 286     let reductions = GMenu.menu () in
 287     let tactics = GMenu.menu () in
 288     reductions_menu_item#set_submenu reductions;
 289     tactics_menu_item#set_submenu tactics;
 290     let normalize = add_menu_item ~menu:reductions ~label:"Normalize" () in
 291     let reduce = add_menu_item ~menu:reductions ~label:"Reduce" () in
 292     let simplify = add_menu_item ~menu:reductions ~label:"Simplify" () in
 293     let whd = add_menu_item ~menu:reductions ~label:"Weak head" () in
 294     menu#append (GMenu.separator_item ());
 295     let copy = add_menu_item ~stock:`COPY () in
 296     let gui = get_gui () in
 297     List.iter (fun item -> item#misc#set_sensitive gui#canCopy)
 298       [ copy; check; normalize; reduce; simplify; whd ];
 299     let reduction_action kind () =
 300       let pat = self#tactic_text_pattern_of_selection in
 301       let statement =
 302         let loc = HExtlib.dummy_floc in
 303         "\n" ^
 304         GrafiteAstPp.pp_executable ~term_pp:(fun s -> s)
 305           ~lazy_term_pp:(fun _ -> assert false) ~obj_pp:(fun _ -> assert false)
 306           ~map_unicode_to_tex:(Helm_registry.get_bool
 307             "matita.paste_unicode_as_tex")
 308           (GrafiteAst.Tactic (loc,
 309             Some (GrafiteAst.Reduce (loc, kind, pat)),
 310             GrafiteAst.Semicolon loc)) in
 311       (MatitaScript.current ())#advance ~statement () in
 312     connect_menu_item copy gui#copy;
 313     connect_menu_item normalize (reduction_action `Normalize);
 314     connect_menu_item reduce (reduction_action `Reduce);
 315     connect_menu_item simplify (reduction_action `Simpl);
 316     connect_menu_item whd (reduction_action `Whd);
 317     menu#popup ~button:right_button ~time
 318
 319   method private button_release_cb gdk_button =
 320     if GdkEvent.Button.button gdk_button = left_button then begin
 321       let button_release_x = GdkEvent.Button.x gdk_button in
 322       let button_release_y = GdkEvent.Button.y gdk_button in
 323       if selection_changed then
 324         ()
 325       else  (* selection _not_ changed *)
 326         if near (button_press_x, button_press_y)
 327           (button_release_x, button_release_y)
 328         then
 329           let x = int_of_float button_press_x in
 330           let y = int_of_float button_press_y in
 331           (match self#get_element_at x y with
 332           | None -> ()
 333           | Some elt ->
 334               (match hrefs_of_elt elt with
 335               | Some hrefs -> self#invoke_href_callback hrefs gdk_button
 336               | None -> ignore (self#action_toggle elt)))
 337     end;
 338     false
 339
 340   method private invoke_href_callback hrefs gdk_button =
 341     let button = GdkEvent.Button.button gdk_button in
 342     if button = left_button then
 343       let time = GdkEvent.Button.time gdk_button in
 344       match href_callback with
 345       | None -> ()
 346       | Some f ->
 347           (match hrefs with
 348           | [ uri ] ->  f uri
 349           | uris ->
 350               let menu = GMenu.menu () in
 351               List.iter
 352                 (fun uri ->
 353                   let menu_item =
 354                     GMenu.menu_item ~label:uri ~packing:menu#append () in
 355                   connect_menu_item menu_item
 356                   (fun () -> try f uri with Not_found -> assert false))
 357                 uris;
 358               menu#popup ~button ~time)
 359
 360   method private choose_selection_cb gdome_elt =
 361     let set_selection elt =
 362       let misc = self#coerce#misc in
 363       self#set_selection (Some elt);
 364       misc#add_selection_target ~target:"STRING" Gdk.Atom.primary;
 365       ignore (misc#grab_selection Gdk.Atom.primary);
 366     in
 367     let rec aux elt =
 368       if (elt#getAttributeNS ~namespaceURI:helm_ns
 369             ~localName:xref_ds)#to_string <> ""
 370       then
 371         set_selection elt
 372       else
 373         try
 374           (match elt#get_parentNode with
 375           | None -> assert false
 376           | Some p -> aux (new Gdome.element_of_node p))
 377         with GdomeInit.DOMCastException _ -> ()
 378     in
 379     (match gdome_elt with
 380     | Some elt when (elt#getAttributeNS ~namespaceURI:xlink_ns
 381         ~localName:href_ds)#to_string <> "" ->
 382           set_selection elt
 383     | Some elt -> aux elt
 384     | None -> self#set_selection None);
 385     selection_changed <- true
 386
 387   method update_font_size = self#set_font_size !current_font_size
 388
 389     (** find a term by id from stored CIC infos @return either `Hyp if the id
 390      * correspond to an hypothesis or `Term (cic, hyp) if the id correspond to a
 391      * term. In the latter case hyp is either None (if the term is a subterm of
 392      * the sequent conclusion) or Some hyp_name if the term belongs to an
 393      * hypothesis *)
 394   method private get_term_by_id cic_info id =
 395     let unsh_item, ids_to_terms, ids_to_hypotheses, ids_to_father_ids, _, _ =
 396       cic_info in
 397     let rec find_father_hyp id =
 398       if Hashtbl.mem ids_to_hypotheses id
 399       then Some (name_of_hypothesis (Hashtbl.find ids_to_hypotheses id))
 400       else
 401         let father_id =
 402           try Hashtbl.find ids_to_father_ids id
 403           with Not_found -> assert false in
 404         match father_id with
 405         | Some id -> find_father_hyp id
 406         | None -> None
 407     in
 408     try
 409       let term = Hashtbl.find ids_to_terms id in
 410       let father_hyp = find_father_hyp id in
 411       SelTerm (term, father_hyp)
 412     with Not_found ->
 413       try
 414         let hyp = Hashtbl.find ids_to_hypotheses id in
 415         let _, context, _ =
 416           match unsh_item with Some seq -> seq | None -> assert false in
 417         let context' = MatitaMisc.list_tl_at hyp context in
 418         SelHyp (name_of_hypothesis hyp, context')
 419       with Not_found -> assert false
 420
 421   method private find_obj_conclusion id =
 422     match self#cic_info with
 423     | None
 424     | Some (_, _, _, _, _, None) -> assert false
 425     | Some (_, ids_to_terms, _, ids_to_father_ids, ids_to_inner_types, Some annobj) ->
 426         let id =
 427          find_root_id annobj id ids_to_father_ids ids_to_terms ids_to_inner_types
 428         in
 429          (try Hashtbl.find ids_to_terms id with Not_found -> assert false)
 430
 431   method private string_of_node ~(paste_kind:paste_kind) node =
 432     if node#hasAttributeNS ~namespaceURI:helm_ns ~localName:xref_ds
 433     then
 434       match paste_kind with
 435       | `Pattern ->
 436           let tactic_text_pattern =  self#tactic_text_pattern_of_node node in
 437           GrafiteAstPp.pp_tactic_pattern
 438             ~term_pp:(fun s -> s) ~lazy_term_pp:(fun _ -> assert false)
 439             ~map_unicode_to_tex:(Helm_registry.get_bool
 440               "matita.paste_unicode_as_tex")
 441             tactic_text_pattern
 442       | `Term -> self#tactic_text_of_node node
 443     else string_of_dom_node node
 444
 445   method private string_of_cic_sequent ~output_type cic_sequent =
 446     let script = MatitaScript.current () in
 447     let metasenv =
 448       if script#onGoingProof () then script#proofMetasenv else [] in
 449     let map_unicode_to_tex =
 450       Helm_registry.get_bool "matita.paste_unicode_as_tex" in
 451     ApplyTransformation.txt_of_cic_sequent_conclusion ~map_unicode_to_tex
 452      ~output_type text_width metasenv cic_sequent
 453
 454   method private pattern_of term context unsh_sequent =
 455     let context_len = List.length context in
 456     let _, unsh_context, conclusion = unsh_sequent in
 457     try
 458       (match
 459         List.nth unsh_context (List.length unsh_context - context_len - 1)
 460       with
 461       | None -> assert false (* can't select a restricted hypothesis *)
 462       | Some (name, Cic.Decl ty) ->
 463           ProofEngineHelpers.pattern_of ~term:ty [term]
 464       | Some (name, Cic.Def (bo, _)) ->
 465           ProofEngineHelpers.pattern_of ~term:bo [term])
 466     with Failure _ | Invalid_argument _ ->
 467       ProofEngineHelpers.pattern_of ~term:conclusion [term]
 468
 469   method private get_cic_info id =
 470     match self#cic_info with
 471     | Some ((Some unsh_sequent, _, _, _, _, _) as info) -> info, unsh_sequent
 472     | Some ((None, _, _, _, _, _) as info) ->
 473         let t = self#find_obj_conclusion id in
 474         info, (~-1, [], t) (* dummy sequent for obj *)
 475     | None -> assert false
 476
 477   method private sequent_of_id ~(paste_kind:paste_kind) id =
 478     let cic_info, unsh_sequent = self#get_cic_info id in
 479     let cic_sequent =
 480       match self#get_term_by_id cic_info id with
 481       | SelTerm (t, _father_hyp) ->
 482           let occurrences =
 483             ProofEngineHelpers.locate_in_conjecture t unsh_sequent in
 484           (match occurrences with
 485           | [ context, _t ] ->
 486               (match paste_kind with
 487               | `Term -> ~-1, context, t
 488               | `Pattern -> ~-1, [], self#pattern_of t context unsh_sequent)
 489           | _ ->
 490               HLog.error (sprintf "found %d occurrences while 1 was expected"
 491                 (List.length occurrences));
 492               assert false) (* since it uses physical equality *)
 493       | SelHyp (_name, context) -> ~-1, context, Cic.Rel 1 in
 494     cic_sequent
 495
 496   method private string_of_selection ~(paste_kind:paste_kind) =
 497     match self#get_selections with
 498     | [] -> None
 499     | node :: _ -> Some (self#string_of_node ~paste_kind node)
 500
 501   method has_selection = self#get_selections <> []
 502
 503     (** @return an associative list format -> string with all possible selection
 504      * formats. Rationale: in order to convert the selection to TERM or PATTERN
 505      * format we need the sequent, the metasenv, ... keeping all of them in a
 506      * closure would be more expensive than keeping their already converted
 507      * forms *)
 508   method strings_of_selection =
 509     try
 510       let misc = self#coerce#misc in
 511       List.iter
 512         (fun target -> misc#add_selection_target ~target Gdk.Atom.clipboard)
 513         [ "TERM"; "PATTERN"; "STRING" ];
 514       ignore (misc#grab_selection Gdk.Atom.clipboard);
 515       List.map
 516         (fun paste_kind ->
 517           paste_kind, HExtlib.unopt (self#string_of_selection ~paste_kind))
 518         [ `Term; `Pattern ]
 519     with Failure _ -> failwith "no selection"
 520
 521 end
 522
 523 let clickableMathView ?hadjustment ?vadjustment ?font_size ?log_verbosity =
 524   GtkBase.Widget.size_params
 525     ~cont:(OgtkMathViewProps.pack_return (fun p ->
 526       OgtkMathViewProps.set_params
 527         (new clickableMathView (GtkMathViewProps.MathView_GMetaDOM.create p))
 528         ~font_size:None ~log_verbosity:None))
 529     []
 530
 531 class cicMathView obj =
 532 object (self)
 533   inherit clickableMathView obj
 534
 535   val mutable current_mathml = None
 536
 537   method load_sequent metasenv metano =
 538     let sequent = CicUtil.lookup_meta metano metasenv in
 539     let (mathml, unsh_sequent,
 540       (_, (ids_to_terms, ids_to_father_ids, ids_to_hypotheses,_ )))
 541     =
 542       ApplyTransformation.mml_of_cic_sequent metasenv sequent
 543     in
 544     self#set_cic_info
 545       (Some (Some unsh_sequent,
 546         ids_to_terms, ids_to_hypotheses, ids_to_father_ids,
 547         Hashtbl.create 1, None));
 548     if BuildTimeConf.debug then begin
 549       let name =
 550        "/tmp/sequent_viewer_" ^ string_of_int (Unix.getuid ()) ^ ".xml" in
 551       HLog.debug ("load_sequent: dumping MathML to ./" ^ name);
 552       ignore (domImpl#saveDocumentToFile ~name ~doc:mathml ())
 553     end;
 554     self#load_root ~root:mathml#get_documentElement
 555
 556   method load_object obj =
 557     let use_diff = false in (* ZACK TODO use XmlDiff when re-rendering? *)
 558     let (mathml,
 559       (annobj, (ids_to_terms, ids_to_father_ids, _, ids_to_hypotheses, _, ids_to_inner_types)))
 560     =
 561       ApplyTransformation.mml_of_cic_object obj
 562     in
 563     self#set_cic_info
 564       (Some (None, ids_to_terms, ids_to_hypotheses, ids_to_father_ids, ids_to_inner_types, Some annobj));
 565     (match current_mathml with
 566     | Some current_mathml when use_diff ->
 567         self#freeze;
 568         XmlDiff.update_dom ~from:current_mathml mathml;
 569         self#thaw
 570     |  _ ->
 571         if BuildTimeConf.debug then begin
 572           let name =
 573            "/tmp/cic_browser_" ^ string_of_int (Unix.getuid ()) ^ ".xml" in
 574           HLog.debug ("cic_browser: dumping MathML to ./" ^ name);
 575           ignore (domImpl#saveDocumentToFile ~name ~doc:mathml ())
 576         end;
 577         self#load_root ~root:mathml#get_documentElement;
 578         current_mathml <- Some mathml);
 579 end
 580
 581 let tab_label meta_markup =
 582   let rec aux =
 583     function
 584     | `Closed m -> sprintf "<s>%s</s>" (aux m)
 585     | `Current m -> sprintf "<b>%s</b>" (aux m)
 586     | `Shift (pos, m) -> sprintf "|<sub>%d</sub>: %s" pos (aux m)
 587     | `Meta n -> sprintf "?%d" n
 588   in
 589   let markup = aux meta_markup in
 590   (GMisc.label ~markup ~show:true ())#coerce
 591
 592 let goal_of_switch = function Stack.Open g | Stack.Closed g -> g
 593
 594 class sequentsViewer ~(notebook:GPack.notebook) ~(cicMathView:cicMathView) () =
 595   object (self)
 596     inherit scriptAccessor
 597
 598     method cicMathView = cicMathView  (** clickableMathView accessor *)
 599
 600     val mutable pages = 0
 601     val mutable switch_page_callback = None
 602     val mutable page2goal = []  (* associative list: page no -> goal no *)
 603     val mutable goal2page = []  (* the other way round *)
 604     val mutable goal2win = []   (* associative list: goal no -> scrolled win *)
 605     val mutable _metasenv = []
 606     val mutable scrolledWin: GBin.scrolled_window option = None
 607       (* scrolled window to which the sequentViewer is currently attached *)
 608     val logo = (GMisc.image
 609       ~file:(MatitaMisc.image_path "matita_medium.png") ()
 610       :> GObj.widget)
 611
 612     val logo_with_qed = (GMisc.image
 613       ~file:(MatitaMisc.image_path "matita_small.png") ()
 614       :> GObj.widget)
 615
 616     method load_logo =
 617      notebook#set_show_tabs false;
 618      notebook#append_page logo
 619
 620     method load_logo_with_qed =
 621      notebook#set_show_tabs false;
 622      notebook#append_page logo_with_qed
 623
 624     method reset =
 625       cicMathView#remove_selections;
 626       (match scrolledWin with
 627       | Some w ->
 628           (* removing page from the notebook will destroy all contained widget,
 629           * we do not want the cicMathView to be destroyed as well *)
 630           w#remove cicMathView#coerce;
 631           scrolledWin <- None
 632       | None -> ());
 633       (match switch_page_callback with
 634       | Some id ->
 635           GtkSignal.disconnect notebook#as_widget id;
 636           switch_page_callback <- None
 637       | None -> ());
 638       for i = 0 to pages do notebook#remove_page 0 done;
 639       notebook#set_show_tabs true;
 640       pages <- 0;
 641       page2goal <- [];
 642       goal2page <- [];
 643       goal2win <- [];
 644       _metasenv <- [];
 645       self#script#setGoal None
 646
 647     method load_sequents
 648       { proof = (_,metasenv,_subst,_,_, _) as proof; stack = stack }
 649     =
 650       _metasenv <- metasenv;
 651       pages <- 0;
 652       let win goal_switch =
 653         let w =
 654           GBin.scrolled_window ~hpolicy:`AUTOMATIC ~vpolicy:`ALWAYS
 655             ~shadow_type:`IN ~show:true ()
 656         in
 657         let reparent () =
 658           scrolledWin <- Some w;
 659           match cicMathView#misc#parent with
 660           | None -> w#add cicMathView#coerce
 661           | Some parent ->
 662              let parent =
 663               match cicMathView#misc#parent with
 664                  None -> assert false
 665                | Some p -> GContainer.cast_container p
 666              in
 667               parent#remove cicMathView#coerce;
 668               w#add cicMathView#coerce
 669         in
 670         goal2win <- (goal_switch, reparent) :: goal2win;
 671         w#coerce
 672       in
 673       assert (
 674         let stack_goals = Stack.open_goals stack in
 675         let proof_goals = ProofEngineTypes.goals_of_proof proof in
 676         if
 677           HExtlib.list_uniq (List.sort Pervasives.compare stack_goals)
 678           <> List.sort Pervasives.compare proof_goals
 679         then begin
 680           prerr_endline ("STACK GOALS = " ^ String.concat " " (List.map string_of_int stack_goals));
 681           prerr_endline ("PROOF GOALS = " ^ String.concat " " (List.map string_of_int proof_goals));
 682           false
 683         end
 684         else true
 685       );
 686       let render_switch =
 687         function Stack.Open i ->`Meta i | Stack.Closed i ->`Closed (`Meta i)
 688       in
 689       let page = ref 0 in
 690       let added_goals = ref [] in
 691         (* goals can be duplicated on the tack due to focus, but we should avoid
 692          * multiple labels in the user interface *)
 693       let add_tab markup goal_switch =
 694         let goal = Stack.goal_of_switch goal_switch in
 695         if not (List.mem goal !added_goals) then begin
 696           notebook#append_page ~tab_label:(tab_label markup) (win goal_switch);
 697           page2goal <- (!page, goal_switch) :: page2goal;
 698           goal2page <- (goal_switch, !page) :: goal2page;
 699           incr page;
 700           pages <- pages + 1;
 701           added_goals := goal :: !added_goals
 702         end
 703       in
 704       let add_switch _ _ (_, sw) = add_tab (render_switch sw) sw in
 705       Stack.iter  (** populate notebook with tabs *)
 706         ~env:(fun depth tag (pos, sw) ->
 707           let markup =
 708             match depth, pos with
 709             | 0, 0 -> `Current (render_switch sw)
 710             | 0, _ -> `Shift (pos, `Current (render_switch sw))
 711             | 1, pos when Stack.head_tag stack = `BranchTag ->
 712                 `Shift (pos, render_switch sw)
 713             | _ -> render_switch sw
 714           in
 715           add_tab markup sw)
 716         ~cont:add_switch ~todo:add_switch
 717         stack;
 718       switch_page_callback <-
 719         Some (notebook#connect#switch_page ~callback:(fun page ->
 720           let goal_switch =
 721             try List.assoc page page2goal with Not_found -> assert false
 722           in
 723           self#script#setGoal (Some (goal_of_switch goal_switch));
 724           self#render_page ~page ~goal_switch))
 725
 726     method private render_page ~page ~goal_switch =
 727       (match goal_switch with
 728       | Stack.Open goal -> cicMathView#load_sequent _metasenv goal
 729       | Stack.Closed goal ->
 730           let doc = Lazy.force closed_goal_mathml in
 731           cicMathView#load_root ~root:doc#get_documentElement);
 732       (try
 733         cicMathView#set_selection None;
 734         List.assoc goal_switch goal2win ()
 735       with Not_found -> assert false)
 736
 737     method goto_sequent goal =
 738       let goal_switch, page =
 739         try
 740           List.find
 741             (function Stack.Open g, _ | Stack.Closed g, _ -> g = goal)
 742             goal2page
 743         with Not_found -> assert false
 744       in
 745       notebook#goto_page page;
 746       self#render_page page goal_switch
 747
 748   end
 749
 750  (** constructors *)
 751
 752 type 'widget constructor =
 753   ?hadjustment:GData.adjustment ->
 754   ?vadjustment:GData.adjustment ->
 755   ?font_size:int ->
 756   ?log_verbosity:int ->
 757   ?width:int ->
 758   ?height:int ->
 759   ?packing:(GObj.widget -> unit) ->
 760   ?show:bool ->
 761   unit ->
 762     'widget
 763
 764 let cicMathView ?hadjustment ?vadjustment ?font_size ?log_verbosity =
 765   GtkBase.Widget.size_params
 766     ~cont:(OgtkMathViewProps.pack_return (fun p ->
 767       OgtkMathViewProps.set_params
 768         (new cicMathView (GtkMathViewProps.MathView_GMetaDOM.create p))
 769         ~font_size ~log_verbosity))
 770     []
 771
 772 let blank_uri = BuildTimeConf.blank_uri
 773 let current_proof_uri = BuildTimeConf.current_proof_uri
 774
 775 type term_source =
 776   [ `Ast of CicNotationPt.term
 777   | `Cic of Cic.term * Cic.metasenv
 778   | `String of string
 779   ]
 780
 781 class cicBrowser_impl ~(history:MatitaTypes.mathViewer_entry MatitaMisc.history)
 782   ()
 783 =
 784   let whelp_RE = Pcre.regexp "^\\s*whelp" in
 785   let uri_RE =
 786     Pcre.regexp
 787       "^cic:/([^/]+/)*[^/]+\\.(con|ind|var)(#xpointer\\(\\d+(/\\d+)+\\))?$"
 788   in
 789   let dir_RE = Pcre.regexp "^cic:((/([^/]+/)*[^/]+(/)?)|/|)$" in
 790   let metadata_RE = Pcre.regexp "^metadata:/(deps)/(forward|backward)/(.*)$" in
 791   let whelp_query_RE = Pcre.regexp
 792     "^\\s*whelp\\s+([^\\s]+)\\s+(\"|\\()(.*)(\\)|\")$"
 793   in
 794   let is_metadata txt = Pcre.pmatch ~rex:metadata_RE txt in
 795   let is_whelp txt = Pcre.pmatch ~rex:whelp_RE txt in
 796   let is_uri txt = Pcre.pmatch ~rex:uri_RE txt in
 797   let is_dir txt = Pcre.pmatch ~rex:dir_RE txt in
 798   let gui = get_gui () in
 799   let (win: MatitaGuiTypes.browserWin) = gui#newBrowserWin () in
 800   let gviz = LablGraphviz.graphviz ~packing:win#graphScrolledWin#add () in
 801   let queries = ["Locate";"Hint";"Match";"Elim";"Instance"] in
 802   let combo,_ = GEdit.combo_box_text ~strings:queries () in
 803   let activate_combo_query input q =
 804     let q' = String.lowercase q in
 805     let rec aux i = function
 806       | [] -> failwith ("Whelp query '" ^ q ^ "' not found")
 807       | h::_ when String.lowercase h = q' -> i
 808       | _::tl -> aux (i+1) tl
 809     in
 810     win#queryInputText#set_text input;
 811     combo#set_active (aux 0 queries);
 812   in
 813   let set_whelp_query txt =
 814     let query, arg =
 815       try
 816         let q = Pcre.extract ~rex:whelp_query_RE txt in
 817         q.(1), q.(3)
 818       with Not_found -> failwith "Malformed Whelp query"
 819     in
 820     activate_combo_query arg query;
 821   in
 822   let toplevel = win#toplevel in
 823   let mathView = cicMathView ~packing:win#scrolledBrowser#add () in
 824   let fail message =
 825     MatitaGtkMisc.report_error ~title:"Cic browser" ~message
 826       ~parent:toplevel ()
 827   in
 828   let tags =
 829     [ "dir", GdkPixbuf.from_file (MatitaMisc.image_path "matita-folder.png");
 830       "obj", GdkPixbuf.from_file (MatitaMisc.image_path "matita-object.png") ]
 831   in
 832   let b = (not (Helm_registry.get_bool "matita.debug")) in
 833   let handle_error f =
 834     try
 835       f ()
 836     with exn ->
 837       if b then
 838         fail (snd (MatitaExcPp.to_string exn))
 839       else raise exn
 840   in
 841   let handle_error' f = (fun () -> handle_error (fun () -> f ())) in
 842   let load_easter_egg = lazy (
 843     win#browserImage#set_file (MatitaMisc.image_path "meegg.png"))
 844   in
 845   let load_coerchgraph tred () =
 846       let str = CoercGraph.generate_dot_file () in
 847       let filename, oc = Filename.open_temp_file "matita" ".dot" in
 848       output_string oc str;
 849       close_out oc;
 850       if tred then
 851         gviz#load_graph_from_file ~gviz_cmd:"tred|dot" filename
 852       else
 853         gviz#load_graph_from_file filename;
 854       HExtlib.safe_remove filename
 855   in
 856   object (self)
 857     inherit scriptAccessor
 858
 859     (* Whelp bar queries *)
 860
 861     val mutable gviz_graph = MetadataDeps.DepGraph.dummy
 862     val mutable gviz_uri = UriManager.uri_of_string "cic:/dummy.con";
 863
 864     val dep_contextual_menu = GMenu.menu ()
 865
 866     initializer
 867       activate_combo_query "" "locate";
 868       win#whelpBarComboVbox#add combo#coerce;
 869       let start_query () =
 870        let query =
 871          try
 872            String.lowercase (List.nth queries combo#active)
 873          with Not_found -> assert false in
 874        let input = win#queryInputText#text in
 875        let statement =
 876          if query = "locate" then
 877              "whelp " ^ query ^ " \"" ^ input ^ "\"."
 878            else
 879              "whelp " ^ query ^ " (" ^ input ^ ")."
 880        in
 881         (MatitaScript.current ())#advance ~statement ()
 882       in
 883       ignore(win#queryInputText#connect#activate ~callback:start_query);
 884       ignore(combo#connect#changed ~callback:start_query);
 885       win#whelpBarImage#set_file (MatitaMisc.image_path "whelp.png");
 886       win#mathOrListNotebook#set_show_tabs false;
 887       win#browserForwardButton#misc#set_sensitive false;
 888       win#browserBackButton#misc#set_sensitive false;
 889       ignore (win#browserUri#entry#connect#activate (handle_error' (fun () ->
 890         self#loadInput win#browserUri#entry#text)));
 891       ignore (win#browserHomeButton#connect#clicked (handle_error' (fun () ->
 892         self#load (`About `Current_proof))));
 893       ignore (win#browserRefreshButton#connect#clicked
 894         (handle_error' (self#refresh ~force:true)));
 895       ignore (win#browserBackButton#connect#clicked (handle_error' self#back));
 896       ignore (win#browserForwardButton#connect#clicked
 897         (handle_error' self#forward));
 898       ignore (win#toplevel#event#connect#delete (fun _ ->
 899         let my_id = Oo.id self in
 900         cicBrowsers := List.filter (fun b -> Oo.id b <> my_id) !cicBrowsers;
 901         if !cicBrowsers = [] &&
 902           Helm_registry.get "matita.mode" = "cicbrowser"
 903         then
 904           GMain.quit ();
 905         false));
 906       ignore(win#whelpResultTreeview#connect#row_activated
 907         ~callback:(fun _ _ ->
 908           handle_error (fun () -> self#loadInput (self#_getSelectedUri ()))));
 909       mathView#set_href_callback (Some (fun uri ->
 910         handle_error (fun () ->
 911           self#load (`Uri (UriManager.uri_of_string uri)))));
 912       gviz#connect_href (fun button_ev attrs ->
 913         let time = GdkEvent.Button.time button_ev in
 914         let uri = List.assoc "href" attrs in
 915         gviz_uri <- UriManager.uri_of_string uri;
 916         match GdkEvent.Button.button button_ev with
 917         | button when button = left_button -> self#load (`Uri gviz_uri)
 918         | button when button = right_button ->
 919             dep_contextual_menu#popup ~button ~time
 920         | _ -> ());
 921       connect_menu_item win#depGraphMenuItem (fun () ->
 922         match self#currentCicUri with
 923         | Some uri -> self#load (`Metadata (`Deps (`Fwd, uri)))
 924         | None -> ());
 925       connect_menu_item win#invDepGraphMenuItem (fun () ->
 926         match self#currentCicUri with
 927         | Some uri -> self#load (`Metadata (`Deps (`Back, uri)))
 928         | None -> ());
 929       connect_menu_item win#hBugsTutorsMenuItem (fun () ->
 930         self#load (`HBugs `Tutors));
 931       connect_menu_item win#browserUrlMenuItem (fun () ->
 932         win#browserUri#entry#misc#grab_focus ());
 933
 934       (* fill dep graph contextual menu *)
 935       let go_menu_item =
 936         GMenu.image_menu_item ~label:"Browse it"
 937           ~packing:dep_contextual_menu#append () in
 938       let expand_menu_item =
 939         GMenu.image_menu_item ~label:"Expand"
 940           ~packing:dep_contextual_menu#append () in
 941       let collapse_menu_item =
 942         GMenu.image_menu_item ~label:"Collapse"
 943           ~packing:dep_contextual_menu#append () in
 944       dep_contextual_menu#append (go_menu_item :> GMenu.menu_item);
 945       dep_contextual_menu#append (expand_menu_item :> GMenu.menu_item);
 946       dep_contextual_menu#append (collapse_menu_item :> GMenu.menu_item);
 947       connect_menu_item go_menu_item (fun () -> self#load (`Uri gviz_uri));
 948       connect_menu_item expand_menu_item (fun () ->
 949         MetadataDeps.DepGraph.expand gviz_uri gviz_graph;
 950         self#redraw_gviz ~center_on:gviz_uri ());
 951       connect_menu_item collapse_menu_item (fun () ->
 952         MetadataDeps.DepGraph.collapse gviz_uri gviz_graph;
 953         self#redraw_gviz ~center_on:gviz_uri ());
 954
 955       self#_load (`About `Blank);
 956       toplevel#show ()
 957
 958     val mutable current_entry = `About `Blank
 959
 960       (** @return None if no object uri can be built from the current entry *)
 961     method private currentCicUri =
 962       match current_entry with
 963       | `Uri uri
 964       | `Metadata (`Deps (_, uri)) -> Some uri
 965       | _ -> None
 966
 967     val model =
 968       new MatitaGtkMisc.taggedStringListModel tags win#whelpResultTreeview
 969
 970     val mutable lastDir = ""  (* last loaded "directory" *)
 971
 972     method mathView = (mathView :> MatitaGuiTypes.clickableMathView)
 973
 974     method private _getSelectedUri () =
 975       match model#easy_selection () with
 976       | [sel] when is_uri sel -> sel  (* absolute URI selected *)
 977 (*       | [sel] -> win#browserUri#entry#text ^ sel  |+ relative URI selected +| *)
 978       | [sel] -> lastDir ^ sel
 979       | _ -> assert false
 980
 981     (** history RATIONALE
 982      *
 983      * All operations about history are done using _historyFoo.
 984      * Only toplevel functions (ATM load and loadInput) call _historyAdd.
 985      *)
 986
 987     method private _historyAdd item =
 988       history#add item;
 989       win#browserBackButton#misc#set_sensitive true;
 990       win#browserForwardButton#misc#set_sensitive false
 991
 992     method private _historyPrev () =
 993       let item = history#previous in
 994       if history#is_begin then win#browserBackButton#misc#set_sensitive false;
 995       win#browserForwardButton#misc#set_sensitive true;
 996       item
 997
 998     method private _historyNext () =
 999       let item = history#next in
1000       if history#is_end then win#browserForwardButton#misc#set_sensitive false;
1001       win#browserBackButton#misc#set_sensitive true;
1002       item
1003
1004     (** notebook RATIONALE
1005      *
1006      * Use only these functions to switch between the tabs
1007      *)
1008     method private _showMath = win#mathOrListNotebook#goto_page  0
1009     method private _showList = win#mathOrListNotebook#goto_page  1
1010     method private _showGviz = win#mathOrListNotebook#goto_page  3
1011     method private _showHBugs = win#mathOrListNotebook#goto_page 4
1012
1013     method private back () =
1014       try
1015         self#_load (self#_historyPrev ())
1016       with MatitaMisc.History_failure -> ()
1017
1018     method private forward () =
1019       try
1020         self#_load (self#_historyNext ())
1021       with MatitaMisc.History_failure -> ()
1022
1023       (* loads a uri which can be a cic uri or an about:* uri
1024       * @param uri string *)
1025     method private _load ?(force=false) entry =
1026       handle_error (fun () ->
1027        if entry <> current_entry || entry = `About `Current_proof || entry =
1028          `About `Coercions || entry = `About `CoercionsFull || force then
1029         begin
1030           (match entry with
1031           | `About `Current_proof -> self#home ()
1032           | `About `Blank -> self#blank ()
1033           | `About `Us -> self#egg ()
1034           | `About `CoercionsFull -> self#coerchgraph false ()
1035           | `About `Coercions -> self#coerchgraph true ()
1036           | `Check term -> self#_loadCheck term
1037           | `Cic (term, metasenv) -> self#_loadTermCic term metasenv
1038           | `Development d -> self#_showDevelDeps d
1039           | `Dir dir -> self#_loadDir dir
1040           | `HBugs `Tutors -> self#_loadHBugsTutors
1041           | `Metadata (`Deps ((`Fwd | `Back) as dir, uri)) ->
1042               self#dependencies dir uri ()
1043           | `Uri uri -> self#_loadUriManagerUri uri
1044           | `Whelp (query, results) ->
1045               set_whelp_query query;
1046               self#_loadList (List.map (fun r -> "obj",
1047                 UriManager.string_of_uri r) results));
1048           self#setEntry entry
1049         end)
1050
1051     method private blank () =
1052       self#_showMath;
1053       mathView#load_root (Lazy.force empty_mathml)#get_documentElement
1054
1055     method private _loadCheck term =
1056       failwith "not implemented _loadCheck";
1057 (*       self#_showMath *)
1058
1059     method private egg () =
1060       win#mathOrListNotebook#goto_page 2;
1061       Lazy.force load_easter_egg
1062
1063     method private redraw_gviz ?center_on () =
1064       let tmpfile, oc = Filename.open_temp_file "matita" ".dot" in
1065       let fmt = Format.formatter_of_out_channel oc in
1066       MetadataDeps.DepGraph.render fmt gviz_graph;
1067       close_out oc;
1068       gviz#load_graph_from_file ~gviz_cmd:"tred | dot" tmpfile;
1069       (match center_on with
1070       | None -> ()
1071       | Some uri -> gviz#center_on_href (UriManager.string_of_uri uri));
1072       HExtlib.safe_remove tmpfile
1073
1074     method private dependencies direction uri () =
1075       let dbd = LibraryDb.instance () in
1076       let graph =
1077         match direction with
1078         | `Fwd -> MetadataDeps.DepGraph.direct_deps ~dbd uri
1079         | `Back -> MetadataDeps.DepGraph.inverse_deps ~dbd uri in
1080       gviz_graph <- graph;  (** XXX check this for memory consuption *)
1081       self#redraw_gviz ~center_on:uri ();
1082       self#_showGviz
1083
1084     method private coerchgraph tred () =
1085       load_coerchgraph tred ();
1086       self#_showGviz
1087
1088     method private home () =
1089       self#_showMath;
1090       match self#script#grafite_status.proof_status with
1091       | Proof  (uri, metasenv, _subst, bo, ty, attrs) ->
1092           let name = UriManager.name_of_uri (HExtlib.unopt uri) in
1093           let obj = Cic.CurrentProof (name, metasenv, bo, ty, [], attrs) in
1094           self#_loadObj obj
1095       | Incomplete_proof { proof = (uri, metasenv, _subst, bo, ty, attrs) } ->
1096           let name = UriManager.name_of_uri (HExtlib.unopt uri) in
1097           let obj = Cic.CurrentProof (name, metasenv, bo, ty, [], attrs) in
1098           self#_loadObj obj
1099       | _ -> self#blank ()
1100
1101       (** loads a cic uri from the environment
1102       * @param uri UriManager.uri *)
1103     method private _loadUriManagerUri uri =
1104       let uri = UriManager.strip_xpointer uri in
1105       let (obj, _) = CicEnvironment.get_obj CicUniv.empty_ugraph uri in
1106       self#_loadObj obj
1107
1108     method private _loadDir dir =
1109       let content = Http_getter.ls ~local:false dir in
1110       let l =
1111         List.fast_sort
1112           Pervasives.compare
1113           (List.map
1114             (function
1115               | Http_getter_types.Ls_section s -> "dir", s
1116               | Http_getter_types.Ls_object o -> "obj", o.Http_getter_types.uri)
1117             content)
1118       in
1119       lastDir <- dir;
1120       self#_loadList l
1121
1122     method private _loadHBugsTutors =
1123       self#_showHBugs
1124
1125     method private setEntry entry =
1126       win#browserUri#entry#set_text (MatitaTypes.string_of_entry entry);
1127       current_entry <- entry
1128
1129     method private _showDevelDeps d =
1130       match MatitamakeLib.development_for_name d with
1131       | None -> ()
1132       | Some devel ->
1133           (match MatitamakeLib.dot_for_development devel with
1134           | None -> ()
1135           | Some fname ->
1136               gviz#load_graph_from_file ~gviz_cmd:"tred | dot" fname;
1137               self#_showGviz)
1138
1139     method private _loadObj obj =
1140       (* showMath must be done _before_ loading the document, since if the
1141        * widget is not mapped (hidden by the notebook) the document is not
1142        * rendered *)
1143       self#_showMath;
1144       mathView#load_object obj
1145
1146     method private _loadTermCic term metasenv =
1147       let context = self#script#proofContext in
1148       let dummyno = CicMkImplicit.new_meta metasenv [] in
1149       let sequent = (dummyno, context, term) in
1150       mathView#load_sequent (sequent :: metasenv) dummyno;
1151       self#_showMath
1152
1153     method private _loadList l =
1154       model#list_store#clear ();
1155       List.iter (fun (tag, s) -> model#easy_append ~tag s) l;
1156       self#_showList
1157
1158     (** { public methods, all must call _load!! } *)
1159
1160     method load entry =
1161       handle_error (fun () -> self#_load entry; self#_historyAdd entry)
1162
1163     (**  this is what the browser does when you enter a string an hit enter *)
1164     method loadInput txt =
1165       let parse_metadata s =
1166         let subs = Pcre.extract ~rex:metadata_RE s in
1167         let uri = UriManager.uri_of_string ("cic:/" ^ subs.(3)) in
1168         match subs.(1), subs.(2) with
1169         | "deps", "forward" -> `Deps (`Fwd, uri)
1170         | "deps", "backward" -> `Deps (`Back, uri)
1171         | _ -> assert false
1172       in
1173       let txt = HExtlib.trim_blanks txt in
1174       (* (* ZACK: what the heck? *)
1175       let fix_uri txt =
1176         UriManager.string_of_uri
1177           (UriManager.strip_xpointer (UriManager.uri_of_string txt))
1178       in
1179       *)
1180       if is_whelp txt then begin
1181         set_whelp_query txt;
1182         (MatitaScript.current ())#advance ~statement:(txt ^ ".") ()
1183       end else begin
1184         let entry =
1185           match txt with
1186           | txt when is_uri txt ->
1187               `Uri (UriManager.uri_of_string ((*fix_uri*) txt))
1188           | txt when is_dir txt -> `Dir (MatitaMisc.normalize_dir txt)
1189           | txt when is_metadata txt -> `Metadata (parse_metadata txt)
1190           | "hbugs:/tutors/" -> `HBugs `Tutors
1191           | txt ->
1192              (try
1193                MatitaTypes.entry_of_string txt
1194               with Invalid_argument _ ->
1195                raise
1196                 (GrafiteTypes.Command_error(sprintf "unsupported uri: %s" txt)))
1197         in
1198         self#_load entry;
1199         self#_historyAdd entry
1200       end
1201
1202       (** {2 methods accessing underlying GtkMathView} *)
1203
1204     method updateFontSize = mathView#set_font_size !current_font_size
1205
1206       (** {2 methods used by constructor only} *)
1207
1208     method win = win
1209     method history = history
1210     method currentEntry = current_entry
1211     method refresh ~force () = self#_load ~force current_entry
1212
1213   end
1214
1215 let sequentsViewer ~(notebook:GPack.notebook) ~(cicMathView:cicMathView) ():
1216   MatitaGuiTypes.sequentsViewer
1217 =
1218   new sequentsViewer ~notebook ~cicMathView ()
1219
1220 let cicBrowser () =
1221   let size = BuildTimeConf.browser_history_size in
1222   let rec aux history =
1223     let browser = new cicBrowser_impl ~history () in
1224     let win = browser#win in
1225     ignore (win#browserNewButton#connect#clicked (fun () ->
1226       let history =
1227         new MatitaMisc.browser_history ~memento:history#save size
1228           (`About `Blank)
1229       in
1230       let newBrowser = aux history in
1231       newBrowser#load browser#currentEntry));
1232 (*
1233       (* attempt (failed) to close windows on CTRL-W ... *)
1234     MatitaGtkMisc.connect_key win#browserWinEventBox#event ~modifiers:[`CONTROL]
1235       GdkKeysyms._W (fun () -> win#toplevel#destroy ());
1236 *)
1237     cicBrowsers := browser :: !cicBrowsers;
1238     (browser :> MatitaGuiTypes.cicBrowser)
1239   in
1240   let history = new MatitaMisc.browser_history size (`About `Blank) in
1241   aux history
1242
1243 let default_cicMathView () = cicMathView ~show:true ()
1244 let cicMathView_instance = MatitaMisc.singleton default_cicMathView
1245
1246 let default_sequentsViewer () =
1247   let gui = get_gui () in
1248   let cicMathView = cicMathView_instance () in
1249   sequentsViewer ~notebook:gui#main#sequentsNotebook ~cicMathView ()
1250 let sequentsViewer_instance = MatitaMisc.singleton default_sequentsViewer
1251
1252 let mathViewer () =
1253   object(self)
1254     method private get_browser reuse =
1255       if reuse then
1256         (match !cicBrowsers with
1257         | [] -> cicBrowser ()
1258         | b :: _ -> (b :> MatitaGuiTypes.cicBrowser))
1259       else
1260         (cicBrowser ())
1261
1262     method show_entry ?(reuse=false) t = (self#get_browser reuse)#load t
1263
1264     method show_uri_list ?(reuse=false) ~entry l =
1265       (self#get_browser reuse)#load entry
1266   end
1267
1268 let refresh_all_browsers () =
1269   List.iter (fun b -> b#refresh ~force:false ()) !cicBrowsers
1270
1271 let update_font_sizes () =
1272   List.iter (fun b -> b#updateFontSize) !cicBrowsers;
1273   (cicMathView_instance ())#update_font_size
1274
1275 let get_math_views () =
1276   ((cicMathView_instance ()) :> MatitaGuiTypes.clickableMathView)
1277   :: (List.map (fun b -> b#mathView) !cicBrowsers)
1278
1279 let find_selection_owner () =
1280   let rec aux =
1281     function
1282     | [] -> raise Not_found
1283     | mv :: tl ->
1284         (match mv#get_selections with
1285         | [] -> aux tl
1286         | sel :: _ -> mv)
1287   in
1288   aux (get_math_views ())
1289
1290 let has_selection () =
1291   try ignore (find_selection_owner ()); true
1292   with Not_found -> false
1293
1294 let math_view_clipboard = ref None (* associative list target -> string *)
1295 let has_clipboard () = !math_view_clipboard <> None
1296 let empty_clipboard () = math_view_clipboard := None
1297
1298 let copy_selection () =
1299   try
1300     math_view_clipboard :=
1301       Some ((find_selection_owner ())#strings_of_selection)
1302   with Not_found -> failwith "no selection"
1303
1304 let paste_clipboard paste_kind =
1305   match !math_view_clipboard with
1306   | None -> failwith "empty clipboard"
1307   | Some cb ->
1308       (try List.assoc paste_kind cb with Not_found -> assert false)
1309