matitaB/components/ng_paramodulation/nCicBlob.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: terms.mli 9822 2009-06-03 15:37:06Z tassi $ *)
  13
  14 let eqPref = ref (fun _ -> assert false);;
  15 let set_eqP t = eqPref := fun _ -> t;;
  16
  17 let default_eqP() =
  18   let uri = NUri.uri_of_string "cic:/matita/basics/logic/eq.ind" in
  19   let ref = NReference.reference_of_spec uri (NReference.Ind(true,0,2)) in
  20     NCic.Const ref
  21 ;;
  22
  23 let equivalence_relation =
  24   let uri = NUri.uri_of_string "cic:/matita/ng/properties/relations/eq_rel.con"
  25   in
  26   let ref = NReference.reference_of_spec uri (NReference.Fix(0,1,2))
  27   in NCic.Const ref
  28
  29 let setoid_eq =
  30   let uri = NUri.uri_of_string "cic:/matita/ng/sets/setoids/eq.con" in
  31   let ref = NReference.reference_of_spec uri (NReference.Fix(0,0,2))
  32   in NCic.Const ref
  33
  34 let set_default_eqP() = eqPref := default_eqP
  35
  36 module type NCicContext =
  37   sig
  38     val metasenv : NCic.metasenv
  39     val subst : NCic.substitution
  40     val context : NCic.context
  41   end
  42
  43 module NCicBlob(C : NCicContext) : Terms.Blob
  44 with type t = NCic.term and type input = NCic.term = struct
  45
  46   type t = NCic.term
  47
  48   let eq x y = x = y;;
  49     (* NCicReduction.alpha_eq C.metasenv C.subst C.context x y;; *)
  50
  51   let height_of_ref = function
  52     | NReference.Def h -> h
  53     | NReference.Fix(_,_,h) -> h
  54     | _ -> 0
  55
  56   let compare_refs (NReference.Ref (u1,r1)) (NReference.Ref (u2,r2)) =
  57     let x = height_of_ref r2 - height_of_ref r1 in
  58       if x = 0 then
  59         Hashtbl.hash (NUri.string_of_uri u1,r1) -
  60           Hashtbl.hash (NUri.string_of_uri u2,r2)
  61       else x
  62
  63   let rec compare x y =
  64     match x,y with
  65     | NCic.Rel i, NCic.Rel j -> j-i
  66     | NCic.Meta (i,_), NCic.Meta (j,_) -> i-j
  67     | NCic.Const r1, NCic.Const r2 -> compare_refs r1 r2
  68     (*NReference.compare r1 r2*)
  69     | NCic.Appl l1, NCic.Appl l2 -> FoUtils.lexicograph compare l1 l2
  70     | NCic.Rel _, ( NCic.Meta _ | NCic.Const _ | NCic.Appl _ ) -> ~-1
  71     | ( NCic.Meta _ | NCic.Const _ | NCic.Appl _ ), NCic.Rel _ -> 1
  72     | NCic.Const _, ( NCic.Meta _ | NCic.Appl _ ) -> ~-1
  73     | ( NCic.Meta _ | NCic.Appl _ ), NCic.Const _ -> 1
  74     | NCic.Appl _, NCic.Meta _ -> ~-1
  75     | NCic.Meta _, NCic.Appl _ -> 1
  76     | _ -> Pervasives.compare x y
  77         (* was assert false, but why? *)
  78
  79   ;;
  80
  81   let compare x y =
  82     (* CSC: NCicPp.status is the best I can put here *)
  83     (* WR: and I can't guess a user id, so I must put None *)
  84     if NCicReduction.alpha_eq (new NCicPp.status None) [] [] [] x y  then 0
  85     (* if x = y  then 0 *)
  86     else compare x y
  87   ;;
  88
  89   let eqP = (!eqPref)()
  90   ;;
  91
  92   let is_eq = function
  93     | Terms.Node [ Terms.Leaf eqt ; ty; l; r ] when eq eqP eqt ->
  94         Some (ty,l,r)
  95 (*
  96     | Terms.Node [ Terms.Leaf eqt ; _; Terms.Node [Terms.Leaf eqt2 ; ty]; l; r]
  97         when eq equivalence_relation eqt && eq setoid_eq eqt2 ->
  98         Some (ty,l,r) *)
  99     | _ -> None
 100
 101   let pp t =
 102     (* CSC: NCicPp.status is the best I can put here *)
 103     (* WR: and I can't guess a user id, so I must put None *)
 104     (new NCicPp.status None)#ppterm ~context:C.context
 105       ~metasenv:C.metasenv ~subst:C.subst t;;
 106
 107   type input = NCic.term
 108
 109   let rec embed = function
 110     | NCic.Meta (i,_) -> Terms.Var i, [i]
 111     | NCic.Appl l ->
 112         let rec aux acc l = function
 113           |[] -> acc@l
 114           |hd::tl -> if List.mem hd l then aux acc l tl else aux (hd::acc) l tl
 115         in
 116         let res,vars = List.fold_left
 117           (fun (r,v) t -> let r1,v1 = embed t in (r1::r),aux [] v v1) ([],[]) l
 118         in (Terms.Node (List.rev res)), vars
 119     | t -> Terms.Leaf t, []
 120   ;;
 121
 122   let embed t = fst (embed t) ;;
 123
 124   let saturate t ty =
 125     let sty, _, args =
 126       (* CSC: NCicPp.status is the best I can put here *)
 127       (* WR: and I can't guess a user id, so I must put None *)
 128       NCicMetaSubst.saturate (new NCicPp.status None) ~delta:0 C.metasenv C.subst
 129        C.context ty 0
 130     in
 131     let proof =
 132       if args = [] then Terms.Leaf t
 133       else Terms.Node (Terms.Leaf t :: List.map embed args)
 134     in
 135     let sty = embed sty in
 136     proof, sty
 137   ;;
 138
 139  end