matitaB/components/content_pres/termContentPres.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = NotationPt
  31 module Env = NotationEnv
  32
  33 let debug = false
  34 let debug_print s = if debug then prerr_endline (Lazy.force s) else ()
  35
  36 type pattern_id = int
  37 type pretty_printer_id = pattern_id
  38
  39 let resolve_binder = function
  40   | `Lambda -> "\\lambda"
  41   | `Pi -> "\\Pi"
  42   | `Forall -> "\\forall"
  43   | `Exists -> "\\exists"
  44
  45 let add_level_info prec t = Ast.AttributedTerm (`Level prec, t)
  46
  47 let rec top_pos t = add_level_info ~-1 t
  48
  49 let rec remove_level_info =
  50   function
  51   | Ast.AttributedTerm (`Level _, t) -> remove_level_info t
  52   | Ast.AttributedTerm (a, t) -> Ast.AttributedTerm (a, remove_level_info t)
  53   | t -> t
  54
  55 let add_xml_attrs attrs t = t
  56 (*  if attrs = [] then t else Ast.AttributedTerm (`XmlAttrs attrs, t) *)
  57
  58 let add_keyword_attrs t = t
  59 (*  add_xml_attrs (RenderingAttrs.keyword_attributes `MathML) *)
  60
  61 let box kind spacing indent content =
  62   Ast.Layout (Ast.Box ((kind, spacing, indent), content))
  63
  64 let hbox = box Ast.H
  65 let vbox = box Ast.V
  66 let hvbox = box Ast.HV
  67 let hovbox = box Ast.HOV
  68 let break = Ast.Layout Ast.Break
  69 let space = Ast.Literal (`Symbol (" ", (None,None)))
  70 let builtin_symbol s = Ast.Literal (`Symbol (s,(None,None)))
  71 let keyword k = add_keyword_attrs (Ast.Literal (`Keyword (k,(None,None))))
  72
  73 let number s =
  74   add_xml_attrs (* (RenderingAttrs.number_attributes `MathML) *) ()
  75     (Ast.Literal (`Number (s,(None,None))))
  76
  77 let ident i =
  78   add_xml_attrs (* (RenderingAttrs.ident_attributes `MathML) *) ()
  79     (Ast.Ident (i,`Ambiguous))
  80
  81 let ident_w_href href i =
  82   match href with
  83   | None -> ident i
  84   | Some href ->
  85       let href = NReference.string_of_reference href in
  86       add_xml_attrs [Some "xlink", "href", href] (ident i)
  87
  88 let binder_symbol s =
  89   add_xml_attrs (* (RenderingAttrs.builtin_symbol_attributes `MathML) *) ()
  90     (builtin_symbol s)
  91
  92 let xml_of_sort x =
  93   let to_string x = Ast.Ident (x, `Ambiguous) in
  94   let identify x =
  95     add_xml_attrs (* (RenderingAttrs.keyword_attributes `MathML) *) () (to_string x)
  96   in
  97   let lvl t = Ast.AttributedTerm (`Level 90,t) in
  98   match x with
  99   | `Prop -> identify "Prop"
 100   | `Set -> identify "Set"
 101   | `CProp _ -> identify "CProp"
 102   | `Type _ -> identify "Type"
 103   | `NType s -> lvl(Ast.Layout (Ast.Sub (identify "Type",to_string s)))
 104   | `NCProp s -> lvl(Ast.Layout (Ast.Sub (identify "CProp",to_string s)))
 105 ;;
 106
 107
 108 let map_space f l =
 109  HExtlib.list_concat
 110   ~sep:[space] (List.map (fun x -> [f x]) l)
 111 ;;
 112
 113 let pp_ast0 status t k =
 114   let rec aux =
 115     function
 116     | Ast.Appl ts ->
 117         let rec aux_args level =
 118           function
 119           | [] -> []
 120           | [ last ] ->
 121               [ Ast.AttributedTerm (`Level level,k last) ]
 122           | hd :: tl ->
 123               (Ast.AttributedTerm (`Level level, k hd)) :: aux_args 71 tl
 124         in
 125         add_level_info Ast.apply_prec
 126           (hovbox true true (NotationUtil.dress break (aux_args 70 ts)))
 127     | Ast.Binder (binder_kind, (id, ty), body) ->
 128         add_level_info Ast.binder_prec
 129           (hvbox false true
 130             [ binder_symbol (resolve_binder binder_kind);
 131               k id; builtin_symbol ":"; aux_ty ty; break;
 132               builtin_symbol "."; k body ])
 133     | Ast.Case (what, indty_opt, outty_opt, patterns) ->
 134         let outty_box =
 135           match outty_opt with
 136           | None -> []
 137           | Some outty ->
 138               [ space; keyword "return"; space; break; remove_level_info (k outty)]
 139         in
 140         let indty_box =
 141           match indty_opt with
 142           | None -> []
 143           | Some (indty, href) -> [ space; keyword "in"; space; break; ident_w_href href indty ]
 144         in
 145         let match_box =
 146           hvbox false false [
 147            hvbox false true [
 148             hvbox false true [keyword "match"; space; break; top_pos (k what)];
 149             break;
 150             hvbox false true indty_box;
 151             break;
 152             hvbox false true outty_box
 153            ];
 154            break;
 155            space;
 156            keyword "with";
 157            space
 158          ]
 159         in
 160         let mk_case_pattern =
 161          function
 162             Ast.Pattern (head, href, vars) ->
 163              hvbox true true (ident_w_href href head ::
 164                List.flatten (List.map (fun x -> [break;x]) (map_space aux_var vars)))
 165           | Ast.Wildcard -> builtin_symbol "_"
 166         in
 167         let patterns' =
 168           List.map
 169             (fun (lhs, rhs) ->
 170               remove_level_info
 171                 (hovbox false true [
 172                   mk_case_pattern lhs; break; builtin_symbol "\\Rightarrow";
 173                   break; top_pos (k rhs) ]))
 174             patterns
 175         in
 176         let patterns'' =
 177           let rec aux_patterns = function
 178             | [] -> assert false
 179             | [ last ] ->
 180                 [ break;
 181                   hbox false false [
 182                     builtin_symbol "|";
 183                     last; builtin_symbol "]" ] ]
 184             | hd :: tl ->
 185                 [ break; hbox false false [ builtin_symbol "|"; hd ] ]
 186                 @ aux_patterns tl
 187           in
 188           match patterns' with
 189           | [] ->
 190               [ hbox false false [ builtin_symbol "["; builtin_symbol "]" ] ]
 191           | [ one ] ->
 192               [ hbox false false [
 193                 builtin_symbol "["; one; builtin_symbol "]" ] ]
 194           | hd :: tl ->
 195               hbox false false [ builtin_symbol "["; hd ]
 196               :: aux_patterns tl
 197         in
 198         add_level_info Ast.simple_prec
 199           (hvbox false false [
 200             hvbox false false ([match_box]); break;
 201             hbox false false [ hvbox false false patterns'' ] ])
 202     | Ast.Cast (bo, ty) ->
 203         add_level_info Ast.simple_prec
 204           (hvbox false true [
 205             builtin_symbol "("; top_pos (k bo); break; builtin_symbol ":";
 206             top_pos (k ty); builtin_symbol ")"])
 207     | Ast.LetIn (var, s, t) ->
 208         add_level_info Ast.let_in_prec
 209           (hvbox false true [
 210             hvbox false true [
 211               keyword "let"; space;
 212               hvbox false true [
 213                 aux_var var; space;
 214                 builtin_symbol "\\def"; break; top_pos (k s) ];
 215               break; space; keyword "in"; space ];
 216             break;
 217             k t ])
 218     | Ast.LetRec (rec_kind, funs, where) ->
 219         let rec_op =
 220           match rec_kind with `Inductive -> "rec" | `CoInductive -> "corec"
 221         in
 222         let mk_fun (args, (name,ty), body, rec_param) =
 223          List.flatten (List.map (fun x -> [aux_var x; space]) args),
 224           k name, HExtlib.map_option k ty, k body, fst (List.nth args rec_param)
 225         in
 226         let mk_funs = List.map mk_fun in
 227         let fst_fun, tl_funs =
 228           match mk_funs funs with hd :: tl -> hd, tl | [] -> assert false
 229         in
 230         let fst_row =
 231           let (params, name, ty, body, rec_param) = fst_fun in
 232           hvbox false true ([
 233             keyword "let";
 234             space;
 235             keyword rec_op;
 236             space;
 237             name;
 238             space] @
 239             params @
 240             [keyword "on" ; space ; rec_param ;space ] @
 241             (match ty with None -> [] | Some ty -> [builtin_symbol ":"; ty]) @
 242             [ builtin_symbol "\\def";
 243             break;
 244             top_pos body ])
 245         in
 246         let tl_rows =
 247           List.map
 248             (fun (params, name, ty, body, rec_param) ->
 249               [ break;
 250                 hvbox false true ([
 251                   keyword "and"; space;
 252                   name] @
 253                   params @
 254                   [space; keyword "on" ; space; rec_param ;space ] @
 255                   (match ty with
 256                       None -> []
 257                     | Some ty -> [builtin_symbol ":"; ty]) @
 258                   [ builtin_symbol "\\def"; break; body ])])
 259             tl_funs
 260         in
 261         add_level_info Ast.let_in_prec
 262           ((hvbox false false
 263             (fst_row :: List.flatten tl_rows
 264              @ [ break; keyword "in"; break; k where ])))
 265     | Ast.Implicit `JustOne -> builtin_symbol "?"
 266     | Ast.Implicit `Vector -> builtin_symbol "…"
 267     | Ast.Meta (n, l) ->
 268         let local_context l =
 269             List.map (function None -> None | Some t -> Some (k t)) l
 270         in
 271         Ast.Meta(n, local_context l)
 272     | Ast.Sort sort -> aux_sort sort
 273     | Ast.Num _
 274     | Ast.Symbol _
 275     | Ast.Ident _
 276     | Ast.Literal _
 277     | Ast.UserInput as leaf -> leaf
 278     | t -> NotationUtil.visit_ast ~special_k k t
 279   and aux_sort sort_kind = xml_of_sort sort_kind
 280   and aux_ty = function
 281     | None -> builtin_symbol "?"
 282     | Some ty -> k ty
 283   and aux_var = function
 284     | name, Some ty ->
 285         hvbox false true [
 286           builtin_symbol "("; name; builtin_symbol ":"; break; k ty;
 287           builtin_symbol ")" ]
 288     | name, None -> name
 289   and special_k = function
 290     | Ast.AttributedTerm (attrs, t) -> Ast.AttributedTerm (attrs, k t)
 291     | t ->
 292         prerr_endline ("unexpected special: " ^ NotationPp.pp_term status t);
 293         assert false
 294   in
 295   aux t
 296
 297   (* persistent state *)
 298
 299 module IntMap = Map.Make(struct type t = int let compare = compare end);;
 300
 301 type db = {
 302  level1_patterns21: NotationPt.term IntMap.t;
 303  compiled21: ((NotationPt.term -> (NotationEnv.t * NotationPt.term list * int) option)) Lazy.t option;
 304  pattern21_matrix: (NotationPt.term * pattern_id) list;
 305  counter: pattern_id
 306 }
 307
 308 let initial_db = {
 309  level1_patterns21 = IntMap.empty;
 310  compiled21 = None;
 311  pattern21_matrix = [];
 312  counter = ~-1
 313 }
 314
 315 class type g_status =
 316   object
 317     method content_pres_db: db
 318   end
 319
 320 class virtual status uid =
 321  object
 322    inherit NCic.status uid
 323    val content_pres_db = initial_db
 324    method content_pres_db = content_pres_db
 325    method set_content_pres_db v = {< content_pres_db = v >}
 326    method set_content_pres_status
 327     : 'status. #g_status as 'status -> 'self
 328     = fun o -> {< content_pres_db = o#content_pres_db >}
 329  end
 330
 331 let get_compiled21 status =
 332   match status#content_pres_db.compiled21 with
 333   | None -> assert false
 334   | Some f -> Lazy.force f
 335
 336 let set_compiled21 status f =
 337  status#set_content_pres_db
 338   { status#content_pres_db with compiled21 = Some f }
 339
 340 (* let add_idrefs =
 341   List.fold_right (fun idref t -> Ast.AttributedTerm (`IdRef idref, t)) *)
 342
 343 let instantiate21 idrefs env l1 =
 344   let rec subst_singleton pos env =
 345     function
 346       Ast.AttributedTerm (attr, t) ->
 347         Ast.AttributedTerm (attr, subst_singleton pos env t)
 348     | t -> NotationUtil.group (subst pos env t)
 349   and subst pos env = function
 350     | Ast.AttributedTerm (attr, t) ->
 351 (*         prerr_endline ("loosing attribute " ^ NotationPp.pp_attribute attr); *)
 352         subst pos env t
 353     | Ast.Variable var ->
 354         let name, expected_ty = NotationEnv.declaration_of_var var in
 355         let ty, value =
 356           try
 357             List.assoc name env
 358           with Not_found ->
 359             prerr_endline ("name " ^ name ^ " not found in environment");
 360             assert false
 361         in
 362         assert (NotationEnv.well_typed ty value); (* INVARIANT *)
 363         (* following assertion should be a conditional that makes this
 364          * instantiation fail *)
 365         if not (NotationEnv.well_typed expected_ty value) then
 366          begin
 367           prerr_endline ("The variable " ^ name ^ " is used with the wrong type in the notation declaration");
 368           assert false
 369          end;
 370         let value = NotationEnv.term_of_value value in
 371         let value =
 372           match expected_ty with
 373           | Env.TermType l -> Ast.AttributedTerm (`Level l,value)
 374           | _ -> value
 375         in
 376         [ value ]
 377     | Ast.Magic m -> subst_magic pos env m
 378     | Ast.Literal l as t ->
 379        (match idrefs with
 380         | [] -> [t]
 381         | desc::_ ->
 382             let desc = Some desc in
 383             (match l with
 384             | `Keyword (k,_) -> [ Ast.Literal (`Keyword (k,(None,desc))) ]
 385             | `Symbol (s,_) -> [ Ast.Literal (`Symbol (s,(None,desc))) ]
 386             | `Number (n,_) -> [ Ast.Literal (`Number (n,(None,desc))) ]))
 387     | Ast.Layout l -> [ Ast.Layout (subst_layout pos env l) ]
 388     | t -> [ NotationUtil.visit_ast (subst_singleton pos env) t ]
 389   and subst_magic pos env = function
 390     | Ast.List0 (p, sep_opt)
 391     | Ast.List1 (p, sep_opt) ->
 392         let rec_decls = NotationEnv.declarations_of_term p in
 393         let rec_values =
 394           List.map (fun (n, _) -> NotationEnv.lookup_list env n) rec_decls
 395         in
 396         let values = NotationUtil.ncombine rec_values in
 397         let sep =
 398           match sep_opt with
 399             | None -> []
 400             | Some l -> [ Ast.Literal l; break; space ]
 401         in
 402         let rec instantiate_list acc = function
 403           | [] -> List.rev acc
 404           | value_set :: [] ->
 405               let env = NotationEnv.combine rec_decls value_set in
 406               instantiate_list (NotationUtil.group (subst pos env p) :: acc)
 407                 []
 408           | value_set :: tl ->
 409               let env = NotationEnv.combine rec_decls value_set in
 410               let terms = subst pos env p in
 411               instantiate_list (NotationUtil.group (terms @ sep) :: acc) tl
 412         in
 413         if values = [] then []
 414         else [hovbox false false (instantiate_list [] values)]
 415     | Ast.Opt p ->
 416         let opt_decls = NotationEnv.declarations_of_term p in
 417         let env =
 418           let rec build_env = function
 419             | [] -> []
 420             | (name, ty) :: tl ->
 421                   (* assumption: if one of the value is None then all are *)
 422                 (match NotationEnv.lookup_opt env name with
 423                 | None -> raise Exit
 424                 | Some v -> (name, (ty, v)) :: build_env tl)
 425           in
 426           try build_env opt_decls with Exit -> []
 427         in
 428           begin
 429             match env with
 430               | [] -> []
 431               | _ -> subst pos env p
 432           end
 433     | _ -> assert false (* impossible *)
 434   and subst_layout pos env = function
 435     | Ast.Box (kind, tl) ->
 436         let tl' = subst_children pos env tl in
 437         Ast.Box (kind, List.concat tl')
 438     | l -> NotationUtil.visit_layout (subst_singleton pos env) l
 439   and subst_children pos env =
 440     function
 441     | [] -> []
 442     | [ child ] ->
 443         let pos' =
 444           match pos with
 445           | `Inner -> `Right
 446           | `Left -> `Left
 447 (*           | `None -> assert false *)
 448           | `Right -> `Right
 449         in
 450         [ subst pos' env child ]
 451     | hd :: tl ->
 452         let pos' =
 453           match pos with
 454           | `Inner -> `Inner
 455           | `Left -> `Inner
 456 (*           | `None -> assert false *)
 457           | `Right -> `Right
 458         in
 459         (subst pos env hd) :: subst_children pos' env tl
 460   in
 461     subst_singleton `Left env l1
 462
 463 let rec pp_ast1 status term =
 464   let rec pp_value = function
 465     | NotationEnv.NumValue _ as v -> v
 466     | NotationEnv.StringValue _ as v -> v
 467 (*     | NotationEnv.TermValue t when t == term -> NotationEnv.TermValue (pp_ast0 status t pp_ast1) *)
 468     | NotationEnv.TermValue t -> NotationEnv.TermValue (pp_ast1 status t)
 469     | NotationEnv.OptValue None as v -> v
 470     | NotationEnv.OptValue (Some v) ->
 471         NotationEnv.OptValue (Some (pp_value v))
 472     | NotationEnv.ListValue vl ->
 473         NotationEnv.ListValue (List.map pp_value vl)
 474     | NotationEnv.DisambiguationValue _ as v -> v
 475   in
 476   let ast_env_of_env env =
 477     (* prerr_endline ("### pp_env: " ^ NotationPp.pp_env status env); *)
 478     List.map (fun (var, (ty, value)) -> (var, (ty, pp_value value))) env
 479   in
 480 (* prerr_endline ("### pattern matching from 2 to 1 on term " ^
 481  * NotationPp.pp_term status term); *)
 482   let res =
 483   match term with
 484   | Ast.AttributedTerm (attrs, term') ->
 485       Ast.AttributedTerm (attrs, pp_ast1 status term')
 486   | _ ->
 487       (match get_compiled21 status term with
 488       | None -> (* prerr_endline "### ramo 1"; *)
 489           pp_ast0 status term (pp_ast1 status)
 490       | Some (env, ctors, pid) ->
 491           (* prerr_endline "### ramo 2";
 492             prerr_endline ("### constructors:\n" ^
 493            (String.concat "\n\n" (List.map (NotationPp.pp_term status) ctors)) ^
 494            "\n\n### constructors end") *)
 495           let idrefs =
 496             List.flatten (List.map NotationUtil.get_idrefs ctors)
 497           in
 498           let l1 =
 499             try
 500               IntMap.find pid status#content_pres_db.level1_patterns21
 501             with Not_found -> assert false
 502           in
 503           instantiate21 idrefs (ast_env_of_env env) l1)
 504   in
 505   (* prerr_endline ("### pattern matching finished: " ^ NotationPp.pp_term
 506    * status res);*)
 507   res
 508
 509 let load_patterns21 status t =
 510   set_compiled21 status (lazy (Content2presMatcher.Matcher21.compiler t))
 511
 512 let pp_ast status ast =
 513   debug_print (lazy "pp_ast <-");
 514   let ast' = pp_ast1 status ast in
 515   debug_print (lazy ("pp_ast -> " ^ NotationPp.pp_term status ast'));
 516   ast'
 517
 518 let fill_pos_info l1_pattern = l1_pattern
 519 (*   let rec aux toplevel pos =
 520     function
 521     | Ast.Layout l ->
 522         (match l
 523
 524     | Ast.Magic m ->
 525         Ast.Box (
 526     | Ast.Variable _ as t -> add_pos_info pos t
 527     | t -> t
 528   in
 529   aux true l1_pattern *)
 530
 531 let fresh_id status =
 532   let counter = status#content_pres_db.counter+1 in
 533    status#set_content_pres_db ({ status#content_pres_db with counter = counter  }), counter
 534
 535 let add_pretty_printer status l2 (CicNotationParser.CL1P (l1,precedence)) =
 536   let status,id = fresh_id status in
 537   let l1' = add_level_info precedence (fill_pos_info l1) in
 538   let l2' = NotationUtil.strip_attributes l2 in
 539   let status =
 540    status#set_content_pres_db
 541     { status#content_pres_db with
 542        level1_patterns21 =
 543         IntMap.add id l1' status#content_pres_db.level1_patterns21;
 544        pattern21_matrix = (l2',id)::status#content_pres_db.pattern21_matrix } in
 545   load_patterns21 status status#content_pres_db.pattern21_matrix
 546
 547   (* presentation -> content *)
 548
 549 let unopt_names names env =
 550   let rec aux acc = function
 551     | (name, (ty, v)) :: tl when List.mem name names ->
 552         (match ty, v with
 553         | Env.OptType ty, Env.OptValue (Some v) ->
 554             aux ((name, (ty, v)) :: acc) tl
 555         | _ -> assert false)
 556     | hd :: tl -> aux (hd :: acc) tl
 557     | [] -> acc
 558   in
 559   aux [] env
 560
 561 let head_names names env =
 562   let rec aux acc = function
 563     | (name, (ty, v)) :: tl when List.mem name names ->
 564         (match ty, v with
 565         | Env.ListType ty, Env.ListValue (v :: _) ->
 566             aux ((name, (ty, v)) :: acc) tl
 567         | Env.TermType _, Env.TermValue _  ->
 568             aux ((name, (ty, v)) :: acc) tl
 569         | Env.OptType _, Env.OptValue _ ->
 570             aux ((name, (ty, v)) :: acc) tl
 571         | _ -> assert false)
 572     | _ :: tl -> aux acc tl
 573       (* base pattern may contain only meta names, thus we trash all others *)
 574     | [] -> acc
 575   in
 576   aux [] env
 577
 578 let tail_names names env =
 579   let rec aux acc = function
 580     | (name, (ty, v)) :: tl when List.mem name names ->
 581         (match ty, v with
 582         | Env.ListType ty, Env.ListValue (_ :: vtl) ->
 583             aux ((name, (Env.ListType ty, Env.ListValue vtl)) :: acc) tl
 584         | Env.TermType _, Env.TermValue _  ->
 585             aux ((name, (ty, v)) :: acc) tl
 586         | Env.OptType _, Env.OptValue _ ->
 587             aux ((name, (ty, v)) :: acc) tl
 588         | _ -> assert false)
 589     | binding :: tl -> aux (binding :: acc) tl
 590     | [] -> acc
 591   in
 592   aux [] env
 593
 594 let instantiate_level2 status env (loc,uri,desc) term =
 595 (*   prerr_endline ("istanzio: " ^ NotationPp.pp_term term); *)
 596   let fresh_env = ref [] in
 597   let lookup_fresh_name n =
 598     try
 599       List.assoc n !fresh_env
 600     with Not_found ->
 601       let new_name = NotationUtil.fresh_name () in
 602       fresh_env := (n, new_name) :: !fresh_env;
 603       new_name
 604   in
 605   let rec aux env term =
 606     match term with
 607     | Ast.AttributedTerm (a, term) -> (*Ast.AttributedTerm (a, *)aux env term
 608     | Ast.Appl terms -> Ast.Appl (List.map (aux env) terms)
 609     | Ast.Binder (binder, var, body) ->
 610         Ast.Binder (binder, aux_capture_var env var, aux env body)
 611     | Ast.Case (term, indty, outty_opt, patterns) ->
 612         Ast.Case (aux env term, indty, aux_opt env outty_opt,
 613           List.map (aux_branch env) patterns)
 614     | Ast.LetIn (var, t1, t3) ->
 615         Ast.LetIn (aux_capture_var env var, aux env t1, aux env t3)
 616     | Ast.LetRec (kind, definitions, body) ->
 617         Ast.LetRec (kind, List.map (aux_definition env) definitions,
 618           aux env body)
 619     | Ast.Meta (index, substs) -> Ast.Meta (index, aux_meta_substs env substs)
 620
 621     | Ast.Implicit _
 622     | Ast.Ident _
 623     | Ast.Num _
 624     | Ast.Sort _
 625     | Ast.UserInput -> term
 626     | Ast.Symbol (s,_) -> aux_symbol s loc (uri,desc)
 627
 628     | Ast.Magic magic -> aux_magic env magic
 629     | Ast.Variable var -> aux_variable env var
 630
 631     | Ast.Cast (t, ty) -> Ast.Cast (aux env t, aux env ty)
 632
 633     | _ -> assert false
 634   and aux_symbol s loc = function
 635   | _, None -> Ast.AttributedTerm (`Loc loc, Ast.Symbol (s, None))
 636   | uri, Some desc ->
 637       Ast.AttributedTerm (`Loc loc, Ast.Symbol (s, Some (uri,desc)))
 638   and aux_opt env = function
 639     | Some term -> Some (aux env term)
 640     | None -> None
 641   and aux_capture_var env (name, ty_opt) = (aux env name, aux_opt env ty_opt)
 642   and aux_branch env (pattern, term) =
 643     (aux_pattern env pattern, aux env term)
 644   and aux_pattern env =
 645    function
 646       Ast.Pattern (head, hrefs, vars) ->
 647        Ast.Pattern (head, hrefs, List.map (aux_capture_var env) vars)
 648     | Ast.Wildcard -> Ast.Wildcard
 649   and aux_definition env (params, var, term, i) =
 650     (List.map (aux_capture_var env) params, aux_capture_var env var, aux env term, i)
 651   and aux_substs env substs =
 652     List.map (fun (name, term) -> (name, aux env term)) substs
 653   and aux_meta_substs env meta_substs = List.map (aux_opt env) meta_substs
 654   and aux_variable env = function
 655     | Ast.NumVar name -> Ast.Num (Env.lookup_num env name, None)
 656     | Ast.IdentVar name ->
 657        (match Env.lookup_string env name with
 658            Env.Ident x -> Ast.Ident (x, `Ambiguous)
 659          | Env.Var x -> Ast.Variable (Ast.IdentVar x))
 660     | Ast.TermVar (name,(Ast.Level l|Ast.Self l)) ->
 661         Ast.AttributedTerm (`Level l,Env.lookup_term env name)
 662     | Ast.FreshVar name -> Ast.Ident (lookup_fresh_name name, `Ambiguous)
 663     | Ast.Ascription (term, name) -> assert false
 664   and aux_magic env = function
 665     | Ast.Default (some_pattern, none_pattern) ->
 666         let some_pattern_names = NotationUtil.names_of_term some_pattern in
 667         let none_pattern_names = NotationUtil.names_of_term none_pattern in
 668         let opt_names =
 669           List.filter
 670             (fun name -> not (List.mem name none_pattern_names))
 671             some_pattern_names
 672         in
 673         (match opt_names with
 674         | [] -> assert false (* some pattern must contain at least 1 name *)
 675         | (name :: _) as names ->
 676             (match Env.lookup_value env name with
 677             | Env.OptValue (Some _) ->
 678                 (* assumption: if "name" above is bound to Some _, then all
 679                  * names returned by "meta_names_of" are bound to Some _ as well
 680                  *)
 681                 aux (unopt_names names env) some_pattern
 682             | Env.OptValue None -> aux env none_pattern
 683             | _ ->
 684                 prerr_endline (sprintf
 685                   "lookup of %s in env %s did not return an optional value"
 686                   name (NotationPp.pp_env status env));
 687                 assert false))
 688     | Ast.Fold (`Left, base_pattern, names, rec_pattern) ->
 689         let acc_name = List.hd names in (* names can't be empty, cfr. parser *)
 690         let meta_names =
 691           List.filter ((<>) acc_name)
 692             (NotationUtil.names_of_term rec_pattern)
 693         in
 694         (match meta_names with
 695         | [] -> assert false (* as above *)
 696         | (name :: _) as names ->
 697             let rec instantiate_fold_left acc env' =
 698               match Env.lookup_value env' name with
 699               | Env.ListValue (_ :: _) ->
 700                   instantiate_fold_left
 701                     (let acc_binding =
 702                       acc_name, (Env.TermType 0, Env.TermValue acc)
 703                      in
 704                      aux (acc_binding :: head_names names env') rec_pattern)
 705                     (tail_names names env')
 706               | Env.ListValue [] -> acc
 707               | _ -> assert false
 708             in
 709             instantiate_fold_left (aux env base_pattern) env)
 710     | Ast.Fold (`Right, base_pattern, names, rec_pattern) ->
 711         let acc_name = List.hd names in (* names can't be empty, cfr. parser *)
 712         let meta_names =
 713           List.filter ((<>) acc_name)
 714             (NotationUtil.names_of_term rec_pattern)
 715         in
 716         (match meta_names with
 717         | [] -> assert false (* as above *)
 718         | (name :: _) as names ->
 719             let rec instantiate_fold_right env' =
 720               match Env.lookup_value env' name with
 721               | Env.ListValue (_ :: _) ->
 722                   let acc = instantiate_fold_right (tail_names names env') in
 723                   let acc_binding =
 724                     acc_name, (Env.TermType 0, Env.TermValue acc)
 725                   in
 726                   aux (acc_binding :: head_names names env') rec_pattern
 727               | Env.ListValue [] -> aux env base_pattern
 728               | _ -> assert false
 729             in
 730             instantiate_fold_right env)
 731     | Ast.If (_, p_true, p_false) as t ->
 732         aux env (NotationUtil.find_branch (Ast.Magic t))
 733     | Ast.Fail -> assert false
 734     | _ -> assert false
 735   in
 736   aux env term