matita/matita/contribs/lambdadelta/basic_2A/etc_yminus/cpy/cpy.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/xoa/ex_4_3.ma".
  16 include "ground_2/xoa/ex_5_4.ma".
  17 include "ground_2/xoa/or_3.ma".
  18 include "ground_2/ynat/ynat_minus_sn.ma".
  19 include "ground_2/ynat/ynat_minus_dx.ma".
  20 include "basic_2A/notation/relations/psubst_6.ma".
  21 include "basic_2A/grammar/genv.ma".
  22 include "basic_2A/substitution/lsuby.ma".
  23
  24 (* CONTEXT-SENSITIVE EXTENDED ORDINARY SUBSTITUTION FOR TERMS ***************)
  25
  26 (* activate genv *)
  27 inductive cpy: ynat → ynat → relation4 genv lenv term term ≝
  28 | cpy_atom : ∀I,G,L,l,m. cpy l m G L (⓪{I}) (⓪{I})
  29 | cpy_subst: ∀I,G,L,K,V,W,i,l,m. l ≤ yinj i → i < l+m →
  30              ⬇[i] L ≡ K.ⓑ{I}V → ⬆[0, i+1] V ≡ W → cpy l m G L (#i) W
  31 | cpy_bind : ∀a,I,G,L,V1,V2,T1,T2,l,m.
  32              cpy l m G L V1 V2 → cpy (↑l) m G (L.ⓑ{I}V1) T1 T2 →
  33              cpy l m G L (ⓑ{a,I}V1.T1) (ⓑ{a,I}V2.T2)
  34 | cpy_flat : ∀I,G,L,V1,V2,T1,T2,l,m.
  35              cpy l m G L V1 V2 → cpy l m G L T1 T2 →
  36              cpy l m G L (ⓕ{I}V1.T1) (ⓕ{I}V2.T2)
  37 .
  38
  39 interpretation "context-sensitive extended ordinary substritution (term)"
  40    'PSubst G L T1 l m T2 = (cpy l m G L T1 T2).
  41
  42 (* Basic properties *********************************************************)
  43
  44 lemma lsuby_cpy_trans: ∀G,l,m. lsub_trans … (cpy l m G) (lsuby l m).
  45 #G #l #m #L1 #T1 #T2 #H elim H -G -L1 -T1 -T2 -l -m
  46 [ //
  47 | #I #G #L1 #K1 #V #W #i #l #m #Hli #Hilm #HLK1 #HVW #L2 #HL12
  48   elim (lsuby_drop_trans_be … HL12 … HLK1) -HL12 -HLK1 /2 width=5 by cpy_subst/
  49 | /4 width=1 by lsuby_succ, cpy_bind/
  50 | /3 width=1 by cpy_flat/
  51 ]
  52 qed-.
  53
  54 lemma cpy_refl: ∀G,T,L,l,m. ⦃G, L⦄ ⊢ T ▶[l, m] T.
  55 #G #T elim T -T // * /2 width=1 by cpy_bind, cpy_flat/
  56 qed.
  57
  58 (* Basic_1: was: subst1_ex *)
  59 lemma cpy_full: ∀I,G,K,V,T1,L,l. ⬇[l] L ≡ K.ⓑ{I}V →
  60                 ∃∃T2,T. ⦃G, L⦄ ⊢ T1 ▶[l, 1] T2 & ⬆[l, 1] T ≡ T2.
  61 #I #G #K #V #T1 elim T1 -T1
  62 [ * #i #L #l #HLK
  63   /2 width=4 by lift_sort, lift_gref, ex2_2_intro/
  64   elim (lt_or_eq_or_gt i l) #Hil
  65   /3 width=4 by lift_lref_ge_minus, lift_lref_lt, ex2_2_intro/
  66   destruct
  67   elim (lift_total V 0 (i+1)) #W #HVW
  68   elim (lift_split … HVW i i)
  69   /4 width=5 by cpy_subst, ylt_inj, ex2_2_intro/
  70 | * [ #a ] #J #W1 #U1 #IHW1 #IHU1 #L #l #HLK
  71   elim (IHW1 … HLK) -IHW1 #W2 #W #HW12 #HW2
  72   [ elim (IHU1 (L.ⓑ{J}W1) (l+1)) -IHU1
  73     /3 width=9 by cpy_bind, drop_drop, lift_bind, ex2_2_intro/
  74   | elim (IHU1 … HLK) -IHU1 -HLK
  75     /3 width=8 by cpy_flat, lift_flat, ex2_2_intro/
  76   ]
  77 ]
  78 qed-.
  79
  80 lemma cpy_weak: ∀G,L,T1,T2,l1,m1. ⦃G, L⦄ ⊢ T1 ▶[l1, m1] T2 →
  81                 ∀l2,m2. l2 ≤ l1 → l1 + m1 ≤ l2 + m2 →
  82                 ⦃G, L⦄ ⊢ T1 ▶[l2, m2] T2.
  83 #G #L #T1 #T2 #l1 #m1 #H elim H -G -L -T1 -T2 -l1 -m1 //
  84 [ /3 width=5 by cpy_subst, ylt_yle_trans, yle_trans/
  85 | /4 width=3 by cpy_bind, ylt_yle_trans, yle_succ/
  86 | /3 width=1 by cpy_flat/
  87 ]
  88 qed-.
  89
  90 lemma cpy_weak_top: ∀G,L,T1,T2,l,m.
  91                     ⦃G, L⦄ ⊢ T1 ▶[l, m] T2 → ⦃G, L⦄ ⊢ T1 ▶[l, |L| - l] T2.
  92 #G #L #T1 #T2 #l #m #H elim H -G -L -T1 -T2 -l -m //
  93 [ #I #G #L #K #V #W #i #l #m #Hli #_ #HLK #HVW
  94   lapply (drop_fwd_length_lt2 … HLK) #Hil
  95   lapply (ylt_inj … Hil) -Hil #Hil
  96   lapply (yle_ylt_trans … Hil Hli) #Hl
  97   @(cpy_subst … Hli … HLK HVW)
  98   <yplus_minus_dx /2 width=1 by ylt_fwd_le/
  99 | #a #I #G #L #V1 #V2 #T1 #T2 #l #m #_ #HT12 #IHV normalize in match (|?|);
 100   /2 width=1 by cpy_bind/
 101 | /2 width=1 by cpy_flat/
 102 ]
 103 qed-.
 104
 105 lemma cpy_weak_full: ∀G,L,T1,T2,l,m.
 106                      ⦃G, L⦄ ⊢ T1 ▶[l, m] T2 → ⦃G, L⦄ ⊢ T1 ▶[0, |L|] T2.
 107 #G #L #T1 #T2 #l #m #HT12
 108 lapply (cpy_weak … HT12 0 (l + m) ? ?) -HT12
 109 /2 width=2 by cpy_weak_top/
 110 qed-.
 111 (*
 112 lemma cpy_split_up: ∀G,L,T1,T2,l,m. ⦃G, L⦄ ⊢ T1 ▶[l, m] T2 → ∀i. i ≤ l + m →
 113                     ∃∃T. ⦃G, L⦄ ⊢ T1 ▶[l, i-l] T & ⦃G, L⦄ ⊢ T ▶[i, l+m-i] T2.
 114 #G #L #T1 #T2 #l #m #H elim H -G -L -T1 -T2 -l -m
 115 [ /2 width=3 by ex2_intro/
 116 | #I #G #L #K #V #W #i #l #m #Hli #Hilm #HLK #HVW #j #Hjlm
 117   elim (ylt_split i j) [ -Hilm -Hjlm | -Hli ]
 118   /4 width=9 by cpy_subst, ylt_yle_trans, ex2_intro/
 119 | #a #I #G #L #V1 #V2 #T1 #T2 #l #m #_ #_ #IHV12 #IHT12 #i #Hilm
 120   elim (IHV12 i) -IHV12 // #V
 121   elim (IHT12 (i+1)) -IHT12 /2 width=1 by yle_succ/ -Hilm
 122   >yplus_SO2 >yplus_succ1 #T #HT1 #HT2
 123   lapply (lsuby_cpy_trans … HT2 (L.ⓑ{I}V) ?) -HT2
 124   /3 width=5 by lsuby_succ, ex2_intro, cpy_bind/
 125 | #I #G #L #V1 #V2 #T1 #T2 #l #m #_ #_ #IHV12 #IHT12 #i #Hilm
 126   elim (IHV12 i) -IHV12 // elim (IHT12 i) -IHT12 // -Hilm
 127   /3 width=5 by ex2_intro, cpy_flat/
 128 ]
 129 qed-.
 130
 131 lemma cpy_split_down: ∀G,L,T1,T2,l,m. ⦃G, L⦄ ⊢ T1 ▶[l, m] T2 → ∀i. i ≤ l + m →
 132                       ∃∃T. ⦃G, L⦄ ⊢ T1 ▶[i, l+m-i] T & ⦃G, L⦄ ⊢ T ▶[l, i-l] T2.
 133 #G #L #T1 #T2 #l #m #H elim H -G -L -T1 -T2 -l -m
 134 [ /2 width=3 by ex2_intro/
 135 | #I #G #L #K #V #W #i #l #m #Hli #Hilm #HLK #HVW #j #Hjlm
 136   elim (ylt_split i j) [ -Hilm -Hjlm | -Hli ]
 137   /4 width=9 by cpy_subst, ylt_yle_trans, ex2_intro/
 138 | #a #I #G #L #V1 #V2 #T1 #T2 #l #m #_ #_ #IHV12 #IHT12 #i #Hilm
 139   elim (IHV12 i) -IHV12 // #V
 140   elim (IHT12 (i+1)) -IHT12 /2 width=1 by yle_succ/ -Hilm
 141   >yplus_SO2 >yplus_succ1 #T #HT1 #HT2
 142   lapply (lsuby_cpy_trans … HT2 (L.ⓑ{I}V) ?) -HT2
 143   /3 width=5 by lsuby_succ, ex2_intro, cpy_bind/
 144 | #I #G #L #V1 #V2 #T1 #T2 #l #m #_ #_ #IHV12 #IHT12 #i #Hilm
 145   elim (IHV12 i) -IHV12 // elim (IHT12 i) -IHT12 // -Hilm
 146   /3 width=5 by ex2_intro, cpy_flat/
 147 ]
 148 qed-.
 149
 150 (* Basic forward lemmas *****************************************************)
 151
 152 lemma cpy_fwd_up: ∀G,L,U1,U2,lt,mt. ⦃G, L⦄ ⊢ U1 ▶[lt, mt] U2 →
 153                   ∀T1,l,m. ⬆[l, m] T1 ≡ U1 →
 154                   l ≤ lt → l + m ≤ lt + mt →
 155                   ∃∃T2. ⦃G, L⦄ ⊢ U1 ▶[l+m, lt+mt-(l+m)] U2 & ⬆[l, m] T2 ≡ U2.
 156 #G #L #U1 #U2 #lt #mt #H elim H -G -L -U1 -U2 -lt -mt
 157 [ * #i #G #L #lt #mt #T1 #l #m #H #_
 158   [ lapply (lift_inv_sort2 … H) -H #H destruct /2 width=3 by ex2_intro/
 159   | elim (lift_inv_lref2 … H) -H * #Hil #H destruct /3 width=3 by lift_lref_ge_minus, lift_lref_lt, ex2_intro/
 160   | lapply (lift_inv_gref2 … H) -H #H destruct /2 width=3 by ex2_intro/
 161   ]
 162 | #I #G #L #K #V #W #i #lt #mt #Hlti #Hilmt #HLK #HVW #T1 #l #m #H #Hllt #Hlmlmt
 163   elim (lift_inv_lref2 … H) -H * #Hil #H destruct [ -V -Hilmt -Hlmlmt | -Hlti -Hllt ]
 164   [ elim (ylt_yle_false … Hllt) -Hllt /3 width=3 by yle_ylt_trans, ylt_inj/
 165   | elim (le_inv_plus_l … Hil) #Hlim #Hmi
 166     elim (lift_split … HVW l (i-m+1) ? ? ?) [2,3,4: /2 width=1 by le_S_S, le_S/ ] -Hlim
 167     #T2 #_ >plus_minus // <minus_minus /2 width=1 by le_S/ <minus_n_n <plus_n_O #H -Hmi
 168     @(ex2_intro … H) -H @(cpy_subst … HLK HVW) /2 width=1 by yle_inj/ >ymax_pre_sn_comm // (**) (* explicit constructor *)
 169   ]
 170 | #a #I #G #L #W1 #W2 #U1 #U2 #lt #mt #_ #_ #IHW12 #IHU12 #X #l #m #H #Hllt #Hlmlmt
 171   elim (lift_inv_bind2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 172   elim (IHW12 … HVW1) -V1 -IHW12 //
 173   elim (IHU12 … HTU1) -T1 -IHU12 /2 width=1 by yle_succ/
 174   <yplus_inj >yplus_SO2 >yplus_succ1 >yplus_succ1
 175   /3 width=2 by cpy_bind, lift_bind, ex2_intro/
 176 | #I #G #L #W1 #W2 #U1 #U2 #lt #mt #_ #_ #IHW12 #IHU12 #X #l #m #H #Hllt #Hlmlmt
 177   elim (lift_inv_flat2 … H) -H #V1 #T1 #HVW1 #HTU1 #H destruct
 178   elim (IHW12 … HVW1) -V1 -IHW12 // elim (IHU12 … HTU1) -T1 -IHU12
 179   /3 width=2 by cpy_flat, lift_flat, ex2_intro/
 180 ]
 181 qed-.
 182
 183 lemma cpy_fwd_tw: ∀G,L,T1,T2,l,m. ⦃G, L⦄ ⊢ T1 ▶[l, m] T2 → ♯{T1} ≤ ♯{T2}.
 184 #G #L #T1 #T2 #l #m #H elim H -G -L -T1 -T2 -l -m normalize
 185 /3 width=1 by monotonic_le_plus_l, le_plus/
 186 qed-.
 187
 188 (* Basic inversion lemmas ***************************************************)
 189
 190 fact cpy_inv_atom1_aux: ∀G,L,T1,T2,l,m. ⦃G, L⦄ ⊢ T1 ▶[l, m] T2 → ∀J. T1 = ⓪{J} →
 191                         T2 = ⓪{J} ∨
 192                         ∃∃I,K,V,i. l ≤ yinj i & i < l + m &
 193                                    ⬇[i] L ≡ K.ⓑ{I}V &
 194                                    ⬆[O, i+1] V ≡ T2 &
 195                                    J = LRef i.
 196 #G #L #T1 #T2 #l #m * -G -L -T1 -T2 -l -m
 197 [ #I #G #L #l #m #J #H destruct /2 width=1 by or_introl/
 198 | #I #G #L #K #V #T2 #i #l #m #Hli #Hilm #HLK #HVT2 #J #H destruct /3 width=9 by ex5_4_intro, or_intror/
 199 | #a #I #G #L #V1 #V2 #T1 #T2 #l #m #_ #_ #J #H destruct
 200 | #I #G #L #V1 #V2 #T1 #T2 #l #m #_ #_ #J #H destruct
 201 ]
 202 qed-.
 203
 204 lemma cpy_inv_atom1: ∀I,G,L,T2,l,m. ⦃G, L⦄ ⊢ ⓪{I} ▶[l, m] T2 →
 205                      T2 = ⓪{I} ∨
 206                      ∃∃J,K,V,i. l ≤ yinj i & i < l + m &
 207                                 ⬇[i] L ≡ K.ⓑ{J}V &
 208                                 ⬆[O, i+1] V ≡ T2 &
 209                                 I = LRef i.
 210 /2 width=4 by cpy_inv_atom1_aux/ qed-.
 211
 212 (* Basic_1: was: subst1_gen_sort *)
 213 lemma cpy_inv_sort1: ∀G,L,T2,k,l,m. ⦃G, L⦄ ⊢ ⋆k ▶[l, m] T2 → T2 = ⋆k.
 214 #G #L #T2 #k #l #m #H
 215 elim (cpy_inv_atom1 … H) -H //
 216 * #I #K #V #i #_ #_ #_ #_ #H destruct
 217 qed-.
 218
 219 (* Basic_1: was: subst1_gen_lref *)
 220 lemma cpy_inv_lref1: ∀G,L,T2,i,l,m. ⦃G, L⦄ ⊢ #i ▶[l, m] T2 →
 221                      T2 = #i ∨
 222                      ∃∃I,K,V. l ≤ i & i < l + m &
 223                               ⬇[i] L ≡ K.ⓑ{I}V &
 224                               ⬆[O, i+1] V ≡ T2.
 225 #G #L #T2 #i #l #m #H
 226 elim (cpy_inv_atom1 … H) -H /2 width=1 by or_introl/
 227 * #I #K #V #j #Hlj #Hjlm #HLK #HVT2 #H destruct /3 width=5 by ex4_3_intro, or_intror/
 228 qed-.
 229
 230 lemma cpy_inv_gref1: ∀G,L,T2,p,l,m. ⦃G, L⦄ ⊢ §p ▶[l, m] T2 → T2 = §p.
 231 #G #L #T2 #p #l #m #H
 232 elim (cpy_inv_atom1 … H) -H //
 233 * #I #K #V #i #_ #_ #_ #_ #H destruct
 234 qed-.
 235
 236 fact cpy_inv_bind1_aux: ∀G,L,U1,U2,l,m. ⦃G, L⦄ ⊢ U1 ▶[l, m] U2 →
 237                         ∀a,I,V1,T1. U1 = ⓑ{a,I}V1.T1 →
 238                         ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ▶[l, m] V2 &
 239                                  ⦃G, L. ⓑ{I}V1⦄ ⊢ T1 ▶[↑l, m] T2 &
 240                                  U2 = ⓑ{a,I}V2.T2.
 241 #G #L #U1 #U2 #l #m * -G -L -U1 -U2 -l -m
 242 [ #I #G #L #l #m #b #J #W1 #U1 #H destruct
 243 | #I #G #L #K #V #W #i #l #m #_ #_ #_ #_ #b #J #W1 #U1 #H destruct
 244 | #a #I #G #L #V1 #V2 #T1 #T2 #l #m #HV12 #HT12 #b #J #W1 #U1 #H destruct /2 width=5 by ex3_2_intro/
 245 | #I #G #L #V1 #V2 #T1 #T2 #l #m #_ #_ #b #J #W1 #U1 #H destruct
 246 ]
 247 qed-.
 248
 249 lemma cpy_inv_bind1: ∀a,I,G,L,V1,T1,U2,l,m. ⦃G, L⦄ ⊢ ⓑ{a,I} V1. T1 ▶[l, m] U2 →
 250                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ▶[l, m] V2 &
 251                               ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ▶[↑l, m] T2 &
 252                               U2 = ⓑ{a,I}V2.T2.
 253 /2 width=3 by cpy_inv_bind1_aux/ qed-.
 254
 255 fact cpy_inv_flat1_aux: ∀G,L,U1,U2,l,m. ⦃G, L⦄ ⊢ U1 ▶[l, m] U2 →
 256                         ∀I,V1,T1. U1 = ⓕ{I}V1.T1 →
 257                         ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ▶[l, m] V2 &
 258                                  ⦃G, L⦄ ⊢ T1 ▶[l, m] T2 &
 259                                  U2 = ⓕ{I}V2.T2.
 260 #G #L #U1 #U2 #l #m * -G -L -U1 -U2 -l -m
 261 [ #I #G #L #l #m #J #W1 #U1 #H destruct
 262 | #I #G #L #K #V #W #i #l #m #_ #_ #_ #_ #J #W1 #U1 #H destruct
 263 | #a #I #G #L #V1 #V2 #T1 #T2 #l #m #_ #_ #J #W1 #U1 #H destruct
 264 | #I #G #L #V1 #V2 #T1 #T2 #l #m #HV12 #HT12 #J #W1 #U1 #H destruct /2 width=5 by ex3_2_intro/
 265 ]
 266 qed-.
 267
 268 lemma cpy_inv_flat1: ∀I,G,L,V1,T1,U2,l,m. ⦃G, L⦄ ⊢ ⓕ{I} V1. T1 ▶[l, m] U2 →
 269                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ▶[l, m] V2 &
 270                               ⦃G, L⦄ ⊢ T1 ▶[l, m] T2 &
 271                               U2 = ⓕ{I}V2.T2.
 272 /2 width=3 by cpy_inv_flat1_aux/ qed-.
 273
 274
 275 fact cpy_inv_refl_O2_aux: ∀G,L,T1,T2,l,m. ⦃G, L⦄ ⊢ T1 ▶[l, m] T2 → m = 0 → T1 = T2.
 276 #G #L #T1 #T2 #l #m #H elim H -G -L -T1 -T2 -l -m
 277 [ //
 278 | #I #G #L #K #V #W #i #l #m #Hli #Hilm #_ #_ #H destruct
 279   elim (ylt_yle_false … Hli) -Hli //
 280 | /3 width=1 by eq_f2/
 281 | /3 width=1 by eq_f2/
 282 ]
 283 qed-.
 284
 285 lemma cpy_inv_refl_O2: ∀G,L,T1,T2,l. ⦃G, L⦄ ⊢ T1 ▶[l, 0] T2 → T1 = T2.
 286 /2 width=6 by cpy_inv_refl_O2_aux/ qed-.
 287
 288 (* Basic_1: was: subst1_gen_lift_eq *)
 289 lemma cpy_inv_lift1_eq: ∀G,T1,U1,l,m. ⬆[l, m] T1 ≡ U1 →
 290                         ∀L,U2. ⦃G, L⦄ ⊢ U1 ▶[l, m] U2 → U1 = U2.
 291 #G #T1 #U1 #l #m #HTU1 #L #U2 #HU12 elim (cpy_fwd_up … HU12 … HTU1) -HU12 -HTU1
 292 /2 width=4 by cpy_inv_refl_O2/
 293 qed-.
 294
 295 (* Basic_1: removed theorems 25:
 296             subst0_gen_sort subst0_gen_lref subst0_gen_head subst0_gen_lift_lt
 297             subst0_gen_lift_false subst0_gen_lift_ge subst0_refl subst0_trans
 298             subst0_lift_lt subst0_lift_ge subst0_lift_ge_S subst0_lift_ge_s
 299             subst0_subst0 subst0_subst0_back subst0_weight_le subst0_weight_lt
 300             subst0_confluence_neq subst0_confluence_eq subst0_tlt_head
 301             subst0_confluence_lift subst0_tlt
 302             subst1_head subst1_gen_head subst1_lift_S subst1_confluence_lift
 303 *)