matita/matita/contribs/lambdadelta/ground/arith/arith.txt

   1 (* Equalities ***************************************************************)
   2
   3 lemma minus_plus_m_m_commutative: ∀n,m:nat. n = m + n - m.
   4 // qed-.
   5
   6 lemma plus_minus_m_m_commutative (n) (m): m ≤ n → n = m+(n-m).
   7 /2 width=1 by plus_minus_associative/ qed-.
   8
   9 lemma plus_to_minus_2: ∀m1,m2,n1,n2. n1 ≤ m1 → n2 ≤ m2 →
  10                        m1+n2 = m2+n1 → m1-n1 = m2-n2.
  11 #m1 #m2 #n1 #n2 #H1 #H2 #H
  12 @plus_to_minus >plus_minus_associative //
  13 qed-.
  14
  15 (* Note: uses minus_minus_comm, minus_plus_m_m, commutative_plus, plus_minus *)
  16 lemma plus_minus_minus_be: ∀x,y,z. y ≤ z → z ≤ x → (x - z) + (z - y) = x - y.
  17 #x #z #y #Hzy #Hyx >plus_minus // >commutative_plus >plus_minus //
  18 qed-.
  19
  20 lemma lt_succ_pred: ∀m,n. n < m → m = ↑↓m.
  21 #m #n #Hm >S_pred /2 width=2 by ltn_to_ltO/
  22 qed-.
  23
  24 fact plus_minus_minus_be_aux: ∀i,x,y,z. y ≤ z → z ≤ x → i = z - y → x - z + i = x - y.
  25 /2 width=1 by plus_minus_minus_be/ qed-.
  26
  27 lemma le_plus_minus: ∀m,n,p. p ≤ n → m + n - p = m + (n - p).
  28 /2 by plus_minus/ qed-.
  29
  30 lemma le_plus_minus_comm: ∀n,m,p. p ≤ m → m + n - p = m - p + n.
  31 /2 by plus_minus/ qed-.
  32
  33 lemma minus_minus_comm3: ∀n,x,y,z. n-x-y-z = n-y-z-x.
  34 // qed.
  35
  36 (* Properties ***************************************************************)
  37
  38 lemma eq_nat_dec: ∀n1,n2:nat. Decidable (n1 = n2).
  39 #n1 elim n1 -n1 [| #n1 #IHn1 ] * [2,4: #n2 ]
  40 [1,4: @or_intror #H destruct
  41 | elim (IHn1 n2) -IHn1 /3 width=1 by or_intror, or_introl/
  42 | /2 width=1 by or_introl/
  43 ]
  44 qed-.
  45
  46 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
  47 #m #n elim (lt_or_ge m n) /2 width=1 by or3_intro0/
  48 #H elim H -m /2 width=1 by or3_intro1/
  49 #m #Hm * /3 width=1 by not_le_to_lt, le_S_S, or3_intro2/
  50 qed-.
  51
  52 lemma monotonic_le_minus_l2: ∀x1,x2,y,z. x1 ≤ x2 → x1 - y - z ≤ x2 - y - z.
  53 /3 width=1 by monotonic_le_minus_l/ qed.
  54
  55 lemma minus_le_trans_sn: ∀x1,x2. x1 ≤ x2 → ∀x. x1-x ≤ x2.
  56 /2 width=3 by transitive_le/ qed.
  57
  58 lemma le_plus_to_minus_l: ∀a,b,c. a + b ≤ c → b ≤ c-a.
  59 /2 width=1 by le_plus_to_minus_r/
  60 qed-.
  61
  62 lemma le_plus_to_minus_comm: ∀n,m,p. n ≤ p+m → n-p ≤ m.
  63 /2 width=1 by le_plus_to_minus/ qed-.
  64
  65 lemma le_inv_S1: ∀m,n. ↑m ≤ n → ∃∃p. m ≤ p & ↑p = n.
  66 #m *
  67 [ #H lapply (le_n_O_to_eq … H) -H
  68   #H destruct
  69 | /3 width=3 by monotonic_pred, ex2_intro/
  70 ]
  71 qed-.
  72
  73 (* Note: this might interfere with nat.ma *)
  74 lemma monotonic_lt_pred: ∀m,n. m < n → 0 < m → pred m < pred n.
  75 #m #n #Hmn #Hm whd >(S_pred … Hm)
  76 @le_S_S_to_le >S_pred /2 width=3 by transitive_lt/
  77 qed.
  78
  79 lemma lt_S_S: ∀x,y. x < y → ↑x < ↑y.
  80 /2 width=1 by le_S_S/ qed.
  81
  82 lemma lt_S: ∀n,m. n < m → n < ↑m.
  83 /2 width=1 by le_S/ qed.
  84
  85 lemma monotonic_lt_minus_r:
  86 ∀p,q,n. q < n -> q < p → n-p < n-q.
  87 #p #q #n #Hn #H
  88 lapply (monotonic_le_minus_r … n H) -H #H
  89 @(le_to_lt_to_lt … H) -H
  90 /2 width=1 by lt_plus_to_minus/
  91 qed.
  92
  93 (* Inversion & forward lemmas ***********************************************)
  94
  95 lemma lt_refl_false: ∀n. n < n → ⊥.
  96 #n #H elim (lt_to_not_eq … H) -H /2 width=1 by/
  97 qed-.
  98
  99 lemma lt_zero_false: ∀n. n < 0 → ⊥.
 100 #n #H elim (lt_to_not_le … H) -H /2 width=1 by/
 101 qed-.
 102
 103 lemma lt_le_false: ∀x,y. x < y → y ≤ x → ⊥.
 104 /3 width=4 by lt_refl_false, lt_to_le_to_lt/ qed-.
 105
 106 lemma le_dec (n) (m): Decidable (n≤m).
 107 #n elim n -n [ /2 width=1 by or_introl/ ]
 108 #n #IH * [ /3 width=2 by lt_zero_false, or_intror/ ]
 109 #m elim (IH m) -IH
 110 [ /3 width=1 by or_introl, le_S_S/
 111 | /4 width=1 by or_intror, le_S_S_to_le/
 112 ]
 113 qed-.
 114
 115 lemma succ_inv_refl_sn: ∀x. ↑x = x → ⊥.
 116 #x #H @(lt_le_false x (↑x)) //
 117 qed-.
 118
 119 lemma le_plus_xSy_O_false: ∀x,y. x + S y ≤ 0 → ⊥.
 120 #x #y #H lapply (le_n_O_to_eq … H) -H <plus_n_Sm #H destruct
 121 qed-.
 122
 123 lemma le_plus_xySz_x_false: ∀y,z,x. x + y + S z ≤ x → ⊥.
 124 #y #z #x elim x -x /3 width=1 by le_S_S_to_le/
 125 #H elim (le_plus_xSy_O_false … H)
 126 qed-.
 127
 128 lemma plus_xySz_x_false: ∀z,x,y. x + y + S z = x → ⊥.
 129 /2 width=4 by le_plus_xySz_x_false/ qed-.
 130
 131 lemma plus_xSy_x_false: ∀y,x. x + S y = x → ⊥.
 132 /2 width=4 by plus_xySz_x_false/ qed-.
 133
 134 lemma pred_inv_fix_sn: ∀x. ↓x = x → 0 = x.
 135 * // #x <pred_Sn #H
 136 elim (succ_inv_refl_sn x) //
 137 qed-.
 138
 139 lemma discr_plus_xy_y: ∀x,y. x + y = y → x = 0.
 140 // qed-.
 141
 142 lemma discr_plus_x_xy: ∀x,y. x = x + y → y = 0.
 143 /2 width=2 by le_plus_minus_comm/ qed-.
 144
 145 lemma plus2_le_sn_sn: ∀m1,m2,n1,n2. m1 + n1 = m2 + n2 → m1 ≤ m2 → n2 ≤ n1.
 146 #m1 #m2 #n1 #n2 #H #Hm
 147 lapply (monotonic_le_plus_l n1 … Hm) -Hm >H -H
 148 /2 width=2 by le_plus_to_le/
 149 qed-.
 150
 151 lemma plus2_le_sn_dx: ∀m1,m2,n1,n2. m1 + n1 = n2 + m2 → m1 ≤ m2 → n2 ≤ n1.
 152 /2 width=4 by plus2_le_sn_sn/ qed-.
 153
 154 lemma plus2_le_dx_sn: ∀m1,m2,n1,n2. n1 + m1 = m2 + n2 → m1 ≤ m2 → n2 ≤ n1.
 155 /2 width=4 by plus2_le_sn_sn/ qed-.
 156
 157 lemma plus2_le_dx_dx: ∀m1,m2,n1,n2. n1 + m1 = n2 + m2 → m1 ≤ m2 → n2 ≤ n1.
 158 /2 width=4 by plus2_le_sn_sn/ qed-.
 159
 160 lemma lt_S_S_to_lt: ∀x,y. ↑x < ↑y → x < y.
 161 /2 width=1 by le_S_S_to_le/ qed-.
 162
 163 (* Note this should go in nat.ma *)
 164 lemma discr_x_minus_xy: ∀x,y. x = x - y → x = 0 ∨ y = 0.
 165 #x @(nat_ind_plus … x) -x /2 width=1 by or_introl/
 166 #x #_ #y @(nat_ind_plus … y) -y /2 width=1 by or_intror/
 167 #y #_ >minus_plus_plus_l
 168 #H lapply (discr_plus_xy_minus_xz … H) -H
 169 #H destruct
 170 qed-.
 171
 172 lemma lt_inv_O1: ∀n. 0 < n → ∃m. ↑m = n.
 173 * /2 width=2 by ex_intro/
 174 #H cases (lt_le_false … H) -H //
 175 qed-.
 176
 177 lemma lt_inv_S1: ∀m,n. ↑m < n → ∃∃p. m < p & ↑p = n.
 178 #m * /3 width=3 by lt_S_S_to_lt, ex2_intro/
 179 #H cases (lt_le_false … H) -H //
 180 qed-.
 181
 182 lemma lt_inv_gen: ∀y,x. x < y → ∃∃z. x ≤ z & ↑z = y.
 183 * /3 width=3 by le_S_S_to_le, ex2_intro/
 184 #x #H elim (lt_le_false … H) -H //
 185 qed-.
 186
 187 lemma plus_inv_O3: ∀x,y. x + y = 0 → x = 0 ∧ y = 0.
 188 /2 width=1 by plus_le_0/ qed-.
 189
 190 lemma plus_inv_S3_sn: ∀x1,x2,x3. x1+x2 = ↑x3 →
 191                       ∨∨ ∧∧ x1 = 0 & x2 = ↑x3
 192                        | ∃∃y1. x1 = ↑y1 & y1 + x2 = x3.
 193 * /3 width=1 by or_introl, conj/
 194 #x1 #x2 #x3 <plus_S1 #H destruct
 195 /3 width=3 by ex2_intro, or_intror/
 196 qed-.
 197
 198 lemma plus_inv_S3_dx: ∀x2,x1,x3. x1+x2 = ↑x3 →
 199                       ∨∨ ∧∧ x2 = 0 & x1 = ↑x3
 200                        | ∃∃y2. x2 = ↑y2 & x1 + y2 = x3.
 201 * /3 width=1 by or_introl, conj/
 202 #x2 #x1 #x3 <plus_n_Sm #H destruct
 203 /3 width=3 by ex2_intro, or_intror/
 204 qed-.
 205
 206 lemma zero_eq_plus: ∀x,y. 0 = x + y → 0 = x ∧ 0 = y.
 207 * /2 width=1 by conj/ #x #y normalize #H destruct
 208 qed-.
 209
 210 lemma nat_split: ∀x. x = 0 ∨ ∃y. ↑y = x.
 211 * /3 width=2 by ex_intro, or_introl, or_intror/
 212 qed-.
 213
 214 lemma nat_elim_le_sn (Q:relation …):
 215       (∀m1,m2. (∀m. m < m2-m1 → Q (m2-m) m2) → m1 ≤ m2 → Q m1 m2) →
 216       ∀n1,n2. n1 ≤ n2 → Q n1 n2.
 217 #Q #IH #n1 #n2 #Hn
 218 <(minus_minus_m_m … Hn) -Hn
 219 lapply (minus_le n2 n1)
 220 let d ≝ (n2-n1)
 221 @(nat_elim1 … d) -d -n1 #d
 222 @pull_2 #Hd
 223 <(minus_minus_m_m … Hd) in ⊢ (%→?); -Hd
 224 let n1 ≝ (n2-d) #IHd
 225 @IH -IH [| // ] #m #Hn
 226 /4 width=3 by lt_to_le, lt_to_le_to_lt/
 227 qed-.
 228
 229 (* Decidability of predicates ***********************************************)
 230
 231 lemma dec_lt (R:predicate nat):
 232       (∀n. Decidable … (R n)) →
 233       ∀n. Decidable … (∃∃m. m < n & R m).
 234 #R #HR #n elim n -n [| #n * ]
 235 [ @or_intror * /2 width=2 by lt_zero_false/
 236 | * /4 width=3 by lt_S, or_introl, ex2_intro/
 237 | #H0 elim (HR n) -HR
 238   [ /3 width=3 by or_introl, ex2_intro/
 239   | #Hn @or_intror * #m #Hmn #Hm
 240     elim (le_to_or_lt_eq … Hmn) -Hmn #H destruct [ -Hn | -H0 ]
 241     /4 width=3 by lt_S_S_to_lt, ex2_intro/
 242   ]
 243 ]
 244 qed-.
 245
 246 lemma dec_min (R:predicate nat):
 247       (∀n. Decidable … (R n)) → ∀n. R n →
 248       ∃∃m. m ≤ n & R m & (∀p. p < m → R p → ⊥).
 249 #R #HR #n
 250 @(nat_elim1 n) -n #n #IH #Hn
 251 elim (dec_lt … HR n) -HR [ -Hn | -IH ]
 252 [ * #p #Hpn #Hp
 253   elim (IH … Hpn Hp) -IH -Hp #m #Hmp #Hm #HNm
 254   @(ex3_intro … Hm HNm) -HNm
 255   /3 width=3 by lt_to_le, le_to_lt_to_lt/
 256 | /4 width=4 by ex3_intro, ex2_intro/
 257 ]
 258 qed-.