weblib/tutorial/chapter5.ma

   1 (* boolean functions over lists *)
   2
   3 include "basics/list.ma".
   4 include "basics/sets.ma".
   5 include "basics/deqsets.ma".
   6
   7 (********* search *********)
   8
   9 let rec memb (S:DeqSet) (x:S) (l: list S) on l  ≝
  10   match l with
  11   [ nil ⇒ false
  12   | cons a tl ⇒ (x == a) ∨ memb S x tl
  13   ].
  14
  15 notation < "\memb x l" non associative with precedence 90 for @{'memb $x $l}.
  16 interpretation "boolean membership" 'memb a l = (memb ? a l).
  17
  18 lemma memb_hd: ∀S,a,l. memb S a (a::l) = true.
  19 #S #a #l normalize >(proj2 … (eqb_true S …) (refl S a)) //
  20 qed.
  21
  22 lemma memb_cons: ∀S,a,b,l.
  23   memb S a l = true → memb S a (b::l) = true.
  24 #S #a #b #l normalize cases (a==b) normalize //
  25 qed.
  26
  27 lemma memb_single: ∀S,a,x. memb S a [x] = true → a = x.
  28 #S #a #x normalize cases (true_or_false … (a==x)) #H
  29   [#_ >(\P H) // |>H normalize #abs @False_ind /2/]
  30 qed.
  31
  32 lemma memb_append: ∀S,a,l1,l2.
  33 memb S a (l1@l2) = true →
  34   memb S a l1= true ∨ memb S a l2 = true.
  35 #S #a #l1 elim l1 normalize [#l2 #H %2 //]
  36 #b #tl #Hind #l2 cases (a==b) normalize /2/
  37 qed.
  38
  39 lemma memb_append_l1: ∀S,a,l1,l2.
  40  memb S a l1= true → memb S a (l1@l2) = true.
  41 #S #a #l1 elim l1 normalize
  42   [normalize #le #abs @False_ind /2/
  43   |#b #tl #Hind #l2 cases (a==b) normalize /2/
  44   ]
  45 qed.
  46
  47 lemma memb_append_l2: ∀S,a,l1,l2.
  48  memb S a l2= true → memb S a (l1@l2) = true.
  49 #S #a #l1 elim l1 normalize //
  50 #b #tl #Hind #l2 cases (a==b) normalize /2/
  51 qed.
  52
  53 lemma memb_exists: ∀S,a,l.memb S a l = true →
  54   ∃l1,l2.l=l1@(a::l2).
  55 #S #a #l elim l [normalize #abs @False_ind /2/]
  56 #b #tl #Hind #H cases (orb_true_l … H)
  57   [#eqba @(ex_intro … (nil S)) @(ex_intro … tl) >(\P eqba) //
  58   |#mem_tl cases (Hind mem_tl) #l1 * #l2 #eqtl
  59    @(ex_intro … (b::l1)) @(ex_intro … l2) >eqtl //
  60   ]
  61 qed.
  62
  63 lemma not_memb_to_not_eq: ∀S,a,b,l.
  64  memb S a l = false → memb S b l = true → a==b = false.
  65 #S #a #b #l cases (true_or_false (a==b)) //
  66 #eqab >(\P eqab) #H >H #abs @False_ind /2/
  67 qed.
  68
  69 lemma memb_map: ∀S1,S2,f,a,l. memb S1 a l= true →
  70   memb S2 (f a) (map … f l) = true.
  71 #S1 #S2 #f #a #l elim l normalize [//]
  72 #x #tl #memba cases (true_or_false (a==x))
  73   [#eqx >eqx >(\P eqx) >(\b (refl … (f x))) normalize //
  74   |#eqx >eqx cases (f a==f x) normalize /2/
  75   ]
  76 qed.
  77
  78 lemma memb_compose: ∀S1,S2,S3,op,a1,a2,l1,l2.
  79   memb S1 a1 l1 = true → memb S2 a2 l2 = true →
  80   memb S3 (op a1 a2) (compose S1 S2 S3 op l1 l2) = true.
  81 #S1 #S2 #S3 #op #a1 #a2 #l1 elim l1 [normalize //]
  82 #x #tl #Hind #l2 #memba1 #memba2 cases (orb_true_l … memba1)
  83   [#eqa1 >(\P eqa1) @memb_append_l1 @memb_map //
  84   |#membtl @memb_append_l2 @Hind //
  85   ]
  86 qed.
  87
  88 (**************** unicity test *****************)
  89
  90 let rec uniqueb (S:DeqSet) l on l : bool ≝
  91   match l with
  92   [ nil ⇒ true
  93   | cons a tl ⇒ notb (memb S a tl) ∧ uniqueb S tl
  94   ].
  95
  96 (* unique_append l1 l2 add l1 in fornt of l2, but preserving unicity *)
  97
  98 let rec unique_append (S:DeqSet) (l1,l2: list S) on l1 ≝
  99   match l1 with
 100   [ nil ⇒ l2
 101   | cons a tl ⇒
 102      let r ≝ unique_append S tl l2 in
 103      if memb S a r then r else a::r
 104   ].
 105
 106 axiom unique_append_elim: ∀S:DeqSet.∀P: S → Prop.∀l1,l2.
 107 (∀x. memb S x l1 = true → P x) → (∀x. memb S x l2 = true → P x) →
 108 ∀x. memb S x (unique_append S l1 l2) = true → P x.
 109
 110 lemma unique_append_unique: ∀S,l1,l2. uniqueb S l2 = true →
 111   uniqueb S (unique_append S l1 l2) = true.
 112 #S #l1 elim l1 normalize // #a #tl #Hind #l2 #uniquel2
 113 cases (true_or_false … (memb S a (unique_append S tl l2)))
 114 #H >H normalize [@Hind //] >H normalize @Hind //
 115 qed.
 116
 117 (******************* sublist *******************)
 118 definition sublist ≝
 119   λS,l1,l2.∀a. memb S a l1 = true → memb S a l2 = true.
 120
 121 lemma sublist_length: ∀S,l1,l2.
 122  uniqueb S l1 = true → sublist S l1 l2 → |l1| ≤ |l2|.
 123 #S #l1 elim l1 //
 124 #a #tl #Hind #l2 #unique #sub
 125 cut (∃l3,l4.l2=l3@(a::l4)) [@memb_exists @sub //]
 126 * #l3 * #l4 #eql2 >eql2 >length_append normalize
 127 applyS le_S_S <length_append @Hind [@(andb_true_r … unique)]
 128 >eql2 in sub; #sub #x #membx
 129 cases (memb_append … (sub x (orb_true_r2 … membx)))
 130   [#membxl3 @memb_append_l1 //
 131   |#membxal4 cases (orb_true_l … membxal4)
 132     [#eqxa @False_ind lapply (andb_true_l … unique)
 133      <(\P eqxa) >membx normalize /2/ |#membxl4 @memb_append_l2 //
 134     ]
 135   ]
 136 qed.
 137
 138 lemma sublist_unique_append_l1:
 139   ∀S,l1,l2. sublist S l1 (unique_append S l1 l2).
 140 #S #l1 elim l1 normalize [#l2 #S #abs @False_ind /2/]
 141 #x #tl #Hind #l2 #a
 142 normalize cases (true_or_false … (a==x)) #eqax >eqax
 143 [<(\P eqax) cases (true_or_false (memb S a (unique_append S tl l2)))
 144   [#H >H normalize // | #H >H normalize >(\b (refl … a)) //]
 145 |cases (memb S x (unique_append S tl l2)) normalize
 146   [/2/ |>eqax normalize /2/]
 147 ]
 148 qed.
 149
 150 lemma sublist_unique_append_l2:
 151   ∀S,l1,l2. sublist S l2 (unique_append S l1 l2).
 152 #S #l1 elim l1 [normalize //] #x #tl #Hind normalize
 153 #l2 #a cases (memb S x (unique_append S tl l2)) normalize
 154 [@Hind | cases (a==x) normalize // @Hind]
 155 qed.
 156
 157 lemma decidable_sublist:∀S,l1,l2.
 158   (sublist S l1 l2) ∨ ¬(sublist S l1 l2).
 159 #S #l1 #l2 elim l1
 160   [%1 #a normalize in ⊢ (%→?); #abs @False_ind /2/
 161   |#a #tl * #subtl
 162     [cases (true_or_false (memb S a l2)) #memba
 163       [%1 whd #x #membx cases (orb_true_l … membx)
 164         [#eqax >(\P eqax) // |@subtl]
 165       |%2 @(not_to_not … (eqnot_to_noteq … true memba)) #H1 @H1 @memb_hd
 166       ]
 167     |%2 @(not_to_not … subtl) #H1 #x #H2 @H1 @memb_cons //
 168     ]
 169   ]
 170 qed.
 171
 172 (********************* filtering *****************)
 173
 174 lemma filter_true: ∀S,f,a,l.
 175   memb S a (filter S f l) = true → f a = true.
 176 #S #f #a #l elim l [normalize #H @False_ind /2/]
 177 #b #tl #Hind cases (true_or_false (f b)) #H
 178 normalize >H normalize [2:@Hind]
 179 cases (true_or_false (a==b)) #eqab
 180   [#_ >(\P eqab) // | >eqab normalize @Hind]
 181 qed.
 182
 183 lemma memb_filter_memb: ∀S,f,a,l.
 184   memb S a (filter S f l) = true → memb S a l = true.
 185 #S #f #a #l elim l [normalize //]
 186 #b #tl #Hind normalize (cases (f b)) normalize
 187 cases (a==b) normalize // @Hind
 188 qed.
 189
 190 lemma memb_filter: ∀S,f,l,x. memb S x (filter ? f l) = true →
 191 memb S x l = true ∧ (f x = true).
 192 /3/ qed.
 193
 194 lemma memb_filter_l: ∀S,f,x,l. (f x = true) → memb S x l = true →
 195 memb S x (filter ? f l) = true.
 196 #S #f #x #l #fx elim l normalize //
 197 #b #tl #Hind cases (true_or_false (x==b)) #eqxb
 198   [<(\P eqxb) >(\b (refl … x)) >fx normalize >(\b (refl … x)) normalize //
 199   |>eqxb cases (f b) normalize [>eqxb normalize @Hind| @Hind]
 200   ]
 201 qed.
 202
 203 (********************* exists *****************)
 204
 205 let rec exists (A:Type[0]) (p:A → bool) (l:list A) on l : bool ≝
 206 match l with
 207 [ nil ⇒ false
 208 | cons h t ⇒ orb (p h) (exists A p t)
 209 ].
 210
 211 lemma Exists_exists : ∀A,P,l.
 212   Exists A P l →
 213   ∃x. P x.
 214 #A #P #l elim l [ * | #hd #tl #IH * [ #H %{hd} @H | @IH ]
 215 qed.