matita/matita/contribs/lambdadelta/basic_2/rt_computation/fpbg.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_2_3.ma".
  16 include "basic_2/notation/relations/predsubtystarproper_6.ma".
  17 include "basic_2/rt_transition/fpb.ma".
  18 include "basic_2/rt_computation/fpbs.ma".
  19
  20 (* PROPER PARALLEL RST-COMPUTATION FOR CLOSURES *****************************)
  21
  22 definition fpbg: tri_relation genv lenv term ≝
  23            λG1,L1,T1,G2,L2,T2.
  24            ∃∃G,L,T. ❪G1,L1,T1❫ ≻ ❪G,L,T❫ & ❪G,L,T❫ ≥ ❪G2,L2,T2❫.
  25
  26 interpretation "proper parallel rst-computation (closure)"
  27    'PRedSubTyStarProper G1 L1 T1 G2 L2 T2 = (fpbg G1 L1 T1 G2 L2 T2).
  28
  29 (* Basic properties *********************************************************)
  30
  31 lemma fpb_fpbg:
  32       ∀G1,G2,L1,L2,T1,T2.
  33       ❪G1,L1,T1❫ ≻ ❪G2,L2,T2❫ → ❪G1,L1,T1❫ > ❪G2,L2,T2❫.
  34 /2 width=5 by ex2_3_intro/ qed.
  35
  36 lemma fpbg_fpbq_trans:
  37       ∀G1,G,G2,L1,L,L2,T1,T,T2.
  38       ❪G1,L1,T1❫ > ❪G,L,T❫ → ❪G,L,T❫ ≽ ❪G2,L2,T2❫ →
  39       ❪G1,L1,T1❫ > ❪G2,L2,T2❫.
  40 #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 *
  41 /3 width=9 by fpbs_strap1, ex2_3_intro/
  42 qed-.
  43
  44 lemma fpbg_fqu_trans:
  45       ∀G1,G,G2,L1,L,L2,T1,T,T2.
  46       ❪G1,L1,T1❫ > ❪G,L,T❫ → ❪G,L,T❫ ⬂ ❪G2,L2,T2❫ →
  47       ❪G1,L1,T1❫ > ❪G2,L2,T2❫.
  48 #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #H1 #H2
  49 /4 width=5 by fpbg_fpbq_trans, fpbq_fquq, fqu_fquq/
  50 qed-.
  51
  52 (* Note: this is used in the closure proof *)
  53 lemma fpbg_fpbs_trans:
  54       ∀G,G2,L,L2,T,T2. ❪G,L,T❫ ≥ ❪G2,L2,T2❫ →
  55       ∀G1,L1,T1. ❪G1,L1,T1❫ > ❪G,L,T❫ → ❪G1,L1,T1❫ > ❪G2,L2,T2❫.
  56 #G #G2 #L #L2 #T #T2 #H @(fpbs_ind_dx … H) -G -L -T /3 width=5 by fpbg_fpbq_trans/
  57 qed-.
  58
  59 (* Basic_2A1: uses: fpbg_fleq_trans *)
  60 lemma fpbg_feqx_trans:
  61       ∀G1,G,L1,L,T1,T. ❪G1,L1,T1❫ > ❪G,L,T❫ →
  62       ∀G2,L2,T2. ❪G,L,T❫ ≛ ❪G2,L2,T2❫ → ❪G1,L1,T1❫ > ❪G2,L2,T2❫.
  63 /3 width=5 by fpbg_fpbq_trans, fpbq_feqx/ qed-.
  64
  65 (* Properties with t-bound rt-transition for terms **************************)
  66
  67 lemma cpm_tneqx_cpm_fpbg (h) (G) (L):
  68       ∀n1,T1,T. ❪G,L❫ ⊢ T1 ➡[h,n1] T → (T1 ≛ T → ⊥) →
  69       ∀n2,T2. ❪G,L❫ ⊢ T ➡[h,n2] T2 → ❪G,L,T1❫ > ❪G,L,T2❫.
  70 /4 width=5 by fpbq_fpbs, cpm_fpbq, cpm_fpb, ex2_3_intro/ qed.