matita/matita/contribs/lambdadelta/basic_2/rt_computation/fpbg.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/xoa/ex_2_3.ma".
  16 include "basic_2/notation/relations/predsubtystarproper_7.ma".
  17 include "basic_2/rt_transition/fpb.ma".
  18 include "basic_2/rt_computation/fpbs.ma".
  19
  20 (* PROPER PARALLEL RST-COMPUTATION FOR CLOSURES *****************************)
  21
  22 definition fpbg: ∀h. tri_relation genv lenv term ≝
  23                  λh,G1,L1,T1,G2,L2,T2.
  24                  ∃∃G,L,T. ❪G1,L1,T1❫ ≻[h] ❪G,L,T❫ & ❪G,L,T❫ ≥[h] ❪G2,L2,T2❫.
  25
  26 interpretation "proper parallel rst-computation (closure)"
  27    'PRedSubTyStarProper h G1 L1 T1 G2 L2 T2 = (fpbg h G1 L1 T1 G2 L2 T2).
  28
  29 (* Basic properties *********************************************************)
  30
  31 lemma fpb_fpbg: ∀h,G1,G2,L1,L2,T1,T2. ❪G1,L1,T1❫ ≻[h] ❪G2,L2,T2❫ →
  32                 ❪G1,L1,T1❫ >[h] ❪G2,L2,T2❫.
  33 /2 width=5 by ex2_3_intro/ qed.
  34
  35 lemma fpbg_fpbq_trans: ∀h,G1,G,G2,L1,L,L2,T1,T,T2.
  36                        ❪G1,L1,T1❫ >[h] ❪G,L,T❫ → ❪G,L,T❫ ≽[h] ❪G2,L2,T2❫ →
  37                        ❪G1,L1,T1❫ >[h] ❪G2,L2,T2❫.
  38 #h #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 *
  39 /3 width=9 by fpbs_strap1, ex2_3_intro/
  40 qed-.
  41
  42 lemma fpbg_fqu_trans (h): ∀G1,G,G2,L1,L,L2,T1,T,T2.
  43                           ❪G1,L1,T1❫ >[h] ❪G,L,T❫ → ❪G,L,T❫ ⬂ ❪G2,L2,T2❫ →
  44                           ❪G1,L1,T1❫ >[h] ❪G2,L2,T2❫.
  45 #h #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #H1 #H2
  46 /4 width=5 by fpbg_fpbq_trans, fpbq_fquq, fqu_fquq/
  47 qed-.
  48
  49 (* Note: this is used in the closure proof *)
  50 lemma fpbg_fpbs_trans: ∀h,G,G2,L,L2,T,T2. ❪G,L,T❫ ≥[h] ❪G2,L2,T2❫ →
  51                        ∀G1,L1,T1. ❪G1,L1,T1❫ >[h] ❪G,L,T❫ → ❪G1,L1,T1❫ >[h] ❪G2,L2,T2❫.
  52 #h #G #G2 #L #L2 #T #T2 #H @(fpbs_ind_dx … H) -G -L -T /3 width=5 by fpbg_fpbq_trans/
  53 qed-.
  54
  55 (* Basic_2A1: uses: fpbg_fleq_trans *)
  56 lemma fpbg_feqx_trans: ∀h,G1,G,L1,L,T1,T. ❪G1,L1,T1❫ >[h] ❪G,L,T❫ →
  57                        ∀G2,L2,T2. ❪G,L,T❫ ≛ ❪G2,L2,T2❫ → ❪G1,L1,T1❫ >[h] ❪G2,L2,T2❫.
  58 /3 width=5 by fpbg_fpbq_trans, fpbq_feqx/ qed-.
  59
  60 (* Properties with t-bound rt-transition for terms **************************)
  61
  62 lemma cpm_tneqx_cpm_fpbg (h) (G) (L):
  63                          ∀n1,T1,T. ❪G,L❫ ⊢ T1 ➡[n1,h] T → (T1 ≛ T → ⊥) →
  64                          ∀n2,T2. ❪G,L❫ ⊢ T ➡[n2,h] T2 → ❪G,L,T1❫ >[h] ❪G,L,T2❫.
  65 /4 width=5 by fpbq_fpbs, cpm_fpbq, cpm_fpb, ex2_3_intro/ qed.