weblib/tutorial/chapter5.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "re/lang.ma".
  16
  17 inductive re (S: DeqSet) : Type[0] ≝
  18    z: re S
  19  | e: re S
  20  | s: S → re S
  21  | c: re S → re S → re S
  22  | o: re S → re S → re S
  23  | k: re S → re S.
  24
  25 interpretation "re epsilon" 'epsilon = (e ?).
  26 interpretation "re or" 'plus a b = (o ? a b).
  27 interpretation "re cat" 'middot a b = (c ? a b).
  28 interpretation "re star" 'star a = (k ? a).
  29
  30 notation < "a" non associative with precedence 90 for @{ 'ps $a}.
  31 notation > "` term 90 a" non associative with precedence 90 for @{ 'ps $a}.
  32 interpretation "atom" 'ps a = (s ? a).
  33
  34 notation "`∅" non associative with precedence 90 for @{ 'empty }.
  35 interpretation "empty" 'empty = (z ?).
  36
  37 let rec in_l (S : DeqSet) (r : re S) on r : word S → Prop ≝
  38 match r with
  39 [ z ⇒ ∅
  40 | e ⇒ {ϵ}
  41 | s x ⇒ {[x]}
  42 | c r1 r2 ⇒ (in_l ? r1) · (in_l ? r2)
  43 | o r1 r2 ⇒ (in_l ? r1) ∪ (in_l ? r2)
  44 | k r1 ⇒ (in_l ? r1) ^*].
  45
  46 notation "\sem{term 19 E}" non associative with precedence 75 for @{'in_l $E}.
  47 interpretation "in_l" 'in_l E = (in_l ? E).
  48 interpretation "in_l mem" 'mem w l = (in_l ? l w).
  49
  50 lemma rsem_star : ∀S.∀r: re S. \sem{r^*} = \sem{r}^*.
  51 // qed.
  52
  53
  54 (* pointed items *)
  55 inductive pitem (S: DeqSet) : Type[0] ≝
  56    pz: pitem S
  57  | pe: pitem S
  58  | ps: S → pitem S
  59  | pp: S → pitem S
  60  | pc: pitem S → pitem S → pitem S
  61  | po: pitem S → pitem S → pitem S
  62  | pk: pitem S → pitem S.
  63
  64 definition pre ≝ λS.pitem S × bool.
  65
  66 interpretation "pitem star" 'star a = (pk ? a).
  67 interpretation "pitem or" 'plus a b = (po ? a b).
  68 interpretation "pitem cat" 'middot a b = (pc ? a b).
  69 notation < ".a" non associative with precedence 90 for @{ 'pp $a}.
  70 notation > "`. term 90 a" non associative with precedence 90 for @{ 'pp $a}.
  71 interpretation "pitem pp" 'pp a = (pp ? a).
  72 interpretation "pitem ps" 'ps a = (ps ? a).
  73 interpretation "pitem epsilon" 'epsilon = (pe ?).
  74 interpretation "pitem empty" 'empty = (pz ?).
  75
  76 let rec forget (S: DeqSet) (l : pitem S) on l: re S ≝
  77  match l with
  78   [ pz ⇒ `∅
  79   | pe ⇒ ϵ
  80   | ps x ⇒ `x
  81   | pp x ⇒ `x
  82   | pc E1 E2 ⇒ (forget ? E1) · (forget ? E2)
  83   | po E1 E2 ⇒ (forget ? E1) + (forget ? E2)
  84   | pk E ⇒ (forget ? E)^* ].
  85
  86 (* notation < "|term 19 e|" non associative with precedence 70 for @{'forget $e}.*)
  87 interpretation "forget" 'norm a = (forget ? a).
  88
  89 let rec in_pl (S : DeqSet) (r : pitem S) on r : word S → Prop ≝
  90 match r with
  91 [ pz ⇒ ∅
  92 | pe ⇒ ∅
  93 | ps _ ⇒ ∅
  94 | pp x ⇒ { [x] }
  95 | pc r1 r2 ⇒ (in_pl ? r1) · \sem{forget ? r2} ∪ (in_pl ? r2)
  96 | po r1 r2 ⇒ (in_pl ? r1) ∪ (in_pl ? r2)
  97 | pk r1 ⇒ (in_pl ? r1) · \sem{forget ? r1}^*  ].
  98
  99 interpretation "in_pl" 'in_l E = (in_pl ? E).
 100 interpretation "in_pl mem" 'mem w l = (in_pl ? l w).
 101
 102 definition in_prl ≝ λS : DeqSet.λp:pre S.
 103   if (\snd p) then \sem{\fst p} ∪ {ϵ} else \sem{\fst p}.
 104
 105 interpretation "in_prl mem" 'mem w l = (in_prl ? l w).
 106 interpretation "in_prl" 'in_l E = (in_prl ? E).
 107
 108 lemma sem_pre_true : ∀S.∀i:pitem S.
 109   \sem{〈i,true〉} = \sem{i} ∪ {ϵ}.
 110 // qed.
 111
 112 lemma sem_pre_false : ∀S.∀i:pitem S.
 113   \sem{〈i,false〉} = \sem{i}.
 114 // qed.
 115
 116 lemma sem_cat: ∀S.∀i1,i2:pitem S.
 117   \sem{i1 · i2} = \sem{i1} · \sem{|i2|} ∪ \sem{i2}.
 118 // qed.
 119
 120 lemma sem_cat_w: ∀S.∀i1,i2:pitem S.∀w.
 121   \sem{i1 · i2} w = ((\sem{i1} · \sem{|i2|}) w ∨ \sem{i2} w).
 122 // qed.
 123
 124 lemma sem_plus: ∀S.∀i1,i2:pitem S.
 125   \sem{i1 + i2} = \sem{i1} ∪ \sem{i2}.
 126 // qed.
 127
 128 lemma sem_plus_w: ∀S.∀i1,i2:pitem S.∀w.
 129   \sem{i1 + i2} w = (\sem{i1} w ∨ \sem{i2} w).
 130 // qed.
 131
 132 lemma sem_star : ∀S.∀i:pitem S.
 133   \sem{i^*} = \sem{i} · \sem{|i|}^*.
 134 // qed.
 135
 136 lemma sem_star_w : ∀S.∀i:pitem S.∀w.
 137   \sem{i^*} w = (∃w1,w2.w1 @ w2 = w ∧ \sem{i} w1 ∧ \sem{|i|}^* w2).
 138 // qed.
 139
 140 lemma append_eq_nil : ∀S.∀w1,w2:word S. w1 @ w2 = ϵ → w1 = ϵ.
 141 #S #w1 #w2 cases w1 // #a #tl normalize #H destruct qed.
 142
 143 lemma not_epsilon_lp : ∀S:DeqSet.∀e:pitem S. ¬ (ϵ ∈ e).
 144 #S #e elim e normalize /2/
 145   [#r1 #r2 * #n1 #n2 % * /2/ * #w1 * #w2 * * #H
 146    >(append_eq_nil …H…) /2/
 147   |#r1 #r2 #n1 #n2 % * /2/
 148   |#r #n % * #w1 * #w2 * * #H >(append_eq_nil …H…) /2/
 149   ]
 150 qed.
 151
 152 (* lemma 12 *)
 153 lemma epsilon_to_true : ∀S.∀e:pre S. ϵ ∈ e → \snd e = true.
 154 #S * #i #b cases b // normalize #H @False_ind /2/
 155 qed.
 156
 157 lemma true_to_epsilon : ∀S.∀e:pre S. \snd e = true → ϵ ∈ e.
 158 #S * #i #b #btrue normalize in btrue; >btrue %2 //
 159 qed.
 160
 161 definition lo ≝ λS:DeqSet.λa,b:pre S.〈\fst a + \fst b,\snd a ∨ \snd b〉.
 162 notation "a ⊕ b" left associative with precedence 60 for @{'oplus $a $b}.
 163 interpretation "oplus" 'oplus a b = (lo ? a b).
 164
 165 lemma lo_def: ∀S.∀i1,i2:pitem S.∀b1,b2. 〈i1,b1〉⊕〈i2,b2〉=〈i1+i2,b1∨b2〉.
 166 // qed.
 167
 168 definition pre_concat_r ≝ λS:DeqSet.λi:pitem S.λe:pre S.
 169   match e with [ mk_Prod i1 b ⇒ 〈i · i1, b〉].
 170
 171 notation "i ◂ e" left associative with precedence 60 for @{'ltrif $i $e}.
 172 interpretation "pre_concat_r" 'ltrif i e = (pre_concat_r ? i e).
 173
 174 lemma eq_to_ex_eq: ∀S.∀A,B:word S → Prop.
 175   A = B → A =1 B.
 176 #S #A #B #H >H /2/ qed.
 177
 178 lemma sem_pre_concat_r : ∀S,i.∀e:pre S.
 179   \sem{i ◂ e} =1 \sem{i} · \sem{|\fst e|} ∪ \sem{e}.
 180 #S #i * #i1 #b1 cases b1 [2: @eq_to_ex_eq //]
 181 >sem_pre_true >sem_cat >sem_pre_true /2/
 182 qed.
 183
 184 definition lc ≝ λS:DeqSet.λbcast:∀S:DeqSet.pitem S → pre S.λe1:pre S.λi2:pitem S.
 185   match e1 with
 186   [ mk_Prod i1 b1 ⇒ match b1 with
 187     [ true ⇒ (i1 ◂ (bcast ? i2))
 188     | false ⇒ 〈i1 · i2,false〉
 189     ]
 190   ].
 191
 192 definition lift ≝ λS.λf:pitem S →pre S.λe:pre S.
 193   match e with
 194   [ mk_Prod i b ⇒ 〈\fst (f i), \snd (f i) ∨ b〉].
 195
 196 notation "a ▸ b" left associative with precedence 60 for @{'lc eclose $a $b}.
 197 interpretation "lc" 'lc op a b = (lc ? op a b).
 198
 199 definition lk ≝ λS:DeqSet.λbcast:∀S:DeqSet.∀E:pitem S.pre S.λe:pre S.
 200   match e with
 201   [ mk_Prod i1 b1 ⇒
 202     match b1 with
 203     [true ⇒ 〈(\fst (bcast ? i1))^*, true〉
 204     |false ⇒ 〈i1^*,false〉
 205     ]
 206   ].
 207
 208 (* notation < "a \sup ⊛" non associative with precedence 90 for @{'lk $op $a}.*)
 209 interpretation "lk" 'lk op a = (lk ? op a).
 210 notation "a^⊛" non associative with precedence 90 for @{'lk eclose $a}.
 211
 212 notation "•" non associative with precedence 60 for @{eclose ?}.
 213
 214 let rec eclose (S: DeqSet) (i: pitem S) on i : pre S ≝
 215  match i with
 216   [ pz ⇒ 〈 `∅, false 〉
 217   | pe ⇒ 〈 ϵ,  true 〉
 218   | ps x ⇒ 〈 `.x, false〉
 219   | pp x ⇒ 〈 `.x, false 〉
 220   | po i1 i2 ⇒ •i1 ⊕ •i2
 221   | pc i1 i2 ⇒ •i1 ▸ i2
 222   | pk i ⇒ 〈(\fst (•i))^*,true〉].
 223
 224 notation "• x" non associative with precedence 60 for @{'eclose $x}.
 225 interpretation "eclose" 'eclose x = (eclose ? x).
 226
 227 lemma eclose_plus: ∀S:DeqSet.∀i1,i2:pitem S.
 228   •(i1 + i2) = •i1 ⊕ •i2.
 229 // qed.
 230
 231 lemma eclose_dot: ∀S:DeqSet.∀i1,i2:pitem S.
 232   •(i1 · i2) = •i1 ▸ i2.
 233 // qed.
 234
 235 lemma eclose_star: ∀S:DeqSet.∀i:pitem S.
 236   •i^* = 〈(\fst(•i))^*,true〉.
 237 // qed.
 238
 239 definition reclose ≝ λS. lift S (eclose S).
 240 interpretation "reclose" 'eclose x = (reclose ? x).
 241
 242 (* theorem 16: 2 *)
 243 lemma sem_oplus: ∀S:DeqSet.∀e1,e2:pre S.
 244   \sem{e1 ⊕ e2} =1 \sem{e1} ∪ \sem{e2}.
 245 #S * #i1 #b1 * #i2 #b2 #w %
 246   [cases b1 cases b2 normalize /2/ * /3/ * /3/
 247   |cases b1 cases b2 normalize /2/ * /3/ * /3/
 248   ]
 249 qed.
 250
 251 lemma odot_true :
 252   ∀S.∀i1,i2:pitem S.
 253   〈i1,true〉 ▸ i2 = i1 ◂ (•i2).
 254 // qed.
 255
 256 lemma odot_true_bis :
 257   ∀S.∀i1,i2:pitem S.
 258   〈i1,true〉 ▸ i2 = 〈i1 · \fst (•i2), \snd (•i2)〉.
 259 #S #i1 #i2 normalize cases (•i2) // qed.
 260
 261 lemma odot_false:
 262   ∀S.∀i1,i2:pitem S.
 263   〈i1,false〉 ▸ i2 = 〈i1 · i2, false〉.
 264 // qed.
 265
 266 lemma LcatE : ∀S.∀e1,e2:pitem S.
 267   \sem{e1 · e2} = \sem{e1} · \sem{|e2|} ∪ \sem{e2}.
 268 // qed.
 269
 270 lemma erase_dot : ∀S.∀e1,e2:pitem S. |e1 · e2| = c ? (|e1|) (|e2|).
 271 // qed.
 272
 273 lemma erase_plus : ∀S.∀i1,i2:pitem S.
 274   |i1 + i2| = |i1| + |i2|.
 275 // qed.
 276
 277 lemma erase_star : ∀S.∀i:pitem S.|i^*| = |i|^*.
 278 // qed.
 279
 280 lemma erase_bull : ∀S.∀i:pitem S. |\fst (•i)| = |i|.
 281 #S #i elim i //
 282   [ #i1 #i2 #IH1 #IH2 >erase_dot <IH1 >eclose_dot
 283     cases (•i1) #i11 #b1 cases b1 // <IH2 >odot_true_bis //
 284   | #i1 #i2 #IH1 #IH2 >eclose_plus >(erase_plus … i1) <IH1 <IH2
 285     cases (•i1) #i11 #b1 cases (•i2) #i21 #b2 //
 286   | #i #IH >eclose_star >(erase_star … i) <IH cases (•i) //
 287   ]
 288 qed.
 289
 290 lemma sem_eclose_star: ∀S:DeqSet.∀i:pitem S.
 291   \sem{〈i^*,true〉} =1 \sem{〈i,false〉}·\sem{|i|}^* ∪ {ϵ}.
 292 /2/ qed.
 293
 294 (* theorem 16: 1 → 3 *)
 295 lemma odot_dot_aux : ∀S.∀e1:pre S.∀i2:pitem S.
 296    \sem{•i2} =1  \sem{i2} ∪ \sem{|i2|} →
 297    \sem{e1 ▸ i2} =1  \sem{e1} · \sem{|i2|} ∪ \sem{i2}.
 298 #S * #i1 #b1 #i2 cases b1
 299   [2:#th >odot_false >sem_pre_false >sem_pre_false >sem_cat /2/
 300   |#H >odot_true >sem_pre_true @(eqP_trans … (sem_pre_concat_r …))
 301    >erase_bull @eqP_trans [|@(eqP_union_l … H)]
 302     @eqP_trans [|@eqP_union_l[|@union_comm ]]
 303     @eqP_trans [|@eqP_sym @union_assoc ] /3/
 304   ]
 305 qed.
 306
 307 lemma sem_fst: ∀S.∀e:pre S. \sem{\fst e} =1 \sem{e}-{[ ]}.
 308 #S * #i *
 309   [>sem_pre_true normalize in ⊢ (??%?); #w %
 310     [/3/ | * * // #H1 #H2 @False_ind @(absurd …H1 H2)]
 311   |>sem_pre_false normalize in ⊢ (??%?); #w % [ /3/ | * // ]
 312   ]
 313 qed.
 314
 315 lemma item_eps: ∀S.∀i:pitem S. \sem{i} =1 \sem{i}-{[ ]}.
 316 #S #i #w %
 317   [#H whd % // normalize @(not_to_not … (not_epsilon_lp …i)) //
 318   |* //
 319   ]
 320 qed.
 321
 322 lemma sem_fst_aux: ∀S.∀e:pre S.∀i:pitem S.∀A.
 323  \sem{e} =1 \sem{i} ∪ A → \sem{\fst e} =1 \sem{i} ∪ (A - {[ ]}).
 324 #S #e #i #A #seme
 325 @eqP_trans [|@sem_fst]
 326 @eqP_trans [||@eqP_union_r [|@eqP_sym @item_eps]]
 327 @eqP_trans [||@distribute_substract]
 328 @eqP_substract_r //
 329 qed.
 330
 331 (* theorem 16: 1 *)
 332 theorem sem_bull: ∀S:DeqSet. ∀e:pitem S.  \sem{•e} =1 \sem{e} ∪ \sem{|e|}.
 333 #S #e elim e
 334   [#w normalize % [/2/ | * //]
 335   |/2/
 336   |#x normalize #w % [ /2/ | * [@False_ind | //]]
 337   |#x normalize #w % [ /2/ | * // ]
 338   |#i1 #i2 #IH1 #IH2 >eclose_dot
 339    @eqP_trans [|@odot_dot_aux //] >sem_cat
 340    @eqP_trans
 341      [|@eqP_union_r
 342        [|@eqP_trans [|@(cat_ext_l … IH1)] @distr_cat_r]]
 343    @eqP_trans [|@union_assoc]
 344    @eqP_trans [||@eqP_sym @union_assoc]
 345    @eqP_union_l //
 346   |#i1 #i2 #IH1 #IH2 >eclose_plus
 347    @eqP_trans [|@sem_oplus] >sem_plus >erase_plus
 348    @eqP_trans [|@(eqP_union_l … IH2)]
 349    @eqP_trans [|@eqP_sym @union_assoc]
 350    @eqP_trans [||@union_assoc] @eqP_union_r
 351    @eqP_trans [||@eqP_sym @union_assoc]
 352    @eqP_trans [||@eqP_union_l [|@union_comm]]
 353    @eqP_trans [||@union_assoc] /2/
 354   |#i #H >sem_pre_true >sem_star >erase_bull >sem_star
 355    @eqP_trans [|@eqP_union_r [|@cat_ext_l [|@sem_fst_aux //]]]
 356    @eqP_trans [|@eqP_union_r [|@distr_cat_r]]
 357    @eqP_trans [|@union_assoc] @eqP_union_l >erase_star
 358    @eqP_sym @star_fix_eps
 359   ]
 360 qed.
 361
 362 definition lifted_cat ≝ λS:DeqSet.λe:pre S.
 363   lift S (lc S eclose e).
 364
 365 notation "e1 ⊙ e2" left associative with precedence 70 for @{'odot $e1 $e2}.
 366
 367 interpretation "lifted cat" 'odot e1 e2 = (lifted_cat ? e1 e2).
 368
 369 lemma odot_true_b : ∀S.∀i1,i2:pitem S.∀b.
 370   〈i1,true〉 ⊙ 〈i2,b〉 = 〈i1 · (\fst (•i2)),\snd (•i2) ∨ b〉.
 371 #S #i1 #i2 #b normalize in ⊢ (??%?); cases (•i2) //
 372 qed.
 373
 374 lemma odot_false_b : ∀S.∀i1,i2:pitem S.∀b.
 375   〈i1,false〉 ⊙ 〈i2,b〉 = 〈i1 · i2 ,b〉.
 376 //
 377 qed.
 378
 379 lemma erase_odot:∀S.∀e1,e2:pre S.
 380   |\fst (e1 ⊙ e2)| = |\fst e1| · (|\fst e2|).
 381 #S * #i1 * * #i2 #b2 // >odot_true_b //
 382 qed.
 383
 384 lemma ostar_true: ∀S.∀i:pitem S.
 385   〈i,true〉^⊛ = 〈(\fst (•i))^*, true〉.
 386 // qed.
 387
 388 lemma ostar_false: ∀S.∀i:pitem S.
 389   〈i,false〉^⊛ = 〈i^*, false〉.
 390 // qed.
 391
 392 lemma erase_ostar: ∀S.∀e:pre S.
 393   |\fst (e^⊛)| = |\fst e|^*.
 394 #S * #i * // qed.
 395
 396 lemma sem_odot_true: ∀S:DeqSet.∀e1:pre S.∀i.
 397   \sem{e1 ⊙ 〈i,true〉} =1 \sem{e1 ▸ i} ∪ { [ ] }.
 398 #S #e1 #i
 399 cut (e1 ⊙ 〈i,true〉 = 〈\fst (e1 ▸ i), \snd(e1 ▸ i) ∨ true〉) [//]
 400 #H >H cases (e1 ▸ i) #i1 #b1 cases b1
 401   [>sem_pre_true @eqP_trans [||@eqP_sym @union_assoc]
 402    @eqP_union_l /2/
 403   |/2/
 404   ]
 405 qed.
 406
 407 lemma eq_odot_false: ∀S:DeqSet.∀e1:pre S.∀i.
 408   e1 ⊙ 〈i,false〉 = e1 ▸ i.
 409 #S #e1 #i
 410 cut (e1 ⊙ 〈i,false〉 = 〈\fst (e1 ▸ i), \snd(e1 ▸ i) ∨ false〉) [//]
 411 cases (e1 ▸ i) #i1 #b1 cases b1 #H @H
 412 qed.
 413
 414 lemma sem_odot:
 415   ∀S.∀e1,e2: pre S. \sem{e1 ⊙ e2} =1 \sem{e1}· \sem{|\fst e2|} ∪ \sem{e2}.
 416 #S #e1 * #i2 *
 417   [>sem_pre_true
 418    @eqP_trans [|@sem_odot_true]
 419    @eqP_trans [||@union_assoc] @eqP_union_r @odot_dot_aux //
 420   |>sem_pre_false >eq_odot_false @odot_dot_aux //
 421   ]
 422 qed.
 423
 424 (* theorem 16: 4 *)
 425 theorem sem_ostar: ∀S.∀e:pre S.
 426   \sem{e^⊛} =1  \sem{e} · \sem{|\fst e|}^*.
 427 #S * #i #b cases b
 428   [>sem_pre_true >sem_pre_true >sem_star >erase_bull
 429    @eqP_trans [|@eqP_union_r[|@cat_ext_l [|@sem_fst_aux //]]]
 430    @eqP_trans [|@eqP_union_r [|@distr_cat_r]]
 431    @eqP_trans [||@eqP_sym @distr_cat_r]
 432    @eqP_trans [|@union_assoc] @eqP_union_l
 433    @eqP_trans [||@eqP_sym @epsilon_cat_l] @eqP_sym @star_fix_eps
 434   |>sem_pre_false >sem_pre_false >sem_star /2/
 435   ]
 436 qed.
 437