matitaB/matita/matitaEngine.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 module G = GrafiteAst
  29 open GrafiteTypes
  30 open Printf
  31
  32 class status uid baseuri =
  33  object
  34   inherit GrafiteTypes.status uid baseuri
  35   inherit ApplyTransformation.status uid
  36  end
  37
  38 exception TryingToAdd of string Lazy.t
  39 exception EnrichedWithStatus of exn * status
  40 exception AlreadyLoaded of string Lazy.t
  41 exception FailureCompiling of string * exn
  42 exception CircularDependency of string
  43
  44 let debug = false ;;
  45 let debug_print = if debug then prerr_endline else ignore ;;
  46
  47 let slash_n_RE = Pcre.regexp "\\n" ;;
  48
  49 let pp_ast_statement status stm =
  50   let stm = GrafiteAstPp.pp_statement status stm
  51     ~map_unicode_to_tex:(Helm_registry.get_bool "matita.paste_unicode_as_tex")
  52   in
  53   let stm = Pcre.replace ~rex:slash_n_RE stm in
  54   let stm =
  55       if String.length stm > 50 then String.sub stm 0 50 ^ " ..."
  56       else stm
  57   in
  58     HLog.debug ("Executing: ``" ^ stm ^ "''")
  59 ;;
  60
  61 let clean_exit baseuri exn =
  62   LibraryClean.clean_baseuris ~verbose:false [baseuri];
  63   raise (FailureCompiling (baseuri,exn))
  64 ;;
  65
  66
  67 let pp_times fname rc big_bang big_bang_u big_bang_s =
  68   if not (Helm_registry.get_bool "matita.verbose") then
  69     let { Unix.tms_utime = u ; Unix.tms_stime = s} = Unix.times () in
  70     let r = Unix.gettimeofday () -. big_bang in
  71     let u = u -. big_bang_u in
  72     let s = s -. big_bang_s in
  73     let extra = try Sys.getenv "BENCH_EXTRA_TEXT" with Not_found -> "" in
  74     let rc,rcascii =
  75       if rc then "\e[0;32mOK\e[0m","Ok" else "\e[0;31mFAIL\e[0m","Fail" in
  76     let times =
  77       let fmt t =
  78         let seconds = int_of_float t in
  79         let cents = int_of_float ((t -. floor t) *. 100.0) in
  80         let minutes = seconds / 60 in
  81         let seconds = seconds mod 60 in
  82         Printf.sprintf "%dm%02d.%02ds" minutes seconds cents
  83       in
  84       Printf.sprintf "%s %s %s" (fmt r) (fmt u) (fmt s)
  85     in
  86     let s = Printf.sprintf "%-4s %s %s" rc times extra in
  87     print_endline s;
  88     flush stdout;
  89     HLog.message ("Compilation of "^Filename.basename fname^": "^rc)
  90 ;;
  91
  92 let cut prefix s =
  93   let lenp = String.length prefix in
  94   let lens = String.length s in
  95   assert (lens > lenp);
  96   assert (String.sub s 0 lenp = prefix);
  97   String.sub s lenp (lens-lenp)
  98 ;;
  99
 100 let activate_extraction baseuri fname =
 101   ()
 102   (* MATITA 1.0
 103  if Helm_registry.get_bool "matita.extract" then
 104   let mangled_baseuri =
 105    let baseuri = String.sub baseuri 5 (String.length baseuri - 5) in
 106      let baseuri = Pcre.replace ~pat:"/" ~templ:"_" baseuri in
 107       String.uncapitalize baseuri in
 108   let f =
 109     open_out
 110      (Filename.dirname fname ^ "/" ^ mangled_baseuri ^ ".ml") in
 111    LibrarySync.add_object_declaration_hook
 112     (fun ~add_obj ~add_coercion _ obj ->
 113       output_string f (CicExportation.ppobj baseuri obj);
 114       flush f; []);
 115       *)
 116 ;;
 117
 118
 119 let eval_ast ~include_paths ?do_heavy_checks status (text,prefix_len,ast as ast') =
 120  let baseuri = status#baseuri in
 121    GrafiteEngine.eval_ast ~include_paths ?do_heavy_checks status ast'
 122 ;;
 123
 124 let baseuri_of_script ~include_paths fname =
 125  try Librarian.baseuri_of_script ~include_paths fname
 126  with
 127    Librarian.NoRootFor _ ->
 128     HLog.error ("The included file '"^fname^"' has no root file,");
 129     HLog.error "please create it.";
 130     raise (Failure ("No root file for "^fname))
 131   | Librarian.FileNotFound _ ->
 132     raise (Failure ("File not found: "^fname))
 133 ;;
 134
 135 let rec get_ast status ~compiling ~asserted ~include_paths strm =
 136   match GrafiteParser.parse_statement status strm with
 137      (GrafiteAst.Executable
 138        (_,GrafiteAst.NCommand (_,GrafiteAst.Include (_,_,mafilename)))) as cmd
 139      ->
 140        let already_included = NCicLibrary.get_transitively_included status in
 141        let asserted,_ =
 142         assert_ng ~already_included ~compiling ~asserted ~include_paths
 143          ?uid:status#user mafilename
 144        in
 145         asserted,cmd
 146    | cmd -> asserted,cmd
 147
 148 and eval_from_stream ~compiling ~asserted ~include_paths ?do_heavy_checks status str cb =
 149  let matita_debug = Helm_registry.get_bool "matita.debug" in
 150  let rec loop asserted status =
 151   let asserted,stop,status =
 152    try
 153      let cont =
 154        try Some (get_ast status ~compiling ~asserted ~include_paths str)
 155        with End_of_file -> None in
 156      match cont with
 157      | None -> asserted, true, status
 158      | Some (asserted,ast) ->
 159         cb status ast;
 160         let status =
 161           eval_ast ~include_paths ?do_heavy_checks status ("",0,ast)
 162         in
 163          asserted, false, status
 164    with exn when not matita_debug ->
 165      raise (EnrichedWithStatus (exn, status))
 166   in
 167   if stop then asserted,status else loop asserted status
 168  in
 169   loop asserted status
 170
 171 and compile ~compiling ~asserted ~include_paths ~outch ?uid fname =
 172   if List.mem fname compiling then raise (CircularDependency fname);
 173   let compiling = fname::compiling in
 174   let matita_debug = Helm_registry.get_bool "matita.debug" in
 175   let root,baseuri,fname,_tgt =
 176     Librarian.baseuri_of_script ~include_paths fname in
 177   if Http_getter_storage.is_read_only baseuri then assert false;
 178   activate_extraction baseuri fname ;
 179   (* MATITA 1.0: debbo fare time_travel sulla ng_library? *)
 180   (* FIXME: currently hardcoded to single user mode *)
 181   let status = new status uid baseuri in
 182   let big_bang = Unix.gettimeofday () in
 183   let { Unix.tms_utime = big_bang_u ; Unix.tms_stime = big_bang_s} =
 184     Unix.times ()
 185   in
 186   let time = Unix.time () in
 187   try
 188     (* cleanup of previously compiled objects *)
 189     if (not (Http_getter_storage.is_empty ~local:true baseuri))
 190       then begin
 191       HLog.message ("baseuri " ^ baseuri ^ " is not empty");
 192       HLog.message ("cleaning baseuri " ^ baseuri);
 193       LibraryClean.clean_baseuris [baseuri];
 194     end;
 195     HLog.message ("compiling " ^ Filename.basename fname ^ " in " ^ baseuri);
 196     if not (Helm_registry.get_bool "matita.verbose") then
 197       (let cc =
 198         let rex = Str.regexp ".*opt$" in
 199         if Str.string_match rex Sys.argv.(0) 0 then "matitac.opt"
 200         else "matitac"
 201       in
 202       let s = Printf.sprintf "%s %-35s " cc (cut (root^"/") fname) in
 203       print_string s; flush stdout);
 204     (* we dalay this error check until we print 'matitac file ' *)
 205     assert (Http_getter_storage.is_empty ~local:true baseuri);
 206     (* create dir for XML files *)
 207     if not (Helm_registry.get_opt_default Helm_registry.bool "matita.nodisk"
 208               ~default:false)
 209     then
 210       HExtlib.mkdir
 211         (Filename.dirname
 212           (Http_getter.filename ~local:true ~writable:true (baseuri ^
 213           "foo.con")));
 214     let buf =
 215      GrafiteParser.parsable_statement status
 216       (Ulexing.from_utf8_channel (open_in fname))
 217     in
 218     let print_cb =
 219       if not (Helm_registry.get_bool "matita.verbose") then (fun _ _ -> ())
 220       else pp_ast_statement
 221     in
 222     let asserted, status =
 223      eval_from_stream ~compiling ~asserted ~include_paths status buf print_cb in
 224     let elapsed = Unix.time () -. time in
 225      (if Helm_registry.get_bool "matita.moo" then begin
 226        GrafiteTypes.Serializer.serialize ~baseuri:(NUri.uri_of_string baseuri)
 227         status
 228      end;
 229      let tm = Unix.gmtime elapsed in
 230      let sec = string_of_int tm.Unix.tm_sec ^ "''" in
 231      let min =
 232        if tm.Unix.tm_min > 0 then (string_of_int tm.Unix.tm_min^"' ") else ""
 233      in
 234      let hou =
 235        if tm.Unix.tm_hour > 0 then (string_of_int tm.Unix.tm_hour^"h ") else ""
 236      in
 237      HLog.message
 238        (sprintf "execution of %s completed in %s." fname (hou^min^sec));
 239      pp_times fname true big_bang big_bang_u big_bang_s;
 240      (* XXX: update script -- currently to stdout *)
 241      let origbuf = Ulexing.from_utf8_channel (open_in fname) in
 242      let interpr = GrafiteDisambiguate.get_interpr status#disambiguate_db in
 243      ignore (SmallLexer.mk_small_printer interpr outch origbuf);
 244      asserted
 245 (* MATITA 1.0: debbo fare time_travel sulla ng_library?
 246      LexiconSync.time_travel
 247        ~present:lexicon_status ~past:initial_lexicon_status;
 248 *))
 249   with
 250   (* all exceptions should be wrapped to allow lexicon-undo (LS.time_travel) *)
 251   | exn when not matita_debug ->
 252 (* MATITA 1.0: debbo fare time_travel sulla ng_library?
 253        LexiconSync.time_travel ~present:lexicon ~past:initial_lexicon_status;
 254  *       *)
 255       pp_times fname false big_bang big_bang_u big_bang_s;
 256       clean_exit baseuri exn
 257
 258 and assert_ng ~already_included ~compiling ~asserted ~include_paths ?outch ?uid mapath =
 259  let _,baseuri,fullmapath,_ = Librarian.baseuri_of_script ~include_paths mapath in
 260  if List.mem fullmapath asserted then asserted,false
 261  else
 262   begin
 263    let baseuri = NUri.uri_of_string baseuri in
 264    let ngtime_of baseuri =
 265     let ngpath = NCicLibrary.ng_path_of_baseuri uid baseuri in
 266     let uid = match uid with Some u -> "Some " ^ u | _ -> "None" in
 267     prerr_endline ("uid = " ^ uid);
 268     prerr_endline ("ngpath = " ^ ngpath);
 269     try
 270      Some (Unix.stat ngpath).Unix.st_mtime
 271     with Unix.Unix_error (Unix.ENOENT, "stat", f) when f = ngpath -> None in
 272    let matime =
 273     try (Unix.stat fullmapath).Unix.st_mtime
 274     with Unix.Unix_error (Unix.ENOENT, "stat", f) when f = fullmapath -> assert false
 275    in
 276    let ngtime = ngtime_of baseuri in
 277    let asserted,to_be_compiled =
 278     match ngtime with
 279        Some ngtime ->
 280         let preamble = GrafiteTypes.Serializer.dependencies_of uid baseuri in
 281         let asserted,children_bad =
 282          List.fold_left
 283           (fun (asserted,b) mapath ->
 284             let asserted,b1 =
 285               assert_ng ~already_included ~compiling ~asserted ~include_paths
 286                 ?uid mapath
 287             in
 288              asserted, b || b1
 289               || let _,baseuri,_,_ =
 290                    Librarian.baseuri_of_script ~include_paths mapath in
 291                  let baseuri = NUri.uri_of_string baseuri in
 292                   (match ngtime_of baseuri with
 293                       Some child_ngtime -> child_ngtime > ngtime
 294                     | None -> assert false)
 295           ) (asserted,false) preamble
 296         in
 297          asserted, children_bad || matime > ngtime
 298      | None -> asserted,true
 299    in
 300     prerr_endline ("asserted = " ^ (String.concat "," asserted));
 301     if not to_be_compiled then fullmapath::asserted,false
 302     else
 303      if List.mem baseuri already_included then
 304        (* maybe recompiling it I would get the same... *)
 305        raise (AlreadyLoaded (lazy mapath))
 306      else
 307       let outch, is_file_ch =
 308         match outch with
 309         | None -> open_out (fullmapath ^ ".mad"), true
 310         | Some c -> c, false
 311       in
 312       prerr_endline ("compiling " ^ fullmapath);
 313       let asserted = compile ~compiling ~asserted ~include_paths ~outch ?uid fullmapath in
 314        if is_file_ch then close_out outch;
 315        fullmapath::asserted,true
 316   end
 317 ;;
 318
 319 let assert_ng ~include_paths ?outch mapath =
 320  snd (assert_ng ~include_paths ~already_included:[] ~compiling:[] ~asserted:[]
 321   ?outch mapath)
 322 let get_ast status ~include_paths strm =
 323  snd (get_ast status ~compiling:[] ~asserted:[] ~include_paths strm)