matita/matita/contribs/lambdadelta/basic_2/rt_computation/fpbg.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/predsubtystarproper_7.ma".
  16 include "basic_2/rt_transition/fpb.ma".
  17 include "basic_2/rt_computation/fpbs.ma".
  18
  19 (* PROPER PARALLEL RST-COMPUTATION FOR CLOSURES *****************************)
  20
  21 definition fpbg: ∀h. tri_relation genv lenv term ≝
  22                  λh,G1,L1,T1,G2,L2,T2.
  23                  ∃∃G,L,T. ⦃G1, L1, T1⦄ ≻[h] ⦃G, L, T⦄ & ⦃G, L, T⦄ ≥[h] ⦃G2, L2, T2⦄.
  24
  25 interpretation "proper parallel rst-computation (closure)"
  26    'PRedSubTyStarProper h G1 L1 T1 G2 L2 T2 = (fpbg h G1 L1 T1 G2 L2 T2).
  27
  28 (* Basic properties *********************************************************)
  29
  30 lemma fpb_fpbg: ∀h,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≻[h] ⦃G2, L2, T2⦄ →
  31                 ⦃G1, L1, T1⦄ >[h] ⦃G2, L2, T2⦄.
  32 /2 width=5 by ex2_3_intro/ qed.
  33
  34 lemma fpbg_fpbq_trans: ∀h,G1,G,G2,L1,L,L2,T1,T,T2.
  35                        ⦃G1, L1, T1⦄ >[h] ⦃G, L, T⦄ → ⦃G, L, T⦄ ≽[h] ⦃G2, L2, T2⦄ →
  36                        ⦃G1, L1, T1⦄ >[h] ⦃G2, L2, T2⦄.
  37 #h #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 *
  38 /3 width=9 by fpbs_strap1, ex2_3_intro/
  39 qed-.
  40
  41 (* Note: this is used in the closure proof *)
  42 lemma fpbg_fpbs_trans: ∀h,G,G2,L,L2,T,T2. ⦃G, L, T⦄ ≥[h] ⦃G2, L2, T2⦄ →
  43                        ∀G1,L1,T1. ⦃G1, L1, T1⦄ >[h] ⦃G, L, T⦄ → ⦃G1, L1, T1⦄ >[h] ⦃G2, L2, T2⦄.
  44 #h #G #G2 #L #L2 #T #T2 #H @(fpbs_ind_dx … H) -G -L -T /3 width=5 by fpbg_fpbq_trans/
  45 qed-.
  46
  47 (* Basic_2A1: uses: fpbg_fleq_trans *)
  48 lemma fpbg_fdeq_trans: ∀h,G1,G,L1,L,T1,T. ⦃G1, L1, T1⦄ >[h] ⦃G, L, T⦄ →
  49                        ∀G2,L2,T2. ⦃G, L, T⦄ ≛ ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ >[h] ⦃G2, L2, T2⦄.
  50 /3 width=5 by fpbg_fpbq_trans, fpbq_fdeq/ qed-.
  51
  52 (* Properties with t-bound rt-transition for terms **************************)
  53
  54 lemma cpm_tdneq_cpm_fpbg (h) (G) (L):
  55                          ∀n1,T1,T. ⦃G, L⦄ ⊢ T1 ➡[n1,h] T → (T1 ≛ T → ⊥) →
  56                          ∀n2,T2. ⦃G, L⦄ ⊢ T ➡[n2,h] T2 → ⦃G, L, T1⦄ >[h] ⦃G, L, T2⦄.
  57 /4 width=5 by fpbq_fpbs, cpm_fpbq, cpm_fpb, ex2_3_intro/ qed.