components/acic_content/termAcicContent.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = CicNotationPt
  31
  32 let debug = false
  33 let debug_print s = if debug then prerr_endline (Lazy.force s) else ()
  34
  35 type interpretation_id = int
  36
  37 let idref id t = Ast.AttributedTerm (`IdRef id, t)
  38
  39 type term_info =
  40   { sort: (Cic.id, Ast.sort_kind) Hashtbl.t;
  41     uri: (Cic.id, UriManager.uri) Hashtbl.t;
  42   }
  43
  44 let get_types uri =
  45   let o,_ = CicEnvironment.get_obj CicUniv.oblivion_ugraph uri in
  46     match o with
  47       | Cic.InductiveDefinition (l,_,lpsno,_) -> l, lpsno
  48       | _ -> assert false
  49
  50 let name_of_inductive_type uri i =
  51   let types, _ = get_types uri in
  52   let (name, _, _, _) = try List.nth types i with Not_found -> assert false in
  53   name
  54
  55   (* returns <name, type> pairs *)
  56 let constructors_of_inductive_type uri i =
  57   let types, _ = get_types uri in
  58   let (_, _, _, constructors) =
  59     try List.nth types i with Not_found -> assert false
  60   in
  61   constructors
  62
  63   (* returns name only *)
  64 let constructor_of_inductive_type uri i j =
  65   (try
  66     fst (List.nth (constructors_of_inductive_type uri i) (j-1))
  67   with Not_found -> assert false)
  68
  69   (* returns the number of left parameters *)
  70 let left_params_no_of_inductive_type uri =
  71    snd (get_types uri)
  72
  73 let ast_of_acic0 ~output_type term_info acic k =
  74   let k = k term_info in
  75   let id_to_uris = term_info.uri in
  76   let register_uri id uri = Hashtbl.add id_to_uris id uri in
  77   let sort_of_id id =
  78     try
  79       Hashtbl.find term_info.sort id
  80     with Not_found ->
  81       prerr_endline (sprintf "warning: sort of id %s not found, using Type" id);
  82       `Type (CicUniv.fresh ())
  83   in
  84   let aux_substs substs =
  85     Some
  86       (List.map
  87         (fun (uri, annterm) -> (UriManager.name_of_uri uri, k annterm))
  88         substs)
  89   in
  90   let aux_context context =
  91     List.map
  92       (function
  93         | None -> None
  94         | Some annterm -> Some (k annterm))
  95       context
  96   in
  97   let aux = function
  98     | Cic.ARel (id,_,_,b) -> idref id (Ast.Ident (b, None))
  99     | Cic.AVar (id,uri,substs) ->
 100         register_uri id uri;
 101         idref id (Ast.Ident (UriManager.name_of_uri uri, aux_substs substs))
 102     | Cic.AMeta (id,n,l) -> idref id (Ast.Meta (n, aux_context l))
 103     | Cic.ASort (id,Cic.Prop) -> idref id (Ast.Sort `Prop)
 104     | Cic.ASort (id,Cic.Set) -> idref id (Ast.Sort `Set)
 105     | Cic.ASort (id,Cic.Type u) -> idref id (Ast.Sort (`Type u))
 106     | Cic.ASort (id,Cic.CProp) -> idref id (Ast.Sort `CProp)
 107     | Cic.AImplicit (id, Some `Hole) -> idref id Ast.UserInput
 108     | Cic.AImplicit (id, _) -> idref id Ast.Implicit
 109     | Cic.AProd (id,n,s,t) ->
 110         let binder_kind =
 111           match sort_of_id id with
 112           | `Set | `Type _ -> `Pi
 113           | `Prop | `CProp -> `Forall
 114         in
 115         idref id (Ast.Binder (binder_kind,
 116           (CicNotationUtil.name_of_cic_name n, Some (k s)), k t))
 117     | Cic.ACast (id,v,t) -> idref id (Ast.Cast (k v, k t))
 118     | Cic.ALambda (id,n,s,t) ->
 119         idref id (Ast.Binder (`Lambda,
 120           (CicNotationUtil.name_of_cic_name n, Some (k s)), k t))
 121     | Cic.ALetIn (id,n,s,ty,t) ->
 122         idref id (Ast.LetIn ((CicNotationUtil.name_of_cic_name n, Some (k ty)),
 123           k s, k t))
 124     | Cic.AAppl (aid,(Cic.AConst _ as he::tl as args))
 125     | Cic.AAppl (aid,(Cic.AMutInd _ as he::tl as args))
 126     | Cic.AAppl (aid,(Cic.AMutConstruct _ as he::tl as args)) as t ->
 127        let last_n n l =
 128          let rec aux =
 129           function
 130              [] -> assert false
 131            | [_] as l -> l,1
 132            | he::tl ->
 133               let (res,len) as res' = aux tl in
 134                if len < n then
 135                 he::res,len + 1
 136                else
 137                 res'
 138          in
 139           match fst (aux l) with
 140              [] -> assert false
 141            | [t] -> t
 142            | Ast.AttributedTerm (_,(Ast.Appl l))::tl ->
 143                idref aid (Ast.Appl (l@tl))
 144            | l -> idref aid (Ast.Appl l)
 145        in
 146        (match LibraryObjects.destroy_nat t with
 147        | Some n -> idref aid (Ast.Num (string_of_int n, -1))
 148        | None ->
 149            let deannot_he = Deannotate.deannotate_term he in
 150            if CoercDb.is_a_coercion' deannot_he && !Acic2content.hide_coercions
 151            then
 152              (match CoercDb.is_a_coercion_to_funclass deannot_he with
 153              | None -> idref aid (last_n 1 (List.map k tl))
 154              | Some i -> idref aid (last_n (i+1) (List.map k tl)))
 155            else
 156              idref aid (Ast.Appl (List.map k args)))
 157     | Cic.AAppl (aid,args) ->
 158         idref aid (Ast.Appl (List.map k args))
 159     | Cic.AConst (id,uri,substs) ->
 160         register_uri id uri;
 161         idref id (Ast.Ident (UriManager.name_of_uri uri, aux_substs substs))
 162     | Cic.AMutInd (id,uri,i,substs) ->
 163         let name = name_of_inductive_type uri i in
 164         let uri_str = UriManager.string_of_uri uri in
 165         let puri_str = sprintf "%s#xpointer(1/%d)" uri_str (i+1) in
 166         register_uri id (UriManager.uri_of_string puri_str);
 167         idref id (Ast.Ident (name, aux_substs substs))
 168     | Cic.AMutConstruct (id,uri,i,j,substs) ->
 169         let name = constructor_of_inductive_type uri i j in
 170         let uri_str = UriManager.string_of_uri uri in
 171         let puri_str = sprintf "%s#xpointer(1/%d/%d)" uri_str (i + 1) j in
 172         register_uri id (UriManager.uri_of_string puri_str);
 173         idref id (Ast.Ident (name, aux_substs substs))
 174     | Cic.AMutCase (id,uri,typeno,ty,te,patterns) ->
 175         let name = name_of_inductive_type uri typeno in
 176         let uri_str = UriManager.string_of_uri uri in
 177         let puri_str = sprintf "%s#xpointer(1/%d)" uri_str (typeno+1) in
 178         let ctor_puri j =
 179           UriManager.uri_of_string
 180             (sprintf "%s#xpointer(1/%d/%d)" uri_str (typeno+1) j)
 181         in
 182         let case_indty = name, Some (UriManager.uri_of_string puri_str) in
 183         let constructors = constructors_of_inductive_type uri typeno in
 184         let lpsno = left_params_no_of_inductive_type uri in
 185         let rec eat_branch n ty pat =
 186           match (ty, pat) with
 187           | Cic.Prod (_, _, t), _ when n > 0 -> eat_branch (pred n) t pat
 188           | Cic.Prod (_, _, t), Cic.ALambda (_, name, s, t') ->
 189               let (cv, rhs) = eat_branch 0 t t' in
 190               (CicNotationUtil.name_of_cic_name name, Some (k s)) :: cv, rhs
 191           | _, _ -> [], k pat
 192         in
 193         let j = ref 0 in
 194         let patterns =
 195           try
 196             List.map2
 197               (fun (name, ty) pat ->
 198                 incr j;
 199                 let name,(capture_variables,rhs) =
 200                  match output_type with
 201                     `Term -> name, eat_branch lpsno ty pat
 202                   | `Pattern -> "_", ([], k pat)
 203                 in
 204                  Ast.Pattern (name, Some (ctor_puri !j), capture_variables), rhs
 205               ) constructors patterns
 206           with Invalid_argument _ -> assert false
 207         in
 208         let indty =
 209          match output_type with
 210             `Pattern -> None
 211           | `Term -> Some case_indty
 212         in
 213         idref id (Ast.Case (k te, indty, Some (k ty), patterns))
 214     | Cic.AFix (id, no, funs) ->
 215         let defs =
 216           List.map
 217             (fun (_, n, decr_idx, ty, bo) ->
 218               let params,bo =
 219                let rec aux =
 220                 function
 221                    Cic.ALambda (_,name,so,ta) ->
 222                     let params,rest = aux ta in
 223                      (CicNotationUtil.name_of_cic_name name,Some (k so))::
 224                       params, rest
 225                  | t -> [],t
 226                in
 227                 aux bo
 228               in
 229               let ty =
 230                let rec eat_pis =
 231                 function
 232                    0,ty -> ty
 233                  | n,Cic.AProd (_,_,_,ta) -> eat_pis (n - 1,ta)
 234                  | n,ty ->
 235                     (* I should do a whd here, but I have no context *)
 236                     assert false
 237                in
 238                 eat_pis ((List.length params),ty)
 239               in
 240                (params,(Ast.Ident (n, None), Some (k ty)), k bo, decr_idx))
 241             funs
 242         in
 243         let name =
 244           try
 245             (match List.nth defs no with
 246             | _, (Ast.Ident (n, _), _), _, _ when n <> "_" -> n
 247             | _ -> assert false)
 248           with Not_found -> assert false
 249         in
 250          idref id (Ast.LetRec (`Inductive, defs, Ast.Ident (name, None)))
 251     | Cic.ACoFix (id, no, funs) ->
 252         let defs =
 253           List.map
 254             (fun (_, n, ty, bo) ->
 255               let params,bo =
 256                let rec aux =
 257                 function
 258                    Cic.ALambda (_,name,so,ta) ->
 259                     let params,rest = aux ta in
 260                      (CicNotationUtil.name_of_cic_name name,Some (k so))::
 261                       params, rest
 262                  | t -> [],t
 263                in
 264                 aux bo
 265               in
 266               let ty =
 267                let rec eat_pis =
 268                 function
 269                    0,ty -> ty
 270                  | n,Cic.AProd (_,_,_,ta) -> eat_pis (n - 1,ta)
 271                  | n,ty ->
 272                     (* I should do a whd here, but I have no context *)
 273                     assert false
 274                in
 275                 eat_pis ((List.length params),ty)
 276               in
 277                (params,(Ast.Ident (n, None), Some (k ty)), k bo, 0))
 278             funs
 279         in
 280         let name =
 281           try
 282             (match List.nth defs no with
 283             | _, (Ast.Ident (n, _), _), _, _ when n <> "_" -> n
 284             | _ -> assert false)
 285           with Not_found -> assert false
 286         in
 287         idref id (Ast.LetRec (`CoInductive, defs, Ast.Ident (name, None)))
 288   in
 289   aux acic
 290
 291   (* persistent state *)
 292
 293 let level2_patterns32 = Hashtbl.create 211
 294 let interpretations = Hashtbl.create 211  (* symb -> id list ref *)
 295
 296 let compiled32 = ref None
 297 let pattern32_matrix = ref []
 298
 299 let get_compiled32 () =
 300   match !compiled32 with
 301   | None -> assert false
 302   | Some f -> Lazy.force f
 303
 304 let set_compiled32 f = compiled32 := Some f
 305
 306 let add_idrefs =
 307   List.fold_right (fun idref t -> Ast.AttributedTerm (`IdRef idref, t))
 308
 309 let instantiate32 term_info idrefs env symbol args =
 310   let rec instantiate_arg = function
 311     | Ast.IdentArg (n, name) ->
 312         let t = (try List.assoc name env with Not_found -> assert false) in
 313         let rec count_lambda = function
 314           | Ast.AttributedTerm (_, t) -> count_lambda t
 315           | Ast.Binder (`Lambda, _, body) -> 1 + count_lambda body
 316           | _ -> 0
 317         in
 318         let rec add_lambda t n =
 319           if n > 0 then
 320             let name = CicNotationUtil.fresh_name () in
 321             Ast.Binder (`Lambda, (Ast.Ident (name, None), None),
 322               Ast.Appl [add_lambda t (n - 1); Ast.Ident (name, None)])
 323           else
 324             t
 325         in
 326         add_lambda t (n - count_lambda t)
 327   in
 328   let head =
 329     let symbol = Ast.Symbol (symbol, 0) in
 330     add_idrefs idrefs symbol
 331   in
 332   if args = [] then head
 333   else Ast.Appl (head :: List.map instantiate_arg args)
 334
 335 let rec ast_of_acic1 ~output_type term_info annterm =
 336   let id_to_uris = term_info.uri in
 337   let register_uri id uri = Hashtbl.add id_to_uris id uri in
 338   match (get_compiled32 ()) annterm with
 339   | None ->
 340      ast_of_acic0 ~output_type term_info annterm (ast_of_acic1 ~output_type)
 341   | Some (env, ctors, pid) ->
 342       let idrefs =
 343         List.map
 344           (fun annterm ->
 345             let idref = CicUtil.id_of_annterm annterm in
 346             (try
 347               register_uri idref
 348                 (CicUtil.uri_of_term (Deannotate.deannotate_term annterm))
 349             with Invalid_argument _ -> ());
 350             idref)
 351           ctors
 352       in
 353       let env' =
 354        List.map
 355         (fun (name, term) -> name, ast_of_acic1 ~output_type term_info term) env
 356       in
 357       let _, symbol, args, _ =
 358         try
 359           Hashtbl.find level2_patterns32 pid
 360         with Not_found -> assert false
 361       in
 362       let ast = instantiate32 term_info idrefs env' symbol args in
 363       Ast.AttributedTerm (`IdRef (CicUtil.id_of_annterm annterm), ast)
 364
 365 let load_patterns32 t =
 366   let t =
 367     HExtlib.filter_map (function (true, ap, id) -> Some (ap, id) | _ -> None) t
 368   in
 369   set_compiled32 (lazy (Acic2astMatcher.Matcher32.compiler t))
 370
 371 let ast_of_acic ~output_type id_to_sort annterm =
 372   debug_print (lazy ("ast_of_acic <- "
 373     ^ CicPp.ppterm (Deannotate.deannotate_term annterm)));
 374   let term_info = { sort = id_to_sort; uri = Hashtbl.create 211 } in
 375   let ast = ast_of_acic1 ~output_type term_info annterm in
 376   debug_print (lazy ("ast_of_acic -> " ^ CicNotationPp.pp_term ast));
 377   ast, term_info.uri
 378
 379 let counter = ref ~-1
 380 let reset () = counter := ~-1;;
 381 let fresh_id =
 382   fun () ->
 383     incr counter;
 384     !counter
 385
 386 let add_interpretation dsc (symbol, args) appl_pattern =
 387   let id = fresh_id () in
 388   Hashtbl.add level2_patterns32 id (dsc, symbol, args, appl_pattern);
 389   pattern32_matrix := (true, appl_pattern, id) :: !pattern32_matrix;
 390   load_patterns32 !pattern32_matrix;
 391   (try
 392     let ids = Hashtbl.find interpretations symbol in
 393     ids := id :: !ids
 394   with Not_found -> Hashtbl.add interpretations symbol (ref [id]));
 395   id
 396
 397 let get_all_interpretations () =
 398   List.map
 399     (function (_, _, id) ->
 400       let (dsc, _, _, _) =
 401         try
 402           Hashtbl.find level2_patterns32 id
 403         with Not_found -> assert false
 404       in
 405       (id, dsc))
 406     !pattern32_matrix
 407
 408 let get_active_interpretations () =
 409   HExtlib.filter_map (function (true, _, id) -> Some id | _ -> None)
 410     !pattern32_matrix
 411
 412 let set_active_interpretations ids =
 413   let pattern32_matrix' =
 414     List.map
 415       (function
 416         | (_, ap, id) when List.mem id ids -> (true, ap, id)
 417         | (_, ap, id) -> (false, ap, id))
 418       !pattern32_matrix
 419   in
 420   pattern32_matrix := pattern32_matrix';
 421   load_patterns32 !pattern32_matrix
 422
 423 exception Interpretation_not_found
 424
 425 let lookup_interpretations symbol =
 426   try
 427    HExtlib.list_uniq
 428     (List.sort Pervasives.compare
 429      (List.map
 430       (fun id ->
 431         let (dsc, _, args, appl_pattern) =
 432           try
 433             Hashtbl.find level2_patterns32 id
 434           with Not_found -> assert false
 435         in
 436         dsc, args, appl_pattern)
 437       !(Hashtbl.find interpretations symbol)))
 438   with Not_found -> raise Interpretation_not_found
 439
 440 let remove_interpretation id =
 441   (try
 442     let _, symbol, _, _ = Hashtbl.find level2_patterns32 id in
 443     let ids = Hashtbl.find interpretations symbol in
 444     ids := List.filter ((<>) id) !ids;
 445     Hashtbl.remove level2_patterns32 id;
 446   with Not_found -> raise Interpretation_not_found);
 447   pattern32_matrix :=
 448     List.filter (fun (_, _, id') -> id <> id') !pattern32_matrix;
 449   load_patterns32 !pattern32_matrix
 450
 451 let _ = load_patterns32 []
 452
 453 let instantiate_appl_pattern env appl_pattern =
 454   let lookup name =
 455     try List.assoc name env
 456     with Not_found ->
 457       prerr_endline (sprintf "Name %s not found" name);
 458       assert false
 459   in
 460   let rec aux = function
 461     | Ast.UriPattern uri -> CicUtil.term_of_uri uri
 462     | Ast.ImplicitPattern -> Cic.Implicit None
 463     | Ast.VarPattern name -> lookup name
 464     | Ast.ApplPattern terms -> Cic.Appl (List.map aux terms)
 465   in
 466   aux appl_pattern
 467